[POJ3368 Frequent values]

[题目来源]：Ulm Local 2007

[关键字]：RMQ

[题目大意]：给定一个非递减的整数序列（n），然后给出m个查询区间，针对每一个查询，输出此区间内重复最多的数字重复的次数。

//=====================================================================================================

[分析]：如果给定的区间恰好是连续的区间的两端则可直接同过RMQ问题求解。但如果不是这样则需要先求出两遍的最大值，再求中间就转换成了之前所说的问题。

[代码]：

var
  n, q: longint;
  a, b, c: array[0..100100] of longint;
  f: array[0..100100,0..40] of longint;

function max(x, y: longint):longint;
begin
  if x > y then exit(x) else exit(y);
end;

procedure st;
var
  t, i, j: longint;
begin
  for i := 1 to n do f[i,0] := a[i];
  t := trunc(ln(n)/ln(2));
  for j := 1 to t do
    for i := 1 to n+1-1 shl j do
       f[i,j] := max(f[i,j-1],f[i+1 shl (j-1),j-1])
end;

procedure init;
var
  i: longint;
begin
  read(n);
  if n = 0 then halt;
  readln(q);
  for i := 1 to n do
    read(c[i]);
  a[1] := 1;
  for i := 2 to n do
    if c[i] = c[i-1] then a[i] := a[i-1]+1 else a[i] := 1;
  b[n] := a[n];
  for i := n-1 downto 1 do
    if c[i] = c[i+1] then b[i] := b[i+1] else b[i] := a[i];
  fillchar(f,sizeof(f),0);
  st;
end;

function find(x, y: longint):longint;
var
  ans, t: longint;
begin
  ans := b[x]-a[x]+1;
  if ans < a[y] then ans := a[y];
  if ans > y-x+1 then exit(y-x+1);
  
  x := x+b[x]-a[x]+1;
  y := y-a[y];
  if x >= y then exit(ans);
  
  t := trunc(ln(y-x+1)/ln(2));
  ans := max(max(f[x,t],f[y-1 shl t+1,t]),ans);
  
  exit(ans);
end;

procedure work;
var
  i, ans, x ,y: longint;
begin
  for i := 1 to q do
    begin
      readln(x,y);
      ans := find(x,y);
      writeln(ans);
    end;
end;

begin
  while 1 = 1 do
    begin
      init;
      work;
    end;
end.