innosetup语法详解 

  1 ; 脚本由 Inno Setup 脚本向导 生成！
  2 ; 有关创建 Inno Setup 脚本文件的详细资料请查阅帮助文档！
  3 ;Inno Setup 是一个免费的 Windows 安装程序制作软件。
  4 ;第一次发表是在 1997 年，Inno Setup 今天在功能设置和稳定性上的竞争力可能已经超过一些商业的安装程序制作软件
  5 ;它是真正免费的软件，即使作为商业应用
  6 ;还有一个特点，压缩率特别高，特别适合VB软件，我这个安装打包后只有3.7M，其他打包工具5M多
  7 ;安装程序用编译脚本的方式创建，脚本其实就是一个类似 .INI 文件格式的 ASCII 码文本文件。 (它不象你想象的那么复杂!)
  8 ;脚本文件一般可以用安装程序编译器程序内置的编辑器进行编辑。在你编写完脚本后，下一个最终步骤就是选择安装程序编译器
  9 ;中的“编译”。创建完成后，就可以运行根据你脚本编译的安装程序了。
 10 ;按默认，这个安装程序创建在包含脚本文件目录下的名为“输出”目录中
 11 
 12 
 13 
 14 [Setup]
 15 ;这个段包含用于安装程序和卸载程序的全局设置。某些提示对于你创建的任何安装程序都是必需的
 16 ;一个必需的指示，用以指定你正在安装的应用程序的标题。不包含版本号，与 AppVerName 指示用于同样的目的。AppName 始终在安装过程中显示在安装屏幕的左上角以及安装向导中
 17 AppName=南才北往
 18 ;这个必需的指示值应该与 AppName 的值相同 (或类似)，但它还应该包含程序的版本号
 19 AppVerName=南才北往 V1.0
 20 ;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效
 21 AppPublisher=南才北往
 22 ;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效
 23 AppPublisherURL=http://www.upc.edu.cn
 24 AppSupportURL=http://www.upc.edu.cn
 25 AppUpdatesURL=http://www.upc.edu.cn
 26 ;这个必需的指示值是用于选择目标位置向导面中的默认目录名，通常它用一个目录常量作为前缀，{pf}\SinyoCDManager将显示:C:\Program Files\SinyoCDManager
 27 DefaultDirName={pf}\南才北往
 28 ;这个指示的值是用在向导的选择开始菜单文件夹页中使用的默认开始菜单文件夹名。如果这个指示是空白或未指定，它将用“默认”作为名字
 29 DefaultGroupName=南才北往
 30 
 31 InfoBeforeFile=D:\南才北往\使用说明.txt
 32 ;指定许可协议文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，在用户选择程序目标目录前显示
 33 LicenseFile=D:\南才北往\License.txt
 34 ;指定“自述”文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，用于在安装完成后显示
 35 ;InfoAfterFile=D:\南才北往\使用说明.txt
 36 ;这是指定要在文件中使用的压缩方法，以及压缩标准
 37 Compression=lzma
 38 ;如果设为 yes，固实压缩将启用。这会使所有文件一次性压缩
 39 SolidCompression=yes
 40 
 41 VersionInfoCompany=HTTP://www.upc.edu.cn
 42 VersionInfoDescription=南才北往
 43 VersionInfoVersion=1.0.0.0
 44 VersionInfoCopyright=Copyright (C) 2009-2010 CDream
 45 ;可重新修复软件
 46 ;AppModifyPath="{app}\Setup.exe" /modify=1
 47 ;资源管理器更改环境变量
 48 ;ChangesEnvironment=1
 49 ;[Tasks]
 50 ;这个段是只选的。它定义安装程序在执行安装期间所有由用户定制的任务。这些任务以选项框和单选项形式在附加任务向导页中出现
 51 ; 注意: 下面的条目包含一个中文用语 (“创建桌面快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。
 52 [Tasks]
 53 Name: "desktopicon"; Description: "创建桌面快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce
 54 ; 注意: 下面的条目包含一个中文用语 (“创建快速运行栏快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。
 55 ;Name: "quicklaunchicon"; Description: "创建快速运行栏快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce
 56 
 57 [Files]
 58 ;这是定义安装程序安装文件到用户系统中的可选文件段
 59 ;因这是VB软件，除软件本身包含的文件外，还必须包含相关的链接库
 60 ;以下即软件本身的文件，注：安装目录下有一个 "\Config" 的子目录
 61 Source: "D:\南才北往\License.txt"; DestDir: "{app}"; Flags: ignoreversion
 62 Source: "D:\南才北往\使用说明.txt"; DestDir: "{app}"; Flags: ignoreversion
 63 Source: "D:\南才北往\帮助.chm"; DestDir: "{app}"; Flags: ignoreversion
 64 Source: "D:\南才北往\使用手册.doc"; DestDir: "{app}"; Flags: isreadme
 65 Source: "D:\南才北往\Config\*"; DestDir: "{app}\Config"; Flags: ignoreversion recursesubdirs createallsubdirs
 66 Source: "D:\南才北往\XdictGrb.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
 67 Source: "D:\南才北往\msvcrt.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile
 68 ; 注意: 不要在任何共享系统文件中使用“Flags: ignoreversion”
 69 [INI]
 70 ;这是你希望安装程序在用户系统中设置 .INI 文件条目的可选段。
 71 ;写一个文件“访问我们.url”用于访问作者网站
 72 Filename: "{app}\访问我们.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.upc.edu.cn";
 73 
 74 [Icons]
 75 ;这个可选段定义所有创建在开始菜单和/或其它位置 (比如桌面) 的快捷方式
 76 Name: "{group}\南才北往"; Filename: "{app}\Recognise.exe"; WorkingDir:"{app}"
 77 Name: "{group}\帮助"; Filename: "{app}\帮助.chm"; WorkingDir:"{app}"
 78 Name: "{group}\使用说明"; Filename: "{app}\使用说明.txt"; WorkingDir:"{app}"
 79 
 80 ; 注意: 下列条目包含一个中文用语 (“网站”)。如果需要你可以翻译为其它语言。
 81 Name: "{group}\访问主页"; Filename: "{app}\访问我们.url"; WorkingDir:"{app}"
 82 Name: "{group}\卸载"; Filename: "{app}\unins000.exe"
 83 
 84 Name: "{userdesktop}\南才北往"; Filename: "{app}\Recognise.exe"; Tasks: desktopicon; WorkingDir:"{app}"
 85 ;Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\南才北往"; Filename: "{app}\Recognise.exe"; Tasks: quicklaunchicon; WorkingDir:"{app}"
 86 
 87 [Run]
 88 ; 注意: 下列条目包含一个中文用语 (“运行”)。如果需要你可以翻译为其它语言。
 89 ;[Run] 段是可选的，用来指定程序完成安装后、在安装程序显示最终对话框之前要执行的程序
 90 Filename: "{app}\Recognise.exe"; Description: "运行 南才北往"; Flags: nowait postinstall skipifsilent
 91 
 92 ;更改显示在程序中显示的消息文本
 93 [Messages]
 94 BeveledLabel=南才北往
 95 ;卸载对话框说明
 96 ConfirmUninstall=您真的想要从电脑中卸载南才北往吗?%n%n按 [是] 则完全删除 %1 以及它的所有组件;%n按 [否]则让软件继续留在您的电脑上.
 97 ;定义解压说明
 98 ;StatusExtractFiles=解压并复制主程序文件及相关库文件...
 99 
100 ;用与在用户系统中创建，修改或删除注册表健值
101 
102 [UninstallDelete]
103 ;这个可选段定义你想让卸载程序删除除用 [Files] 或 [Dirs] 条目安装/创建外的其它文件或目录，或由你应用程序创建的一些公共使用的 .INI 文件。卸载程序在卸载时最后一步处理这些条目
104 Type: files; Name: "{app}\访问我们.url"

 

posted @ 2014-05-11 08:15  IT少年  阅读(15306)  评论(1)  编辑  收藏  举报