批处理实现批量创建快捷方式

功能：自动读取./dir.txt文件中配置的每行目录，并在当前目录下创建该目录的快捷方式（目录可以是可访问的网络磁盘目录，此功能可以取代网络磁盘映射，特别适用于网络磁盘映射太多，而虚拟网络磁盘驱动器数量不足的情况）

注意：批处理中的for循环中的语句会被解析为一条语句执行，所以必须使用变量延迟才能保证数据的正确性，同时，for循环中的右括号要启用转义

测试：

./dir.txt内容如下：

 

运行前目录：

 

运行后目录：

 

批处理代码如下： 

@echo off

color 0a
title 自动创建文件目录快捷方式

::设置变量延迟
setlocal EnableDelayedExpansion

for /f "tokens=*" %%a in (./dir.txt) do (
  set ThePath=%%a

  for %%b in (%%a) do (
    set LinkName=%%~nxb.lnk

  mshta VBScript:Execute("Set Shell=CreateObject(""WScript.Shell""):Set Link=Shell.CreateShortcut(""!LinkName!""):Link.TargetPath=""!ThePath!"":Link.Save:close"^)

  )
)

echo 创建完成！按任意键退出
pause>nul

::说明：复制以上代码到文本文档中，保存为.bat文件，点击直接运行即可自动读取./dir.txt中每行目录，并在当前目录下创建该目录的快捷方式
::(注：部分杀毒软件可能会报毒，请允许此程序的所有操作并添加信任）

 加强版：可配置快捷方式名称（因为相同目录可能被拷贝多份）

 

./dir.txt内容如下：（第一列为指定的快捷方式名称，中间以“：”隔开，后跟具体路径名，注意：冒号两边不能加空格）

 

 

运行前目录：

 

 

 

 

运行后目录：

 

 

 批处理代码如下：

@echo off

color 0a
title 自动创建文件目录快捷方式

::设置变量延迟
setlocal EnableDelayedExpansion

for /f "delims=: tokens=1,*" %%a in (./dir.txt) do (
  set LinkName=%%a.lnk
  set ThePath=%%b
  mshta VBScript:Execute("Set Shell=CreateObject(""WScript.Shell""):Set Link=Shell.CreateShortcut(""!LinkName!""):Link.TargetPath=""!ThePath!"":Link.Save:close"^)
)

echo 创建完成！按任意键退出
pause>nul

::说明：复制以上代码到文本文档中，保存为.bat文件，点击直接运行即可自动读取./dir.txt中每行目录（可以是可访问的网络磁盘目录），并在当前目录下创建该目录的快捷方式
::(注：部分杀毒软件可能会报毒，请允许此程序的所有操作并添加信任）