FPGA基础——旅鼠游戏（FSM）

FSM（Finite State Machine）

分为2大类：

第一类，若输出只和状态有关而与输入无关，则称为Moore状态机

第二类，输出不仅和状态有关而且和输入有关系，则称为Mealy状态机

Mealy状态机，常采用一段式写法，只用了一个always语句，所有的状态转移，判断状态转移条件，数据输出都在一个always语句里，缺点是如果状态太多，会使整段程序显的冗长。

Moore状态机，常采用三段式的写法，状态转移用了一个always语句，判断状态转移条件是组合逻辑always @(*)，采用了一个always语句，数据输出也是单独的 always语句，这样写起来比较直观清晰，状态很多时也不会显得繁琐。

---

1. 旅鼠游戏介绍

　　在《旅鼠》这款游戏中，小动物的大脑相当简单。简单到我们要用一个有限状态机来建立模型。在《旅鼠》的2D世界中，旅鼠可能会处于两种状态之一:向左走或向右走。如果碰到障碍物，它会改变方向。特别是，如果一只旅鼠被撞到左边，它就会向右走。如果它在右边被撞到，它就会向左走。如果它同时在两边碰撞，它仍然会改变方向。

                                                    

 

 

　　实现一个Moore状态机，它有两个状态、两个输入和一个输出来模拟这种行为。

 

module top_module (
    input clk,
    input areset,　　　　//异步复位
    input bump_left,　　
    input bump_right,
    output walk_left,
    output walk_right
);

    
    // 状态参数设置，常见：二进制码、格雷码、独热码、BCD码
    parameter WL=0, WR=1;
    reg state;　　//当前状态
    reg next;　　 //下个状态　
    
    
    // Combinational always block for state transition logic. Given the current state and inputs,
    // what should be next state be?
    // Combinational always block: Use blocking assignments.    
    always@(*) begin
        case (state)
            WL: next = bump_left  ? WR : WL;
            WR: next = bump_right ? WL : WR;
        endcase
    end
    
    
    // Combinational always block for state transition logic. Given the current state and inputs,
    // what should be next state be?
    // Combinational always block: Use blocking assignments.    
    always @(posedge clk, posedge areset) begin
        if (areset) state <= WL;
        else state <= next;
    end
        
        
    // 输出组合逻辑。
    // In more complex circuits, a combinational always block may be more suitable.        
    assign walk_left = (state==WL);
    assign walk_right = (state==WR);

    
endmodule

 2.旅鼠游戏补充

除了左右行走，旅鼠还会在地面消失时摔倒(可能会发出“啊!”的声音)。除了左右行走和颠簸时改变方向外，当地面=0时，旅鼠还会摔倒并说“啊!”当地面重新出现(地面=1)时，旅鼠会继续沿著坠落前的方向行走。摔倒时被撞不会影响行走方向，在地面消失(但还没有摔倒)的同一周期内被撞，或摔倒时地面重新出现，也不会影响行走危难。

 

 

除了行走和跌倒，有时候还会让旅鼠做一些有用的事情，比如挖(当挖=1时它就开始挖了)。如果旅鼠正在地面上行走(地面=1并且没有掉下来)，它可以继续挖掘，直到它到达另一边(地面=0)。在这一点上，因为没有地面，它会掉下来(啊!)，然后在它再次撞击地面时继续朝原来的方向走。就像摔倒一样，在挖的时候被撞到是没有影响的，在摔倒或没有地面的时候被告知挖也被忽略了。

 

 

 

 

虽然旅鼠可以走路、摔倒和挖洞，但旅鼠并非无懈可击。如果旅鼠跌倒的时间过长就会撞到地面，它可能会GG。特别是，如果旅鼠跌倒超过20个时钟周期，然后击中地面，它将GG和停止行走，掉落，或挖掘(所有4个输出变成0)，永远(或直到FSM重置)。旅鼠在落地前坠落的距离没有上限。旅鼠只有在撞击地面时才会GG;它们不会在半空中GG。

                                                    

 

 

module top_module(
    input clk,
    input areset,    // Freshly brainwashed Lemmings walk left.
    input bump_left,
    input bump_right,
    input ground,
    input dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging ); 
    parameter LEFT = 4'd0, RIGHT = 4'd1, FALL_L = 4'd2, FALL_R = 4'd3;
    parameter DIG_L = 4'd4, DIG_R = 4'd5, DYING = 4'd6, SPLAT = 4'd7; 
    reg    [3:0]    current_state;
    reg [3:0]    next_state;
    reg cnt_start;
    reg [4:0]cnt_fall;
    
    always@(posedge clk or posedge areset)begin
        if(areset)begin
            current_state <= LEFT;
        end
        else begin
            current_state <= next_state;
        end
    end
    
    always@(*)begin
        case(current_state)
            LEFT:begin
                next_state = ground ? (dig ? DIG_L : (bump_left ? RIGHT : LEFT)) : FALL_L;
            end
            RIGHT:begin
                next_state = ground ? (dig ? DIG_R : (bump_right ? LEFT : RIGHT)) : FALL_R;
            end
            FALL_L:begin
                next_state = ground ? LEFT : ((cnt_fall==5'd20)?DYING:FALL_L);
            end
            FALL_R:begin
                next_state = ground ? RIGHT : ((cnt_fall==5'd20)?DYING:FALL_R);
            end
            DIG_L:begin
                next_state = ground ? DIG_L : FALL_L;
            end
            DIG_R:begin
                next_state = ground ? DIG_R : FALL_R;
            end
            DYING:begin
                next_state = ground ? SPLAT : DYING;
            end
            SPLAT:begin
                next_state = SPLAT;
            end
            default:begin
                next_state = LEFT;
            end
        endcase
    end    
    
    always@(posedge clk or posedge areset)begin
        if(areset)
            cnt_fall <= 0;
        else if(cnt_start) 
            cnt_fall <= cnt_fall+1'b1;
        else
            cnt_fall <= 0;
    end

    assign cnt_start = (next_state==FALL_L) || (next_state==FALL_R);
    
    assign walk_left = (current_state == LEFT);
    assign walk_right = (current_state == RIGHT);
    assign digging = (current_state == DIG_L || current_state == DIG_R);
    assign aaah = (current_state == FALL_L || current_state == FALL_R || current_state == DYING);

endmodule