Shadow Mapping 的原理与实践（二）

3) 定义并生成Shadow Map纹理

texture2D Lamp0ShadowMapColor : RENDERCOLORTARGET
<
      float2 ViewPortRatio = {1.0,1.0};
      int MipLevels = 1;
      string Format = "A8R8G8B8" ;
>;

sampler2D Lamp0ShadowMapSampler = sampler_state {
      Texture = <Lamp0ShadowMapColor>;
      FILTER = MIN_MAG_MIP_LINEAR;
      AddressU = Clamp;
      AddressV = Clamp;
};

    第3行的作用是使生成的Shadaow Map纹理大小与渲染窗口自动保持一致，这样可以很方便地观察到Shadow Map纹理大小改变时，对最终生成的阴影效果的影响。 

 

float4x4 matWorld : World;
float4x4 matView : View;
float4x4 matProject : Projection;

struct SourceData
{
    float3 pos3 : POSITION;
    float4 n : NORMAL;
};

struct VertexOutput
{
    float4 pos4 : POSITION;

    float4 rpos4 : TEXCOORD3;
    float4 n : NORMAL;
    
    float4 lpos4 : TEXCOORD2;
    float4 ldirt4 : TEXCOORD6;
    float4 uvd : TEXCOORD5;
};

static float4x4 matLightView = LightViewMat(Lamp0Point, Lamp0LookAt); 
static float4x4 matLightProj = LightProjcetMat();

VertexOutput makeShadowVS(SourceData vData)
{
    VertexOutput vOut = (VertexOutput)0;
    
    float4x4 matTmp = mul(matWorld, matLightView);
    matTmp = mul(matTmp, matLightProj);
    
    
    float4 coordCVV = mul(float4(vData.pos3.xyz, 1.0f), matTmp);
    
    float4 m = 1/coordCVV.w;

    vOut.pos4.xyz = m*coordCVV.xyz;
    vOut.pos4.w = 1.0f;
    
    vOut.lpos4 = vOut.pos4;
    vOut.lpos4.z *= fat;
    
    return vOut;
}

float4 makeShadowPS(VertexOutput In) : COLOR 
{    
    return float4(In.lpos4.z, 0, 0, 1);
}

       在生成纹理时，将Z-Buffer Test 设为Enable状态，这样就可以保证纹理中保存的深度值始终是离光源最近的那个点的。另外，可以修改上段代码第5行的纹理像素格式，就能方便地得到更精确的深度值。

 

4) 使用Shadow Map纹理生成阴影

      以图一为例，直观来看，生成阴影前应该先将相应观察平面S上的像素对应的空间点（如b'对应的b）的位置计算出来，再用之前生成的Light Space的matLightView和matLightProj把点b投射到平面H上。这样就需要进行从b'到b的变换，很显然观察窗口S的透视矩阵的逆矩阵是存在的。但实际上还有更简易的做法：

VertexOutput useShadowVS(SourceData vData)
{
    VertexOutput v = (VertexOutput)0;
    v.pos4 = mul(float4(vData.pos3, 1.0f), matWorldViewProj);
    

    v.n = mul(float4(vData.n.xyz, 0.0f), matWorld);
    v.n = normalize(v.n);
    v.rpos4 = mul(float4(vData.pos3, 1.0f), matWorld);
        
    float3 vLightDirect = Lamp0Point - v.rpos4.xyz;
    vLightDirect = normalize(vLightDirect);
    v.ldirt4 = float4(vLightDirect, 0.0f);
    
    float4x4 matTmp = mul(matWorld, matLightView);
    matTmp = mul(matTmp, matLightProj);
    
    float4 lightCVV = mul(float4(vData.pos3, 1.0f), matTmp);
    lightCVV.z -= 0.1f;
    
    float m = 1/lightCVV.w;
    lightCVV.xyz = m*lightCVV.xyz;
    lightCVV.w = 1.0f;
    
    v.lpos4 = lightCVV;
    
    
    float2 uv = (float2)0;
    uv.x = (1.0f+v.lpos4.x)/2.0f;
    uv.y = (1.0f-v.lpos4.y)/2.0f;
    v.uvd.xy = uv;
    v.uvd.z = v.lpos4.z;
    
    return v;
}


float4 useShadowPS(VertexOutput v) : COLOR
{

    float2 uv = v.uvd.xy;
    float dep = v.uvd.z;
    
    float3 samplerCol = (float3)0;
    float c = -1;
    float tmpLm = 0.0f;
    
    float3 sdp = tex2D(Lamp0ShadowMapSampler, uv).rgb;    
    if( dep < sdp.x )
    {
        tmpLm = 1.0f;
    }
    float fall = 1.0/dot(v.ldirt4.xyz, v.ldirt4.xyz);
    
    float3 ld = v.ldirt4.xyz;
    float3 n = v.n;
    float diffuse = dot(ld, n);
    float3 col = float3(1,1,1);
    float linf = 0.8f;
    //col = diffuse * col;
    
    tmpLm = (tmpLm)*diffuse*fall*linf;
    col = tmpLm * col;

    return float4(col, 1);
}

       第15到第32行，直接计算出每一个顶点在Light Space投影平面上的点的x、y、 z坐标值；在进入到观察者投影变换时，可见像素的x、y、z坐标就可以据此通过插值得到。这样做好处是，避免计算透视变换的逆运算，能使代码更简洁，不足之处是增加了大量多余的运算。        

       第19行，对lightCVV的z值做了一个偏移运算，作用是校正浮点运算可能出现的误差。以图一中的点b为例，由于基于浮点数的空间变换运算会出现计算误差，因此位于W表面上的b点经投影变换后，本应等于Z-Buffer中相应像素的深度值，有可能变得大于此值，从而导致其后的逻辑判断出错（第49行），所以需要对运算结果做一个误差校正。更一般的做法是将lightCVV乘以一个事先设置好的误差校正矩阵。

       第53行，计算光照强度衰减因子（与距离的平方成反比）。初始光照强度在第59行设定。