达梦数据库中使用find_in_set()函数

本文转载自Allyn博客（http://www.allyns.cn）：http://www.allyns.cn/info/102?eqid=c1f67a7a0001c94d0000000364619de7

 

在日常开发过程中，我遇到了这样一个问题，我在使用数据库实现自定义流程的时候，由于审批人可以是多个用户，所以用字符串形式用逗号分隔存储用户id，如下图所示字符assignee

这里我用户id使用的uuid，但是我有一些内置用户id使用了常见的普通数字，因为查询的时候我直接使用的like模糊匹配，所以导致我再获取需要本人审批的流程的时候，内置用户常常会获取到很多不属于他的流程，通过查询一些文档，了解到了find_in_set函数。

mysql手册中find_in_set函数的语法：

FIND_IN_SET(str,strlist)

str 要查询的字符串

strlist 字段名 参数以”,”分隔 如 (1,2,6,8)

查询字段(strlist)中包含(str)的结果，返回结果为null或记录

假如字符串str在由N个子链组成的字符串列表strlist 中，则返回值的范围在 1 到 N 之间。 一个字符串列表就是一个由一些被 ‘,' 符号分开的子链组成的字符串。如果第一个参数是一个常数字符串，而第二个是type SET列，则FIND_IN_SET() 函数被优化，使用比特计算。 如果str不在strlist 或strlist 为空字符串，则返回值为 0 。如任意一个参数为NULL，则返回值为 NULL。

这个函数能够完美的解决我上面遇到的问题，但是因为国产化的原因需要使用达梦数据库，在达梦数据库中使用会提示没有该函数，这个时候我们就需要自定义函数

create or replace FUNCTION FIND_IN_SET(piv_str1 varchar2, piv_str2 varchar2, p_sep varchar2 := ',')  
    RETURN NUMBER IS  
      l_idx    number:=0; -- 用于计算piv_str2中分隔符的位置  
      str      varchar2(500);  -- 根据分隔符截取的子字符串  
      piv_str  varchar2(500) := piv_str2; -- 将piv_str2赋值给piv_str  
      res      number:=0; -- 返回结果  
      res_place      number:=0;-- 原字符串在目标字符串中的位置  
    BEGIN  
    -- 如果字段是null 则返回0  
    IF piv_str2 IS NULL THEN  
      RETURN res;  
    END IF;  
    -- 如果piv_str中没有分割符，直接判断piv_str1和piv_str是否相等，相等 res_place=1  
    IF instr(piv_str, p_sep, 1) = 0 THEN  
       IF piv_str = piv_str1 THEN  
          res_place:=1;  
          res:= res_place;  
       END IF;  
    ELSE  
     -- 循环按分隔符截取piv_str  
    LOOP  
        l_idx := instr(piv_str,p_sep);  
        --  
        res_place := res_place + 1;  
        -- 当piv_str中还有分隔符时  
          IF l_idx > 0 THEN  
          -- 截取第一个分隔符前的字段str  
             str:= substr(piv_str,1,l_idx-1);  
             -- 判断 str 和piv_str1 是否相等，相等则结束循环判断  
             IF str = piv_str1 THEN  
               res:= res_place;  
               EXIT;  
             END IF;  
            piv_str := substr(piv_str,l_idx+length(p_sep));  
          ELSE  
          -- 当截取后的piv_str 中不存在分割符时，判断piv_str和piv_str1是否相等，相等 res=res_path  
            IF piv_str = piv_str1 THEN  
               res:= res_place;  
            END IF;  
            -- 无论最后是否相等，都跳出循环  
            EXIT;  
          END IF;  
     END LOOP;  
     -- 结束循环  
     END IF;  
     -- 返回res  
     RETURN res;  
    END FIND_IN_SET;
/
commit;

 

这里要非常注意的一点，一定不能漏掉后面的/符号，这个/表示自定义函数结束，然后commit提交。

然后我们就能在达梦数据库中正常使用FIND_IN_SET函数啦