BZOJ1057: [ZJOI2007]棋盘制作

1057: [ZJOI2007]棋盘制作

Time Limit: 20 Sec  Memory Limit: 162 MB
Submit: 1329  Solved: 664
[Submit][Status]

Description

国际象棋是世界上最古老的博弈游戏之一，和中国的围棋、象棋以及日本的将棋同享盛名。据说国际象棋起源于易经的思想，棋盘是一个8*8大小的黑白相间的方阵，对应八八六十四卦，黑白对应阴阳。而我们的主人公小Q，正是国际象棋的狂热爱好者。作为一个顶尖高手，他已不满足于普通的棋盘与规则，于是他跟他的好朋友小W决定将棋盘扩大以适应他们的新规则。小Q找到了一张由N*M个正方形的格子组成的矩形纸片，每个格子被涂有黑白两种颜色之一。小Q想在这种纸中裁减一部分作为新棋盘，当然，他希望这个棋盘尽可能的大。不过小Q还没有决定是找一个正方形的棋盘还是一个矩形的棋盘（当然，不管哪种，棋盘必须都黑白相间，即相邻的格子不同色），所以他希望可以找到最大的正方形棋盘面积和最大的矩形棋盘面积，从而决定哪个更好一些。于是小Q找到了即将参加全国信息学竞赛的你，你能帮助他么？

Input

第一行包含两个整数N和M，分别表示矩形纸片的长和宽。接下来的N行包含一个N * M的01矩阵，表示这张矩形纸片的颜色（0表示白色，1表示黑色）。

Output

包含两行，每行包含一个整数。第一行为可以找到的最大正方形棋盘的面积，第二行为可以找到的最大矩形棋盘的面积（注意正方形和矩形是可以相交或者包含的）。

Sample Input

3 3
1 0 1
0 1 0
1 0 0

Sample Output

4
6

HINT

 

对于20%的数据，N, M ≤ 80 对于40%的数据，N, M ≤ 400 对于100%的数据，N, M ≤ 2000

 

Source

题解:

h[i]表示 i 向上满足黑白相间的高度

首先可以用单调栈求出 h[i]作为区间最小值的左右范围，然后可以左右各扫一边得出横着最远拓展到哪里满足黑白相间

l 取max，r 取min，更新答案即可

犯了几个sb错误：

1.a[i-1,j]写成a[i,j-1]。。。

2.l 本该取 max，取成了 min。。。

代码：

const maxn=2000+100;
var a:array[0..maxn,0..maxn] of longint;
    h,l,r,sta,l1,l2,r1,r2:array[0..maxn] of longint;
    n,m,i,j,k,ans1,ans2,top,tmp:longint;
    function min(x,y:longint):longint;
     begin
     if x<y then exit(x) else exit(y);
     end;
    function max(x,y:longint):longint;
     begin
     if x>y then exit(x) else exit(y);
     end;

procedure init;
 begin
   readln(n,m);
   fillchar(a,sizeof(a),60);
   for i:=1 to n do
    begin
     for j:=1 to m do read(a[i,j]);
    end;
 end;
procedure main;
 begin
   h[0]:=-1;h[m+1]:=-1;ans1:=0;ans2:=0;
   for i:=1 to n do
    begin
     for j:=1 to m do if a[i,j]=a[i-1,j] xor 1  then inc(h[j]) else h[j]:=1;
     top:=0;
     for j:=1 to m+1 do
      begin
      while (top>0) and (h[j]<h[sta[top]]) do
       begin
       r1[sta[top]]:=j-1;dec(top);
       end;
      inc(top);sta[top]:=j;
      end;
     top:=0;
     for j:=m downto 0 do
      begin
      while (top>0) and (h[j]<h[sta[top]]) do
       begin
       l1[sta[top]]:=j+1;dec(top);
       end;
      inc(top);sta[top]:=j;
      end;
     for j:=1 to m do
       begin
       if a[i,j]<>a[i,j-1] xor 1 then tmp:=j;
       l2[j]:=tmp;
       end;
     for j:=m downto 1 do
       begin
       if a[i,j]<>a[i,j+1] xor 1 then tmp:=j;
       r2[j]:=tmp;
       end;
     for j:=1 to m do
       begin
       l[j]:=max(l1[j],l2[j]);
       r[j]:=min(r1[j],r2[j]);
       ans1:=max(ans1,h[j]*(r[j]-l[j]+1));
       ans2:=max(ans2,sqr(min(h[j],r[j]-l[j]+1)));
       end;
     //for j:=1 to m do writeln(j,' ',l1[j],' ',l2[j],' ',r1[j],' ',r2[j]);
    end;
 writeln(ans2);
 writeln(ans1);
 end;

begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  init;
  main;
  close(input);close(output);
end.