CH Round #52 - Thinking Bear #1 (NOIP模拟赛)

A.拆地毯

题目：http://www.contesthunter.org/contest/CH%20Round%20%2352%20-%20Thinking%20Bear%20%231%20(NOIP模拟赛)/拆地毯

题解：按最大生成树顺序加k条边即可

代码：

const maxn=100000+1000;
var c:array[0..maxn] of int64;
    fa,a,b:array[0..maxn] of longint;
    i,j,n,m,k:longint;
    ans:int64;
function find(x:longint):longint;
 begin
 if fa[x]<>x then fa[x]:=find(fa[x]);
 exit(fa[x]);
 end;

procedure sort(l,r:longint);
 var i,j:longint;x,y:int64;
 begin
 i:=l;j:=r;x:=c[(i+j)>>1];
 repeat
  while c[i]>x do inc(i);
  while c[j]<x do dec(j);
  if i<=j then
   begin
   y:=a[i];a[i]:=a[j];a[j]:=y;
   y:=b[i];b[i]:=b[j];b[j]:=y;
   y:=c[i];c[i]:=c[j];c[j]:=y;
   inc(i);dec(j);
   end;
 until i>j;
 if i<r then sort(i,r);
 if j>l then sort(l,j);
 end;
procedure init;
 begin
   readln(n,m,k);
   for i:=1 to m do readln(a[i],b[i],c[i]);
 end;
procedure main;
 begin
  sort(1,m);
  for i:=1 to n do fa[i]:=i;
  j:=1;
  ans:=0;
  for i:=1 to k do
   begin
     while (find(a[j])=find(b[j])) do inc(j);
     fa[find(a[j])]:=find(b[j]);
     inc(ans,c[j]);
   end;
  writeln(ans);
 end;

begin
  init;
  main;
end.     

B.还教室

题目：http://www.contesthunter.org/contest/CH%20Round%20%2352%20-%20Thinking%20Bear%20%231%20(NOIP模拟赛)/还教室

题解：前两个操作都是线段树基础操作，第三个操作需要一点变形

        首先我们要知道：方差s=sigma（xi-x0）^2  (i=1..n) /n =sigma（xi^2）-x0^2        x0表示平均数

        这手推一下就知道了，我们只需要指导一段区间内的平方和即可，线段树也是可以维护的

        （ms贴吧里有人说 只要是具有加和性？就能用线段树来维护？

         我理解的是 加上1个值x1 又加了1个值x2，不管第一次加的值，直接把需要加的值更改为x1+x2在维护的时候可以正确就是对的。。。）

代码：

const maxn=100000+1000;
type node=record
     l,r,mid,lch,rch:longint;
     sum,pf,tag:int64;
     end;
var t:array[0..4*maxn] of node;
    a:array[0..maxn] of longint;
    i,j,n,m,ch,x,y:longint;
    xx,yy,z:int64;
procedure pushup(k:longint);
 begin
 with t[k] do
   begin
     sum:=t[lch].sum+t[rch].sum;
     pf:=t[lch].pf+t[rch].pf;
   end;
 end;
procedure update(k:longint;val:int64);
 begin
 with t[k] do
   begin
     inc(tag,val);
     inc(pf,2*val*sum+(r-l+1)*val*val);
     inc(sum,(r-l+1)*val);
   end;
 end;
procedure pushdown(k:longint);
 begin
 with t[k] do
   begin
     if tag=0 then exit;
     update(lch,tag);update(rch,tag);
     tag:=0;
   end;
 end;

procedure build(k,x,y:longint);
 begin
 with t[k] do
  begin
    l:=x;r:=y;mid:=(l+r)>>1;lch:=k<<1;rch:=k<<1+1;tag:=0;
    if l=r then begin sum:=a[l];pf:=a[l]*a[l];exit;end;
    build(lch,l,mid);build(rch,mid+1,r);
    pushup(k);
  end;
 end;
procedure change(k,x,y,z:longint);
 begin
 with t[k] do
  begin
    if (l=x) and (r=y) then begin update(k,z);exit;end;
    pushdown(k);
    if y<=mid then change(lch,x,y,z)
    else if x>mid then change(rch,x,y,z)
    else
       begin
         change(lch,x,mid,z);change(rch,mid+1,y,z);
       end;
    pushup(k);
  end;
 end;
function getsum(k,x,y:longint):int64;
 begin
 with t[k] do
   begin
     if (l=x) and (r=y) then exit(sum);
     pushdown(k);
     if y<=mid then exit(getsum(lch,x,y))
     else if x>mid then exit(getsum(rch,x,y))
     else exit(getsum(lch,x,mid)+getsum(rch,mid+1,y));
   end;
 end;
function getsqr(k,x,y:longint):int64;
 begin
 with t[k] do
   begin
     if (l=x) and (r=y) then exit(pf);
     pushdown(k);
     if y<=mid then exit(getsqr(lch,x,y))
     else if x>mid then exit(getsqr(rch,x,y))
     else exit(getsqr(lch,x,mid)+getsqr(rch,mid+1,y));
   end;
 end;

procedure init;
 begin
   readln(n,m);
   for i:=1 to n do read(a[i]);readln;
   build(1,1,n);
 end;
procedure solvechange;
 begin
   readln(x,y,z);
   change(1,x,y,z);
 end;
function gcd(x,y:int64):int64;
 begin
   if y=0 then exit(x) else exit(gcd(y,x mod y));
 end;
procedure solveaverage;
 begin
   readln(x,y);
   xx:=getsum(1,x,y);yy:=y-x+1;
   z:=gcd(xx,yy);
   if xx=0 then writeln('0/1')
   else writeln(xx div z,'/',yy div z);
 end;
procedure solvefangcha;
 begin
   readln(x,y);
   yy:=y-x+1;
   xx:=yy*getsqr(1,x,y)-sqr(getsum(1,x,y));
   yy:=yy*yy;
   z:=gcd(xx,yy);
   if xx=0 then writeln('0/1')
   else writeln(xx div z,'/',yy div z);
 end;

procedure main;
 begin
   for i:=1 to m do
    begin
      read(ch);
      case ch of
      1:solvechange;
      2:solveaverage;
      3:solvefangcha;
      end;
    end;
 end;

begin
  init;
  main;
end.               

C.皇后游戏

题目：http://www.contesthunter.org/contest/CH%20Round%20%2352%20-%20Thinking%20Bear%20%231%20(NOIP模拟赛)/皇后游戏

题解：不会捉。。。按a排序，骗了30分。。。

代码：

1.我的

const maxn=100000+1000;
var a,b,c:array[0..maxn] of int64;
    ans,sum:int64;
    i,j,n,cs:longint;
    function max(x,y:int64):int64;
     begin
     if x>y then exit(x) else exit(y);
     end;

procedure sort(l,r:longint);
 var i,j:longint;x,y:int64;
 begin
 i:=l;j:=r;x:=c[(i+j)>>1];
 repeat
  while c[i]<x do inc(i);
  while c[j]>x do dec(j);
  if i<=j then
   begin
   y:=a[i];a[i]:=a[j];a[j]:=y;
   y:=b[i];b[i]:=b[j];b[j]:=y;
   y:=c[i];c[i]:=c[j];c[j]:=y;
   inc(i);dec(j);
   end;
 until i>j;
 if i<r then sort(i,r);
 if j>l then sort(l,j);
 end;
procedure init;
 begin
   readln(n);
   for i:=1 to n do readln(a[i],b[i]);
   for i:=1 to n do c[i]:=a[i];
 end;
procedure main;
 begin
   sort(1,n);sum:=0;ans:=0;
   for i:=1 to n do
    begin
     sum:=sum+a[i];
     ans:=max(ans,sum)+b[i];
    end;
   writeln(ans);
 end;

begin
  readln(cs);
  while cs>0 do
   begin
    dec(cs);
    init;
    main;
   end;
end.  

2.标程 也是排序，不过好高大上啊。。。

//#include <cmath>
#include <iostream>
#include <cstdio>
#include <cstring>
#include <string>
#include <cstdlib>
#include <vector>
#include <set>
#include <algorithm>
#define mp make_pair
#define fi first
#define se second
 
using namespace std;

typedef long long int64;
typedef pair<int,int> PII;
const int MAXN=200005;
 
int n;
PII a[MAXN];
int64 dp[MAXN];

inline bool cmp(const PII &x,const PII &y)
{
    return min(x.fi,y.se)<min(x.se,y.fi);
}
 
int main()
{
    int testCase;
    for (scanf("%d",&testCase);testCase;testCase--)
    {
        scanf("%d",&n);
        for (int i=1;i<=n;i++) scanf("%d%d",&a[i].fi,&a[i].se);
        sort(a+1,a+n+1,cmp);
        int64 s=0;
        for (int i=1;i<=n;i++)
        {
            s+=a[i].fi;
            dp[i]=max(s,dp[i-1])+a[i].se;
        }
        cout<<dp[n]<<endl;
    }
    return 0;
}