BZOJ1221: [HNOI2001] 软件开发

1221: [HNOI2001] 软件开发

Time Limit: 10 Sec  Memory Limit: 162 MB
Submit: 503  Solved: 265
[Submit][Status]

Description

某软件公司正在规划一项n天的软件开发计划，根据开发计划第i天需要ni个软件开发人员，为了提高软件开发人员的效率，公司给软件人员提供了很多的服务，其中一项服务就是要为每个开发人员每天提供一块消毒毛巾，这种消毒毛巾使用一天后必须再做消毒处理后才能使用。消毒方式有两种，A种方式的消毒需要a天时间，B种方式的消毒需要b天（b>a），A种消毒方式的费用为每块毛巾fA, B种消毒方式的费用为每块毛巾fB，而买一块新毛巾的费用为f（新毛巾是已消毒的，当天可以使用）；而且f>fA>fB。公司经理正在规划在这n天中，每天买多少块新毛巾、每天送多少块毛巾进行A种消毒和每天送多少块毛巾进行B种消毒。当然，公司经理希望费用最低。你的任务就是：为该软件公司计划每天买多少块毛巾、每天多少块毛巾进行A种消毒和多少毛巾进行B种消毒，使公司在这项n天的软件开发中，提供毛巾服务的总费用最低。

Input

第1行为n,a,b,f,fA,fB. 第2行为n1，n2，……，nn. （注：1≤f,fA,fB≤60，1≤n≤1000）

Output

最少费用

Sample Input

4 1 2 3 2 1
8 2 1 6

Sample Output

38

HINT

 

Source

最小费用最大流

题解：

我想说这题与餐巾计划有区别吗？。。。

题目坑爹，也没说可以留到下一天洗，害我WA一次

代码：

const inf=maxlongint;
type node=record
     from,go,next,v,c:longint;
     end;
var e:array[0..2000000] of node;
    pre,head,q,d:array[0..1000000] of longint;
    v:array[0..1000000] of boolean;
    i,j,n,m,maxf,s,t,l,r,mincost,tot,a,b,fa,fb,f,x:longint;
function min(x,y:longint):longint;
 begin
 if x<y then exit(x) else exit(y);
 end;
procedure ins(x,y,z,w:longint);
 begin
 inc(tot);
 with e[tot] do
  begin
  from:=x;go:=y;v:=z;c:=w;next:=head[x];head[x]:=tot;
  end;
 end;
procedure insert(x,y,z,w:longint);
 begin
 ins(x,y,z,w);ins(y,x,0,-w);
 end;
function spfa:boolean;
 var i,x,y:longint;
 begin
 fillchar(v,sizeof(v),false);
 for i:=s to t do d[i]:=inf;
 l:=0;r:=1;q[1]:=s;d[s]:=0;v[s]:=true;
 while l<r do
  begin
  inc(l);
  x:=q[l];v[x]:=false;
  i:=head[x];
  while i<>0 do
   begin
   y:=e[i].go;
   if (e[i].v<>0) and (d[x]+e[i].c<d[y]) then
    begin
    d[y]:=d[x]+e[i].c;
    pre[y]:=i;
    if not(v[y]) then
     begin
     v[y]:=true;
     inc(r);
     q[r]:=y;
     end;
    end;
   i:=e[i].next;
  end;
 end;
 exit(d[t]<>inf);
 end;
procedure mcf;
 var i,tmp:longint;
 begin
 mincost:=0;
 while spfa do
  begin
  tmp:=inf;
  i:=pre[t];
  while i<>0 do
   begin
   tmp:=min(tmp,e[i].v);
   i:=pre[e[i].from];
   end;
  inc(mincost,tmp*d[t]);
  i:=pre[t];
  while i<>0 do
   begin
   dec(e[i].v,tmp);
   inc(e[i xor 1].v,tmp);
   i:=pre[e[i].from];
   end;
  end;
 end;
procedure init;
 begin
 tot:=1;
 readln(n,a,b,f,fa,fb);
 s:=0;t:=2*n+1;
 for i:=1 to n do
  begin
  read(x);
  insert(i+n,t,x,0);
  insert(s,i,x,0);
  insert(s,i+n,x,f);
  if i+1<=n then insert(i,i+1,inf,0);
  if i+a+1<=n then insert(i,i+a+n+1,inf,fa);
  if i+b+1<=n then insert(i,i+b+n+1,inf,fb);
  end;

 end;
procedure main;
 begin
 mincost:=0;
 mcf;
 writeln(mincost);
 end;
begin
 assign(input,'input.txt');assign(output,'output.txt');
 reset(input);rewrite(output);
 init;
 main;
 close(input);close(output);
end.