BZOJ1251: 序列终结者

1251: 序列终结者

Time Limit: 20 Sec  Memory Limit: 162 MB
Submit: 2301  Solved: 923
[Submit][Status]

Description

网上有许多题，就是给定一个序列，要你支持几种操作：A、B、C、D。一看另一道题，又是一个序列 要支持几种操作：D、C、B、A。尤其是我们这里的某人，出模拟试题，居然还出了一道这样的，真是没技术含量……这样 我也出一道题，我出这一道的目的是为了让大家以后做这种题目有一个“库”可以依靠，没有什么其他的意思。这道题目 就叫序列终结者吧。 【问题描述】 给定一个长度为N的序列，每个序列的元素是一个整数（废话）。要支持以下三种操作： 1. 将[L,R]这个区间内的所有数加上V。 2. 将[L,R]这个区间翻转，比如1 2 3 4变成4 3 2 1。 3. 求[L,R]这个区间中的最大值。 最开始所有元素都是0。

Input

第一行两个整数N，M。M为操作个数。 以下M行，每行最多四个整数，依次为K，L，R，V。K表示是第几种操作，如果不是第1种操作则K后面只有两个数。

Output

对于每个第3种操作，给出正确的回答。

Sample Input

4 4
1 1 3 2
1 2 4 -1
2 1 3
3 2 4

Sample Output

2
【数据范围】
N<=50000，M<=100000。

HINT

 

Source

Splay

题解：

这题还没有维护数列BT，就敢叫序列终结者？

注意标记的传递和边界的处理，专门增加的两个节点不能影响到答案，0 也不能影响到答案

代码：

{$inline on}
{$M 1000000000,0,maxlongint}
const maxn=100000+1000;
var s,fa,mx,tag,v,id,a:array[0..maxn] of longint;
    rev:array[0..maxn] of boolean;
    c:array[0..maxn,0..1] of longint;
    i,j,n,m,x,y,z,tot,rt,now,l,r:longint;
    ch:longint;
    procedure swap(var x,y:longint);inline;
     var t:longint;
     begin
      t:=x;x:=y;y:=t;
     end;
    function max(x,y:longint):longint;inline;
     begin
      if x>y then exit(x) else exit(y);
     end;
procedure pushup(x:longint);inline;
 begin
  l:=c[x,0];r:=c[x,1];
  s[x]:=s[l]+s[r]+1;
  mx[x]:=max(v[x],max(mx[l],mx[r]));
 end;
procedure rever(x:longint);inline;
 begin
  if x=0 then exit;
  rev[x]:=not(rev[x]);
  swap(c[x,0],c[x,1]);
 end;
procedure change(x,val:longint);inline;
 begin
  if x=0 then exit;
  inc(tag[x],val);
  inc(v[x],val);
  inc(mx[x],val);
 end;
procedure pushdown(x:longint);inline;
 var l,r:longint;
 begin
  l:=c[x,0];r:=c[x,1];
  if tag[x]<>0 then
    begin
     change(l,tag[x]);change(r,tag[x]);
     tag[x]:=0;
    end;
  if rev[x] then
    begin
     rever(l);rever(r);
     rev[x]:=false;
    end;
 end;
procedure rotate(x:longint;var k:longint);inline;
 var y,z,l,r:longint;
 begin
  y:=fa[x];z:=fa[y];
  l:=ord(c[y,1]=x);r:=l xor 1;
  if y=k then k:=x else c[z,ord(c[z,1]=y)]:=x;
  fa[x]:=z;fa[y]:=x;fa[c[x,r]]:=y;
  c[y,l]:=c[x,r];c[x,r]:=y;
  pushup(y);pushup(x);
 end;
procedure splay(x:longint;var k:longint);inline;
 var y,z:longint;
 begin
  while x<>k do
   begin
    y:=fa[x];z:=fa[y];
    if y<>k then
     if (c[z,0]=y) xor (c[y,0]=x) then rotate(x,k)
     else rotate(y,k);
    rotate(x,k);
   end;
 end;
procedure build(l,r,f:longint);inline;
 var x,y,z,mid:longint;
 begin
  if l>r then exit;
  mid:=(l+r)>>1;
  x:=id[mid];y:=id[f];
  v[x]:=a[mid];
  c[y,ord(mid>f)]:=x;fa[x]:=y;
  if l=r then
    begin
     s[x]:=1;mx[x]:=v[x];
     exit;
    end;
  build(l,mid-1,mid);build(mid+1,r,mid);
  pushup(x);
 end;
function find(x,rank:longint):longint;inline;
 var l,r:longint;
 begin
  pushdown(x);
  l:=c[x,0];r:=c[x,1];
  if s[l]+1=rank then exit(x)
  else if s[l]>=rank then exit(find(l,rank))
  else exit(find(r,rank-s[l]-1));
 end;
procedure split(l,r:longint;var x,y:longint);inline;
 begin
  x:=find(rt,l);y:=find(rt,r);
  splay(x,rt);splay(y,c[x,1]);
 end;
procedure main;
 begin
  readln(n,m);
  for i:=1 to n+2 do id[i]:=i;
  fillchar(a,sizeof(a),0);
  a[1]:=-maxlongint;a[n+2]:=-maxlongint;
  mx[0]:=-maxlongint;
  build(1,n+2,0);rt:=(n+3)>>1;
  for i:=1 to m do
   begin
    read(ch);
    case ch of
    1:begin
      readln(l,r,z);split(l,r+2,x,y);
      change(c[y,0],z);
      end;
    2:begin
      readln(l,r);split(l,r+2,x,y);
      rever(c[y,0]);
      end;
    3:begin
      readln(l,r);split(l,r+2,x,y);
      writeln(mx[c[y,0]]);
      end;
    end;
   end;
 end;
begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  main;
  close(input);close(output);
end.