BZOJ3196: Tyvj 1730 二逼平衡树

3196: Tyvj 1730 二逼平衡树

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 775  Solved: 316
[Submit][Status]

Description

您需要写一种数据结构（可参考题目标题），来维护一个有序数列，其中需要提供以下操作：
1.查询k在区间内的排名
2.查询区间内排名为k的值
3.修改某一位值上的数值
4.查询k在区间内的前驱(前驱定义为小于x，且最大的数)
5.查询k在区间内的后继(后继定义为大于x，且最小的数)

Input

第一行两个数 n,m 表示长度为n的有序序列和m个操作
第二行有n个数，表示有序序列
下面有m行，opt表示操作标号
若opt=1 则为操作1，之后有三个数l,r,k 表示查询k在区间[l,r]的排名
若opt=2 则为操作2，之后有三个数l,r,k 表示查询区间[l,r]内排名为k的数
若opt=3 则为操作3，之后有两个数pos,k 表示将pos位置的数修改为k
若opt=4 则为操作4，之后有三个数l,r,k 表示查询区间[l,r]内k的前驱
若opt=5 则为操作5，之后有三个数l,r,k 表示查询区间[l,r]内k的后继

Output

对于操作1,2,4,5各输出一行，表示查询结果

Sample Input

9 6
4 2 2 1 9 4 0 1 1
2 1 4 3
3 4 10
2 1 4 3
1 2 5 9
4 3 9 5
5 2 8 5

Sample Output

2
4
3
4
9

HINT

 

1.n和m的数据范围：n,m<=50000

2.序列中每个数的数据范围：[0,1e8]

3.虽然原题没有，但事实上5操作的k可能为负数

题解：

需要注意几点：

1.一个数的rank是比它小的数的个数+1

2.要使用正确的二分查找

   在查找区间第k小的时候，相当于在rank数组中查询k，如果k出现了那么返回k最后出现的位置 否则返回一个位置在这个位置插入k后，rank数组仍然有序

   就如上一篇博文中的YES-RIGHT  NO-LEFT类型的二分查找

3.求前驱后继的代码要想好怎么写

   以pred为例，节点为0时返回-inf，关键值<=节点值则到左子树去寻找，否则到右子树并且判断返回值是否为-inf，

  是的话说明右子树为空，而该节点是比关键值小的一个值，没有比它大的了，所以前驱就是该节点

代码：

uses math;
const maxn=50000+1000;inf=1000000000;
type node=record
     l,r,lch,rch,rt,mid:longint;
     end;
var t:array[0..8*maxn] of node;
    l,r,s,w,rnd,v,a:array[0..20*maxn] of longint;
    i,n,m,x,y,z,tot,ch:longint;
procedure pushup(k:longint);
 begin
   s[k]:=s[l[k]]+s[r[k]]+w[k];
 end;
procedure rturn(var k:longint);
 var t:longint;
 begin
   t:=l[k];l[k]:=r[t];r[t]:=k;s[t]:=s[k];pushup(k);k:=t;
 end;
procedure lturn(var k:longint);
 var t:longint;
 begin
   t:=r[k];r[k]:=l[t];l[t]:=k;s[t]:=s[k];pushup(k);k:=t;
 end;
procedure ins(var k,num:longint);
 begin
  if k=0 then
   begin
    inc(tot);k:=tot;v[k]:=num;s[k]:=1;w[k]:=1;l[k]:=0;r[k]:=0;
    rnd[k]:=random(maxlongint);exit;
   end;
  inc(s[k]);
  if num=v[k] then inc(w[k])
  else if num<v[k] then begin ins(l[k],num);if rnd[l[k]]<rnd[k] then rturn(k);end
  else begin ins(r[k],num);if rnd[r[k]]<rnd[k] then lturn(k);end;
 end;
procedure del(var k,num:longint);
 begin
  if v[k]=num then
   begin
    if w[k]>1 then begin dec(w[k]);dec(s[k]);exit;end;
    if l[k]*r[k]=0 then k:=l[k]+r[k]
    else if rnd[l[k]]<rnd[r[k]] then begin rturn(k);del(k,num);end
    else begin lturn(k);del(k,num);end;
    exit;
   end;
  dec(s[k]);
  if num<v[k] then del(l[k],num) else del(r[k],num);
 end;
procedure build(k,x,y:longint);
 var i:longint;
 begin
  with t[k] do
   begin
     l:=x;r:=y;mid:=(l+r)>>1;
     for i:=l to r do ins(rt,a[i]);
     if l=r then exit;
     lch:=k<<1;rch:=k<<1+1;
     build(lch,l,mid);build(rch,mid+1,r);
   end;
 end;
procedure change(k,x,y:longint);
 begin
  with t[k] do
   begin
     del(rt,a[x]);ins(rt,y);
     if l=r then exit;
     if x<=mid then change(lch,x,y)
     else change(rch,x,y);
   end;
 end;
function pred(k,num:longint):longint;
 begin
  if k=0 then exit(-inf);
  if num<=v[k] then pred:=pred(l[k],num)
  else
     begin
      pred:=pred(r[k],num);
      if pred=-inf then pred:=v[k];
     end;
 end;
function succ(k,num:longint):longint;
 begin
  if k=0 then exit(inf);
  if num>=v[k] then succ:=succ(r[k],num)
  else
      begin
       succ:=succ(l[k],num);
       if succ=inf then succ:=v[k];
      end;
 end;
function findpred(k,x,y,z:longint):longint;
 begin
 with t[k] do
  begin
    if (l=x) and (r=y) then exit(pred(rt,z));
    if y<=mid then exit(findpred(lch,x,y,z))
    else if x>mid then exit(findpred(rch,x,y,z))
    else exit(max(findpred(lch,x,mid,z),findpred(rch,mid+1,y,z)));
  end;
 end;
function findsucc(k,x,y,z:longint):longint;
 begin
 with t[k] do
  begin
    if (l=x) and (r=y) then exit(succ(rt,z));
    if y<=mid then exit(findsucc(lch,x,y,z))
    else if x>mid then exit(findsucc(rch,x,y,z))
    else exit(min(findsucc(lch,x,mid,z),findsucc(rch,mid+1,y,z)));
  end;
 end;

function rank(k,num:longint):longint;
 begin
  if k=0 then exit(0);
  if num=v[k] then exit(s[l[k]])
  else if num<v[k] then exit(rank(l[k],num))
  else exit(s[l[k]]+w[k]+rank(r[k],num));
 end;
function query(k,x,y,num:longint):longint;
 begin
  with t[k] do
   begin
    if (l=x) and (r=y) then exit(rank(rt,num));
    if y<=mid then exit(query(lch,x,y,num))
    else if x>mid then exit(query(rch,x,y,num))
    else exit(query(lch,x,mid,num)+query(rch,mid+1,y,num));
   end;
 end;
procedure solverank;
 begin
  readln(x,y,z);
  writeln(query(1,x,y,z)+1);
 end;
procedure solvefind;
 var l,r,mid:longint;
 begin
  readln(x,y,z);
  l:=0;r:=inf;
  while l<=r do
   begin
     mid:=(l+r)>>1;
     if query(1,x,y,mid)+1>z then r:=mid-1 else l:=mid+1;
   end;
 writeln(r);
 end;
procedure solvechange;
 begin
  readln(x,y);
  change(1,x,y);
  a[x]:=y;
 end;
procedure solvepred;
 begin
  readln(x,y,z);
  writeln(findpred(1,x,y,z));
 end;
procedure solvesucc;
 begin
  readln(x,y,z);
  writeln(findsucc(1,x,y,z));
 end;

procedure init;
 begin
  tot:=0;
  readln(n,m);
  for i:=1 to n do read(a[i]);readln;
  build(1,1,n);
 end;
procedure main;
 begin
  for i:=1 to m do
   begin
     read(ch);
     case ch of
     1:solverank;
     2:solvefind;
     3:solvechange;
     4:solvepred;
     5:solvesucc;
     end;
   end;
 end;
begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  init;
  main;
  close(input);close(output);
end.