文件保护.bat

写了个文件保护的批处理，用于简单的保护移动硬盘中的exe文件

 

 

@echo off
mode con cols=40 lines=25
title 文件保护 v1.0 - by zhouyou96
color 0e

::set bh_dir=%~pd0 
set bh_dir=%cd%

:start
cls
echo  --------------------------------------
echo              文件保护 v1.0
echo       作者：zhouyou96 QQ:191458000
echo  --------------------------------------
echo  　　为了防止移动硬盘中的文件中毒，可以
echo  通过简单的将“.exe”文件重命名为“.exe
echo  .保护”达到保护的目的。
echo.
echo  1.后面加“.保护”；
echo  2.将“.保护”去掉；
echo  3.向操作系统注册“.保护”文件；
echo  4.从系统中反注册“.保护”文件；
echo  5.退出
echo.
echo  正在操作目录：
echo  %bh_dir%
echo.



:cho
set choice=
set /p choice=请选择：
if not "%choice%"=="" set choice=%choice:~0,1%
if "%choice%"=="1" goto pro
if "%choice%"=="2" goto unpro
if "%choice%"=="3" goto regbh
if "%choice%"=="4" goto unregbh
if "%choice%"=="5" goto end
echo.
echo      ==请选择1~5，按任意键重选!!!== 
pause>nul
goto start



:pro
for /r %bh_dir% %%i in (*.exe;*.dll) do (
  cls
  echo      ==正在执行，后面加“.保护”  ==
  echo  正在处理：%%i
  ren "%%i" "%%~nxi.保护"
)
cls
echo.
echo      ==后面加“.保护”，操作完成。==
echo      ==      按任意键继续         ==
pause>nul
goto start



:unpro
for /r %bh_dir% %%i in (*.保护) do (
  cls
  echo      ==正在执行，将“.保护”去掉”  ==
  echo  正在处理：%%i
  ren "%%i" "%%~ni"
)
cls
echo.
echo      ==将“.保护”去掉，操作完成。== 
echo      ==      按任意键继续         ==
pause>nul
goto start


:changedir
echo.
echo      ==暂未实现== 
pause>nul
goto start

cls
echo.
echo      ==      按任意键继续         ==
pause>nul
goto start


:regbh
copy "%0" "%windir%\bh.bat"
assoc .保护=受保护的文件
ftype 受保护的文件="%windir%\bh.bat" %1
cls
echo.
echo   ==已向操作系统注册“.保护”文件。== 
echo   在cmd命令模式下运行bh以保护当前目录
echo   ==        按任意键继续           ==
pause>nul
goto start


:unregbh
del "%windir%\bh.bat" /f
assoc .保护=
ftype 受保护的文件=
cls
echo.
echo   ==已从系统中反注册“.保护”文件。== 
echo   ==        按任意键继续           ==
pause>nul
goto start

:end
exit

 

下载批处理文件： 点击下载