BZOJ1103: [POI2007]大都市meg

1103: [POI2007]大都市meg

Time Limit: 10 Sec  Memory Limit: 162 MB
Submit: 1145  Solved: 569
[Submit][Status]

Description

在经济全球化浪潮的影响下,习惯于漫步在清晨的乡间小路的邮递员Blue Mary也开始骑着摩托车传递邮件了。不过，她经常回忆起以前在乡间漫步的情景。昔日，乡下有依次编号为1..n的n个小村庄，某些村庄之间有一些双向的土路。从每个村庄都恰好有一条路径到达村庄1（即比特堡）。并且，对于每个村庄，它到比特堡的路径恰好只经过编号比它的编号小的村庄。另外，对于所有道路而言，它们都不在除村庄以外的其他地点相遇。在这个未开化的地方，从来没有过高架桥和地下铁道。随着时间的推移，越来越多的土路被改造成了公路。至今，Blue Mary还清晰地记得最后一条土路被改造为公路的情景。现在，这里已经没有土路了——所有的路都成为了公路，而昔日的村庄已经变成了一个大都市。 Blue Mary想起了在改造期间她送信的经历。她从比特堡出发，需要去某个村庄，并且在两次送信经历的间隔期间,有某些土路被改造成了公路.现在Blue Mary需要你的帮助：计算出每次送信她需要走过的土路数目。（对于公路，她可以骑摩托车；而对于土路，她就只好推车了。）

Input

第一行是一个数n(1 < = n < = 2 50000). 
以下n-1行，每行两个整数a，b（1 < =  a以下一行包含一个整数m（1 < = m < = 2 50000），表示Blue Mary曾经在改造期间送过m次信。 
以下n+m-1行，每行有两种格式的若干信息，表示按时间先后发生过的n+m-1次事件: 
若这行为 A a b(a若这行为 W a, 则表示Blue Mary曾经从比特堡送信到村庄a。

 

Output

有m行，每行包含一个整数，表示对应的某次送信时经过的土路数目。

Sample Input

5
1 2
1 3
1 4
4 5
4
W 5
A 1 4
W 5
A 4 5
W 5
W 2
A 1 2
A 1 3

Sample Output

2
1
0
1

HINT

 

 

Source

题解：

神奇的DFS序！

先DFS，记录前后时间戳l[i],r[i]则区间(l[i],r[i])就表示它的子树

我们add（l[i],1) add (r[i],-1) 则对 l[i]求前缀和就是从这个点到根节点的土路数目

因为如果一进一出 +1 -1正好抵消了！而如果在 i 的子树中就只有+1，就算上这条边了

可以理解为如果从i的父节点进入i，则土路+1，如果从i 回到i 的父节点，土路-1

下面考虑修改，直接add(l[i],-1) add(r[i],1)即可

这正好与之前的操作相反，这样无论在不在 i 的子树内都是 i 节点的贡献都是0，也就代表了这场为了一条公路

需要注意的几个细节：

1.根节点1不用add(l[i],1) add(r[i],-1)，因为1没有父节点，而且从1出发，初始土路数肯定为0

2.修改(x,y)这条路要看谁是谁的儿子，我们可以记录dep来判断，也可以记录fa，总之只需要改掉儿子的信息即可 

ps：这题用树链剖分可以骗到100分（14个测试点），其他略有超时。。。

代码：

{$inline on}
{$M 10000000,0,maxlongint}
const maxn=300000+100;
type node=record
     go,next:longint;
     end;

var  e:array[0..2*maxn] of node;
     head,dep,l,r:array[0..maxn] of longint;
     s:array[0..2*maxn] of longint;
     i,n,x,y,tot,clock:longint;
     ch:char;
     procedure swap(var x,y:longint);inline;
      var t:longint;
      begin
        t:=x;x:=y;y:=t;
      end;
     procedure insert(x,y:longint);inline;
      begin
        inc(tot);
        e[tot].go:=y;e[tot].next:=head[x];head[x]:=tot;
      end;
procedure dfs(x:longint);inline;
 var i,y:longint;
 begin
   inc(clock);l[x]:=clock;
   i:=head[x];
   while i<>0 do
    begin
     y:=e[i].go;
     if dep[y]=0 then
      begin
        dep[y]:=dep[x]+1;
        dfs(y);
      end;
     i:=e[i].next;
    end;
   inc(clock);r[x]:=clock;
 end;
procedure add(x,y:longint);inline;
 begin
   while x<=2*n do
     begin
      inc(s[x],y);
      inc(x,x and (-x));
     end;
 end;
function sum(x:longint):longint;inline;
 begin
   sum:=0;
   while x>0 do
     begin
      inc(sum,s[x]);
      dec(x,x and (-x));
     end;
 end;
procedure init;
 begin
   readln(n);
   for i:=1 to n-1 do begin readln(x,y);insert(x,y);insert(y,x);end;
   dep[1]:=1;
   dfs(1);
   //for i:=1 to n do writeln(i,' ',l[i],' ',r[i],' ',dep[i]);
   for i:=2 to n do begin add(l[i],1);add(r[i],-1);end;
 end;
procedure solveask;inline;
 begin
   readln(x);writeln(sum(l[x]));
 end;
procedure solvechange;inline;
 begin
   readln(x,y);
   if dep[x]<dep[y] then swap(x,y);
   add(l[x],-1);add(r[x],1);
 end;
procedure main;
 begin
   readln;
   while not eof do
    begin
     read(ch);
     case ch of
     'W':solveask;
     'A':solvechange;
     end;
    end;
 end;
begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  init;
  main;
  close(input);close(output);
end.