[POJ1840 Eqs]

[题目来源]：POJ1840

[关键字]：Hash

[题目大意]：给出形如：a1*x1^3+a2*x2^3+a3*x3^3+a4*x4^3+a5*x5^3=0的方程求其一共有多少解。

//===========================================================================================================

[分析]：原始得朴素思想是枚举前4个值然后判断，如果是解就加一。但如此必超时无疑，所以可以将其拆成两部分，要想成立必有前一部分的值等于后一部分的值的的相反数。枚举实际上就是把一部分的值和后一部分的每一个值比较查找符合条件的值。而要想加快就必须在查找上优化——Hash！先枚举下你两个x的值存入Hash表，再枚举后三个的值进行查找。

[代码]：

program Project1;
var
  a: array[0..10] of longint;
  t: array[-50..50] of longint;
  num: array[-20000..20000] of longint;
  h: array[-20000..20000,0..20] of longint;

function hash(x: longint):longint;
begin
  hash := x mod 15988;
end;

procedure init;
var
  i: longint;
begin
  for i := 1 to 5 do read(a[i]);
end;

procedure work;
var
  i, j, k, i1, i2, i3, ans, tot: longint;
begin
  tot := 0;
  for i := -50 to 50 do
    t[i] := i*i*i;
  for i := -50 to 50 do
    for j := -50 to 50 do
      if (i <> 0) and (j <> 0) then
        begin
          ans := a[1]*t[i]+a[2]*t[j];
          k := hash(ans);
          //writeln(k);
          inc(num[k]);
          h[k,num[k]] := ans;
        end;
  for i1 := -50 to 50 do
    for i2 := -50 to 50 do
      for i3 := -50 to 50 do
        if (i1 <> 0) and (i2 <> 0) and (i3 <> 0) then
          begin
            ans := a[3]*t[i1]+a[4]*t[i2]+a[5]*t[i3];
            ans := -ans;
            k := hash(ans);
            for j := 1 to num[k] do
              if h[k,j] = ans then inc(tot);
          end;
  writeln(tot);
end;

begin
  init;
  work;
end.