动态规划_背包问题扩展

扩展问题中比较常见的就是求方案数和求第K优解.

求方案数的问题中,一般是求将背包装满的方案数(求最优方案数不多见).

代码很简单:

var   f:array[0..10000] of longint;
      v:array[0..100] of longint;
      n,m,i,j:longint;


begin
      readln(n,m);
      for i:=1 to n do readln(v[i]);
      f[0]:=1;
      for i:=1 to n do
         for j:=v[i] to m do inc(f[j],f[j-v[i]]);
      writeln(f[m]);
end.

note:

对于a1X1+a2X2+a3X3+...+anXn=M这样的方程,
可以将ai视为物品体积,M视为背包容量,用求方案数的

算法求出非负整数解的个数.
//---------------------------------------------------------------------------

求第K优解的就是在原来的方程中加上一维,变成f[i,k]表示体积为i时的第K优解,
转移时,取出上一个阶段的前K优解,更新出这个阶段的前K优解(暂时的),显然这两
个东西都是有序的,那么我们可以像归并排序中合并有序队列那样合并两个队列,
更新出这个阶段的前K优解.

code:

const oo=1000000000;
      maxv=5001;
      maxn=201;
      maxk=51;
var   f:array[0..maxv,0..maxk] of longint;
      pre,now:array[0..maxk] of longint;
      p,w:array[0..maxn] of longint;
      k,v,n,i,j,l,pl,nl,ans:longint;

      function max(a,b:longint):longint;
      begin
            if a>b then exit(a); exit(b)
      end;

begin
      readln(k,v,n);
      for i:=1 to n do readln(p[i],w[i]);

      for i:=0 to maxv do
         for j:=0 to maxk do f[i,j]:=-oo;

      f[0,1]:=0;
      for i:=1 to n do
         for j:=v downto p[i] do
         begin
               for l:=1 to k do
               begin
                     pre[l]:=f[j,l];
                     now[l]:=f[j-p[i],l]+w[i];
               end;
               pl:=1;
               nl:=1;
               for l:=1 to k do
               if pre[pl]>now[nl] then
               begin
                     f[j,l]:=pre[pl];
                     inc(pl);
               end
               else
               begin
                     f[j,l]:=now[nl];
                     inc(nl);
               end;
         end;

      for i:=1 to k do inc(ans,f[v,i]);
      writeln(ans);
end.

简单地写到这.

参考资料:

《背包九讲》