ZJOI2010网络扩容

无限orz hzwer神牛……

第一问很简单，按数据建图，然后一遍最大流算法即可。

    第二问则需要用最小费用最大流算法，主要是建图，那么可以从第一问的残留网络上继续建图，对残留网络上的每一条边建一条容量是∞费用是w的边（反向弧容量为0，费用为-w），然后建一个超级源点，从超级源向1建一条容量为k，费用为0的边，对这个图进行最小费用最大流算法。

    最小费用最大流操作：

    1.首先要对于这道题的图来说，有的边需要花费费用，而有的又不用，而不用扩容的边费用为0，需要扩容的边费用为w，容量无限，这就是本题这样建图的原因。

    2.对于残留网络进行费用最短路SPFA算法，不用扩容的边一定会选费用为0的边，然后记录路径，找最小容量对可行路进行增流，更新ans

——hzwer

uses math;
const inf=maxlongint;
type node=record
     from,go,v,c,t,next:longint;
     end;
var  i,n,m,k,t,u,v,w,c,s,cnt,ans:longint;
     q,first,from,h,cur,d:array[0..10000] of longint;
     e:array[0..50000] of node;
procedure ins(u,v,w,c:longint);
 begin
   inc(cnt);
   e[cnt].go:=v;e[cnt].from:=u;
   e[cnt].v:=w;e[cnt].t:=c;
   e[cnt].next:=first[u];first[u]:=cnt;
 end;
procedure insert(u,v,w,c:longint);
 begin
   ins(u,v,w,c);ins(v,u,0,-c);
 end;
procedure ins2(u,v,w,c:longint);
 begin
   inc(cnt);
   e[cnt].go:=v;e[cnt].from:=u;
   e[cnt].v:=w;e[cnt].c:=c;
   e[cnt].next:=first[u];first[u]:=cnt;
 end;
procedure insert2(u,v,w,c:longint);
 begin
   ins2(u,v,w,c);ins2(v,u,0,-c);
 end;
function bfs:boolean;
 var head,tail,i,x,y:longint;
   begin
     head:=0;tail:=1;fillchar(h,sizeof(h),0);
     q[1]:=s;h[s]:=1;
     while head<tail do
      begin
        inc(head);
        x:=q[head];
        i:=first[x];
        while i<>0 do
         begin
           y:=e[i].go;
           if (e[i].v<>0) and (h[y]=0) then
            begin
              h[y]:=h[x]+1;
              inc(tail);
              q[tail]:=y;
            end;
           i:=e[i].next;
         end;
      end;
   exit(h[t]<>0);
   end;
function dfs(x,f:longint):longint;
 var  i,tmp,used,y:longint;
   begin
   if x=t then exit(f);
   tmp:=0;used:=0;
   i:=cur[x];
   while i<>0 do
     begin
      y:=e[i].go;
      if (e[i].v<>0) and (h[y]=h[x]+1) then
       begin
         tmp:=dfs(y,min(f-used,e[i].v));
         dec(e[i].v,tmp);
         inc(e[i xor 1].v,tmp);
         inc(used,tmp);
         if e[i].v<>0 then cur[x]:=i;
         if used=f then exit(f);
       end;
      i:=e[i].next;
     end;
   if used=0 then h[x]:=-1;
   exit(used);
   end;
procedure dinic;
 begin
   while bfs do
    begin
      for i:=1 to n do cur[i]:=first[i];
      inc(ans,dfs(s,inf));
    end;
 end;
procedure build;
 var tmp:longint;
 begin
 tmp:=cnt;
 for i:=2 to cnt do
   if i and 1=0 then insert2(e[i].from,e[i].go,inf,e[i].t);
 end;
function spfa:boolean;
 var i,x,y,head,tail:longint;
      v:array[0..10000] of boolean;
   begin
    head:=0;tail:=1;
    for i:=1 to n do d[i]:=inf;
    fillchar(v,sizeof(v),false);
    q[1]:=0;d[0]:=0;v[i]:=true;
    while head<tail do
     begin
      inc(head);
      x:=q[head]; v[x]:=false;
      i:=first[x];
      while i<>0 do
       begin
        y:=e[i].go;
        if (e[i].v>0) and (d[x]+e[i].c<d[y]) then
         begin
           d[y]:=d[x]+e[i].c;
           from[y]:=i;
           if not(v[y]) then
            begin
              inc(tail);
              q[tail]:=y;
              v[y]:=true;
            end;
         end;
        i:=e[i].next;
       end;
     end;
   exit(d[n]<>inf);
   end;
procedure mcf;
 var i,x:longint;
   begin
   x:=inf;
   i:=from[n];
   while i<>0 do
     begin
      x:=min(x,e[i].v);
      i:=from[e[i].from];
     end;
   i:=from[n];
   while i<>0 do
     begin
      dec(e[i].v,x);
      inc(e[i xor 1].v,x);
      i:=from[e[i].from];
     end;
   inc(ans,x*d[n]);
   end;
procedure main;
 begin
   cnt:=1;
   readln(n,m,k);
   for i:=1 to m do
    begin
      readln(u,v,w,c);
      insert(u,v,w,c);
    end;
   ans:=0;
   s:=1;t:=n;
   dinic;
   write(ans,' ');
   ans:=0;
   build;
   ins(0,1,k,0);
   while spfa do mcf;
   writeln(ans);
 end;
begin
  main;
end.