poj1556 The Doors 2012-01-11

http://poj.org/problem?id=1556

 

 

________________________________________

将两个x坐标不同的点之间连一条边，判断是否经过墙壁，如果可行就将这条边加入图，最后计算起点到终点的最短路

 

________________________________________

Program Stone;
const exp=1e-8;
var n,m:longint;
    xi:array[0..50]of real;
    yi:array[0..50,1..4]of real;
    pos:array[0..50,1..4]of longint;
    map:array[1..500,1..500]of real;
    h:array[1..500]of real;
    f:array[1..500]of boolean;
 Procedure init;
 var i,j:longint;
  begin
    xi[0]:=0;yi[0][1]:=5;
    xi[n+1]:=10;yi[n+1][1]:=5;
    pos[0,1]:=1;pos[n+1,1]:=2;
    m:=2;
    for i:=1 to n do
     begin
        read(xi[i]);
        for j:=1 to 4 do begin
                           read(yi[i][j]);
                           inc(m);pos[i,j]:=m;
                         end;
     end;
    for i:=1 to m do
     for j:=1 to m do map[i,j]:=0;
  end;
 Function cross(x1,y1,x2,y2:real):real;   //叉积
  begin
     cross:=x1*y2-x2*y1;
  end;
 Function threeout(x:real):longint;     //三出口，判断精度
  begin
     if abs(x)<exp then exit(0);             //精度之内输出0
     if x>0 then exit(1) else exit(-1);     
  end;
 Function between(y1,y2,y3:real):boolean;    //判断一个点是否在两个点之间
  Begin
    if threeout(y1-y3)*threeout(y1-y2)<=0 then exit(true) else exit(false);    
  end;
 Function check(x1,y1,x2,y2,x3,y3,x4,y4:real):boolean;    //判断是否相交。
 var s1,s2,s3,s4:longint;
  begin
    s1:=threeout(cross(x2-x1,y2-y1,x3-x1,y3-y1));
    s2:=threeout(cross(x2-x1,y2-y1,x4-x1,y4-y1));
    s3:=threeout(cross(x4-x3,y4-y3,x1-x3,y1-y3));
    s4:=threeout(cross(x4-x3,y4-y3,x2-x3,y2-y3));
    if (s1 xor s2=-2)and(s3 xor s4=-2) then exit(true);       //规范相交。
    if (s1=0)and(between(y3,y1,y2)) then exit(true);     //不规范相交的判断
    if (s2=0)and(between(y4,y1,y2)) then exit(true);
    if (s3=0)and(between(y1,y3,y4)) then exit(true);
    if (s4=0)and(between(y2,y3,y4)) then exit(true);
    exit(false);
  end;
 Procedure main;
 var i1,i2,j1,j2,k,l:longint;
     flag:boolean;
  begin
    for i1:=0 to n do
     for i2:=1 to 4 do
      if not(((i1=0)or(i1=n+1))and(i2>1)) then
      for j1:=i1+1 to n+1 do
       for j2:=1 to 4 do
       if not(((j1=0)or(j1=n+1))and(j2>1)) then
        begin
          flag:=true;
          for k:=i1+1 to j1-1 do
           begin
             if not((check(xi[i1],yi[i1][i2],xi[j1],yi[j1][j2],xi[k],yi[k][1],xi[k],yi[k][2]))or
                (check(xi[i1],yi[i1][i2],xi[j1],yi[j1][j2],xi[k],yi[k][3],xi[k],yi[k][4])))then flag:=false;    

            //如果这条边与某堵墙的其中一个门相交，者这条边可以经过这堵墙。
           end;
          if flag then map[pos[i1,i2],pos[j1,j2]]:=sqrt(sqr(xi[j1]-xi[i1])+sqr(yi[j1][j2]-yi[i1][i2]));   //如果该边可行，就加入图。
        end;
  end;
 Procedure dijkstra;   //求最短路。
 var i,j,k,l:longint;
     s:real;
  begin
   for i:=1 to m do h[i]:=map[1,i];
   fillchar(f,sizeof(f),true);
    for i:=1 to m-2 do
     begin
       s:=10000000;
       for j:=2 to m do
        if (f[j])and(h[j]>exp)and(s-h[j]>exp) then
            begin
               s:=h[j];k:=j;
            end;
       f[k]:=false;
       for j:=2 to m do
        if (map[k,j]>exp)and((h[j]-(h[k]+map[k,j])>exp)or(abs(h[j])<exp)) then h[j]:=h[k]+map[k,j];
     end;
    writeln(h[2]:0:2); 
  end;
Begin
 assign(input,'input.in');reset(input);
  readln(n);
  while n<>-1 do
   begin
      init;
      main;
      dijkstra;
      readln(n);
   end;
end.