vijos1603迷宫

这题的构思太巧妙了：

经典题目8 给定一个有向图，问从A点恰好走k步（允许重复经过边）到达B点的方案数mod p的值
    把给定的图转为邻接矩阵，即A(i,j)=1当且仅当存在一条边i->j。令C=A*A，那么C(i,j)=ΣA(i,k)*A(k,j)，实际上就等于从点i到点j恰好经过2条边的路径数（枚举k为中转点）。类似地，C*A的第i行第j列就表示从i到j经过3条边的路径数。同理，如果要求经过k步的路径数，我们只需要二分求出A^k即可。

代码：

type matrix=array[1..55,1..55] of int64;
var a,b:matrix;
    i,j,n,m,s,t,p:longint;
function mo(x:int64):int64;
 begin
   mo:=x mod p;
 end;
procedure init;
 begin
   readln(n);
   for i:=1 to n do
    begin
      for j:=1 to n do read(a[i,j]);
      readln;
    end;
   fillchar(b,sizeof(b),0);
   for i:=1 to n do b[i,i]:=1;
   readln(m,s,t,p);
 end;
procedure mul(var x,y,z:matrix);
 var t:matrix;
     i,j,k:longint;
 begin
   fillchar(t,sizeof(t),0);
   for i:=1 to n do
    for j:=1 to n do
     for k:=1 to n do
      t[i,j]:=mo(t[i,j]+x[i,k]*y[k,j]);
   z:=t;
 end;
procedure ksm(cs:longint);
 begin
   while cs<>0 do
    begin
      if cs and 1=1 then mul(a,b,b);
      cs:=cs>>1;
      mul(a,a,a);
    end;
 end;
procedure main;
 begin
   ksm(m);
   writeln(b[s,t]);
 end;
begin
  init;
  main;
end.