POJ1659

题意:中文描述.

分析:havel定理的应用.

havel定理的简介:

给定一个非负整数序列{d1,d2,...dn}，若存在一个无向图使得图中各点的度与此序列一一对应，则称此序列可图化。进一步，若图为简单图，则称此序列可简单图化。

可图化的判定比较简单：d1+d2+...dn=0(mod2)。关于具体图的构造，我们可以简单地把奇数度的点配对，剩下的全部搞成自环。

可简单图化的判定，有一个Havel定理，是说: 我们把序列排成不增序，即d1>=d2>=...>=dn，则d可简单图化当且仅当d'=(d2-1, d3-1, ... d(d1+1)-1, d(d1+2), d(d1+3), ... dn)可简单图化。这个定理写起来麻烦，实际上就是说，我们把d排序以后，找出度最大的点(设度为d1)，把它和度次大的d1个点之间连边，然后这个点就可以不管了，一直继续这个过程，直到建出完整的图，或出现负度等明显不合理的情况。

定理的简单证明如下:

(<=)若d'可简单图化，我们只需把原图中的最大度点和d'中度最大的d1个点连边即可，易得此图必为简单图。

(=>)若d可简单图化，设得到的简单图为G。分两种情况考虑:

(a)若G中存在边(V1,V2), (V1,V3), ...(V1,V(d1+1))，则把这些边除去得简单图G'，于是d'可简单图化为G'

(b)若存在点Vi,Vj使得i<j, (V1,Vi)不在G中，但(V1,Vj)在G中。这时，因为di>=dj，必存在k使得(Vi, Vk)在G中但(Vj,Vk)不在G中。这时我们可以令GG=G-{(Vi,Vk),(V1,Vj)}+{(Vk,Vj),(V1,Vi)}。GG的度序列仍为d，我们又回到了情况(a)。

code:

type  Frog=record
      deg,idx:longint;
end;
var   m:array[0..11,0..11] of boolean;
      f:array[0..11] of frog;
      dnum,dx,i,j,n:longint;
      flag:boolean;

      procedure sort(l,r:longint);
      var   p,q:longint;
      begin
            for p:=l to r do
               for q:=p to r do
               if f[p].deg<f[q].deg then
               begin
                     f[0]:=f[p];
                     f[p]:=f[q];
                     f[q]:=f[0];
               end;
      end;


begin
      readln(dnum);
      for dx:=1 to dnum do
      begin
            fillchar(m,sizeof(m),0);
            readln(n);
            for i:=1 to n do
            begin
                  read(f[i].deg);
                  f[i].idx:=i;
            end;
            readln;
            flag:=true;
            for i:=1 to n do
            begin
                  sort(i,n);
                  for j:=i+1 to i+f[i].deg do
                  begin
                        m[f[i].idx,f[j].idx]:=true;
                        m[f[j].idx,f[i].idx]:=true;
                        dec(f[j].deg);
                        if f[j].deg<0 then
                        begin
                              flag:=false;
                              break;
                        end;
                  end;
                  if flag=false then
                  begin
                        writeln('NO');
                        writeln;
                        break;
                  end;
            end;
            if flag=false then continue;
            writeln('YES'); 
            for i:=1 to n do
            begin
                  for j:=1 to n do write(ord(m[i,j]),' ');
                  writeln;
            end;
            writeln;
      end;
end.