SQL处理分割字符串

建一个表值函数，如下：
USE [LMS]
GO
/****** Object:  UserDefinedFunction [dbo].[f_split]    Script Date: 2013/8/26 16:04:37 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
 ALTER FUNCTION [dbo].[f_split]
 (
     @strText varchar(3000),--待分离的原字符串
     @strSplit varchar(100)--分隔符
 )
 RETURNS @temp Table
 (
     ID int IDENTITY PRIMARY KEY,
     Code varchar(1000)
 )
 AS
 BEGIN
     Declare @intLen int --用来存储待分离原字符串长度
     Declare @intSplitLen int --分隔符长度
     Declare @intIndex int --用来存储分离字符串在原字符串的位置
    Declare @strVal varchar(1000)--用来存储分离出来后的字符串
     --获取原字符串的长度
    Set @intLen = LEN(RTRIM(LTRIM(@strText)))
     Set @intSplitLen = LEN(RTRIM(LTRIM(@strSplit)))
     --原字符串不为空，才继续分离
     If(@intLen > 0)
     Begin
         --循环原字符串，直至原字符串被分离完毕
         While CHARINDEX(@strSplit,@strText)>0
         Begin
             --获取分离字符串在原字符串的位置
             Set @intIndex = CHARINDEX(@strSplit,@strText)
             --获取分离出的字符串，并插入表中
             Set @strVal = RTRIM(LTRIM(LEFT(@strText,@intIndex-1)))
             if(LEN(@strVal)>0)
             Begin
                 Insert Into @temp (Code) values(@strVal)
             End
             --分离后，将分离出的字符串（包括分隔符）从原字符串中删除
             Set @strText = Substring(@strText,@intIndex+@intSplitLen,@intLen-@intIndex)
             --重新设置原字符串的长度
             Set @intLen = LEN(@strText)
         End
         --如果分离后的原字符串依然不为空，则也应该插入表中
         if(LEN(RTRIM(LTRIM(@strText)))>0)
         Begin
             Insert Into @temp (Code) values(@strText)
         End
     End
     return
end

调用方法：
DECLARE @BOStateIDs VARCHAR(100)    
SET @BOStateIDs='1,4,5'

CREATE TABLE #TempIDs(ID INT)
INSERT INTO #TempIDs
SELECT  code
FROM    [dbo].[f_split](@BOStateIDs, ',')

select * from BOBasicInfo where BOStatusID IN(
SELECT ID FROM #TempIDs
)