Advanced Installer打包MySQL

一.精简mysql

Mysql数据库比较大，可以进行精简。这样可以减少mysql打包后的大小。

精简方案：(该方案针对绿色解压版的mysql)

1：只保留，share，bin

2:：删除BIN下面除以下三个文件之外的所有文件：

　　libmysql.dll(MYSQL5中的文件,若有则保留没有也没事)

　　mysqladmin.exe

　　Mysqld.exe（服务）

Mysql.exe（用于执行部分命令）

3：删除Share目录下除以下目录外的所有目录charsets，english

4：精简后的文件结构为

Mysql

|--bin

|--share

二.准备一键安装mysql批处理文件(MySql安装.bat)

@setlocal enabledelayedexpansion
@echo off
color f0
title MYSQL一键安装
 
set basedir=%~dp0
set bin=%~dp0\bin
cd /d %~dp0
if exist !bin!\mysqld.exe (
rem 写入配置
>my.ini echo [mysqld]
>>my.ini echo port=3306
>>my.ini echo basedir=!basedir!
>>my.ini echo datadir=!basedir!\Data
>>my.ini echo log-error=!basedir!\Logs.log
>>my.ini echo max_connections=200
>>my.ini echo max_connect_errors=10
>>my.ini echo character-set-server=utf8mb4
>>my.ini echo default-storage-engine=INNODB
>>my.ini echo default_authentication_plugin=mysql_native_password
>>my.ini echo local_infile=ON
>>my.ini echo.
>>my.ini echo [mysql]
>>my.ini echo default-character-set=utf8mb4
>>my.ini echo local_infile=ON
>>my.ini echo.
>>my.ini echo [client]
>>my.ini echo port=3306
>>my.ini echo default-character-set=utf8mb4
 
rem 添加环境变量
echo 开始检查环境变量...
echo.
for /f "tokens=2*" %%i ^
in ('reg query "HKLM\SYSTEM\ControlSet001\Control\Session Manager\Environment" /v Path^|findstr /i "path"') ^
do (set "p=%%j")
for /f "tokens=*" %%a in ('echo !p! ^| find /i "!bin!"') do (set flag=1)
if not defined flag (
echo 开始添加环境变量
setx Path "!p!;!bin!" /M | find "成功" && echo 环境变量添加成功
set p=!Path!
) else (echo 环境变量已存在，无需设置。)
echo.
 
rem 初始化 --console
cd !bin!
 
>!basedir!\Logs.log echo --------初始化数据库开始--------
 
echo 开始初始化数据库
 
mysqld --initialize-insecure
 
>>!basedir!\Logs.log echo --------初始化数据库结束--------
 
rem 安装服务
echo 开始安装服务
mysqld --install MySQL | find "successfully" && echo 服务安装成功
echo.
rem 启动服务
echo 开始启动MYSQL服务
net start MySQL
echo. 
 
mysql -u root -e "ALTER USER 'root'@'localhost' IDENTIFIED WITH mysql_native_password BY 'root@123'";
 
echo 安装完成
) else (
echo 请将本工具放在解压后的MYSQL根目录下再打开
)
 
pause >nul

　　若需要在安装mysql数据库之后，创建数据库并添加数据

则在MySql安装.bat中的 echo 安装完成之后添加如下代码

cd /d %basedir%
set CurBatDir=%cd%/Main.bat
if exist "%CurBatDir%" (call "%CurBatDir%") else (echo 没有找到"%CurBatDir%")

　准备好Main.bat、创建mis数据库.bat、创建三段码数据库.bat

Main.bat

@echo off
 
cd /d %~dp0
set a=%cd%/创建三段码数据库.bat
set b=%cd%/创建mis数据库.bat
@echo --------------mysql数据初始化开始
@echo 执行第一个文件
if exist "%a%" (call "%a%") else (echo 没有找到"%a%")
@echo 执行第二个文件
if exist "%b%" (call "%b%") else (echo 没有找到"%b%")
@echo --------------mysql数据初始化结束

创建mis数据库.bat

@ECHO OFF 
@echo 创建mis数据库开始
cd /d %~dp0
SET dbhost=localhost
SET dbuser=root
SET dbpasswd=root@123
SET dbName=mis
SET sqlpath=%cd%/sql/
set sqlfile=mis.sql
 
cd /d %~dp0/bin
::执行SQL脚本
if exist "%sqlpath%" (
mysql -h%dbhost% -u%dbuser% -p%dbpasswd% < %sqlpath%%sqlfile% --default-character-set=utf8
) else (echo 没有找到"%sqlpath%")
 
@echo 创建mis数据库结束