BZOJ1305: [CQOI2009]dance跳舞

1305: [CQOI2009]dance跳舞

Time Limit: 5 Sec  Memory Limit: 162 MB
Submit: 1314  Solved: 574
[Submit][Status]

Description

一次舞会有n个男孩和n个女孩。每首曲子开始时，所有男孩和女孩恰好配成n对跳交谊舞。每个男孩都不会和同一个女孩跳两首（或更多）舞曲。有一些男孩女孩相互喜欢，而其他相互不喜欢（不会“单向喜欢”）。每个男孩最多只愿意和k个不喜欢的女孩跳舞，而每个女孩也最多只愿意和k个不喜欢的男孩跳舞。给出每对男孩女孩是否相互喜欢的信息，舞会最多能有几首舞曲？

Input

第一行包含两个整数n和k。以下n行每行包含n个字符，其中第i行第j个字符为'Y'当且仅当男孩i和女孩j相互喜欢。

Output

仅一个数，即舞曲数目的最大值。

Sample Input

3 0
YYY
YYY
YYY

Sample Output

3

HINT

 

N<=50 K<=30

 

Source

加强数据By dwellings and liyizhen2

题解：

我是这样想的：

1.因为有和不喜欢的人跳舞，还有和喜欢的人跳舞，所以应该把每个点拆成两个 num[i,1],num[i,2]

2.如果男生i 喜欢 女生 j，那我们连边num[i,1]到num[j,1]否则我们连边 num[i,2]到num[j,2]

3.因为每次都必须有n对，才能算一首曲子，所以我们从小到大枚举答案，当然不用重构图

   每次给每个人只加1的流量，如果某一次发现maxflow<n就退出出，输出 i-1

   至于选择不喜欢的人还是喜欢的人，由最大流决定，所以我们还得应增一个点num[i,3]，由它向num[i,1]连容量为inf的边，num[i,2]连容量为k的边

   每次枚举答案的时候由 s向num[i,3]（男生）连边，num[i,3]（女生）向t连边

4.也就是说num[i,3]是用来限制每一次的流量，必须使得一个男生只能跳一次，一个女生只能和一个男生跳

5. 至于到了下一次的时候上一次新添的边是否应该回边无效化，我也不知道，无效和不无效都能A

代码：

const inf=maxlongint;maxn=5000;maxm=500000;
type node=record
     from,go,next,v:longint;
     end;
var  tot,i,j,n,m,maxflow,l,r,s,t,x,y,cnt:longint;
     h,head,q,cur:array[0..2*maxn] of longint;
     e:array[0..2*maxm] of node;
     num:array[0..2*maxn,1..3] of longint;
     ch:char;
     function min(x,y:longint):longint;
      begin
      if x<y then exit(x) else exit(y);
      end;
procedure ins(x,y,z:longint);
 begin
 inc(tot);
 e[tot].from:=x;e[tot].go:=y;e[tot].v:=z;e[tot].next:=head[x];head[x]:=tot;
 end;
procedure insert(x,y,z:longint);
 begin
 ins(x,y,z);ins(y,x,0);
 end;
function bfs:boolean;
 var i,x,y:longint;
 begin
 fillchar(h,sizeof(h),0);
 l:=0;r:=1;q[1]:=s;h[s]:=1;
 while l<r do
  begin
  inc(l);
  x:=q[l];
  i:=head[x];
  while i<>0 do
   begin
   y:=e[i].go;
   if (e[i].v<>0) and (h[y]=0) then
    begin
     h[y]:=h[x]+1;
     inc(r);q[r]:=y;
    end;
   i:=e[i].next;
   end;
  end;
 exit (h[t]<>0);
 end;
function dfs(x,f:longint):longint;
 var i,y,used,tmp:longint;
 begin
 if x=t then exit(f);
 used:=0;
 i:=cur[x];
 while i<>0 do
  begin
  y:=e[i].go;
  if (h[y]=h[x]+1) and (e[i].v<>0) then
   begin
   tmp:=dfs(y,min(e[i].v,f-used));
   dec(e[i].v,tmp);if e[i].v<>0 then cur[x]:=i;
   inc(e[i xor 1].v,tmp);
   inc(used,tmp);
   if used=f then exit(f);
   end;
  i:=e[i].next;
  end;
 if used=0 then h[x]:=-1;
 exit(used);
 end;
procedure dinic;
 var i:longint;
 begin
 while bfs do
  begin
  for i:=s to t do cur[i]:=head[i];
  inc(maxflow,dfs(s,inf));
  end;
 end;
procedure init;
 begin
 tot:=1;
 readln(n,m);
 for i:=1 to 2*n do
  begin
   inc(cnt);num[i,1]:=cnt;
   inc(cnt);num[i,2]:=cnt;
   inc(cnt);num[i,3]:=cnt;
   if i<=n then
    begin
    insert(num[i,3],num[i,1],inf);
    insert(num[i,3],num[i,2],m);
    end
   else
    begin
    insert(num[i,1],num[i,3],inf);
    insert(num[i,2],num[i,3],m);
    end;
  end;
 s:=0;t:=6*n+1;
 for i:=1 to n do
  begin
   for j:=1 to n do
    begin
    read(ch);
    if ch='Y' then insert(num[i,1],num[j+n,1],1)
    else insert(num[i,2],num[j+n,2],1);
    end;
   readln;
  end;
 end;
procedure main;
 begin
 for i:=1 to n+1 do
   begin
   // for j:=1 to tot do if (e[j].go=t) or (e[j].from=t) then e[j].v:=0;
    for j:=1 to 2*n do if j<=n then insert(s,num[j,3],1) else insert(num[j,3],t,1);
    maxflow:=0;
    dinic;
    if maxflow<>n then break;
   end;
 writeln(i-1);
 end;
begin
 assign(input,'input.txt');assign(output,'output.txt');
 reset(input);rewrite(output);
 init;
 main;
 close(input);close(output);
end.