用VBA批量输出Outlook通讯录内容

我发现自己经常要将Gmail通讯录与Outlook通讯录进行同步操作，而往往我只是要更新某个类别的用户信息。Outlook菜单只支持全部导出通讯录信息为csv文件。而当我想要只输出某一类别（如"同学.高中"时）则要先输出为Excel表格，再筛选转换成csv文件。绝不能这样耗费大好时光。我决意用VBA来解决这个问题。

Outlook是Office组件之一，其支持VBA自动化对象，但相关书籍较少，只能通过Google与自己摸索来学习，最终脚本如下：

Sub ExportVCards()

    Dim objNS As NameSpace '命名空间
    Dim objContactFolder   '通讯录目录
    Dim objEntry As Variant 'OEM条目
    Dim objContactEntry As ContactItem '通讯录条目
    Dim count As Integer '计数器
    Dim CategoriesName As String '类别名称  
    Dim ExportFolder As String '输出目录  
    CategoriesName = "同学.中学"
    ExportFolder = "e:\\temp\\contacts\\"
    
    count = 0
    
    Set objNS = Application.GetNamespace("MAPI") '连接到命令空间中，这是直接在Outlook中运用宏时获取命令句柄的方法
    Set objContactFolder = objNS.GetDefaultFolder(olFolderContacts) '转到通讯录目录中
    
    For Each objEntry In objContactFolder.Items   '遍历通讯录目录
        If Not TypeOf objEntry Is ContactItem Then
            If TypeOf objEntry Is DistListItem Then
                Debug.Print "Found a distribution list, skipping"
            Else
                Debug.Print "****** found a something odd ****"
                Debug.Print "  " & objEntry
            End If
        Else        
            Set objContactEntry = objEntry
	    If CategoriesName = objEntry.Categories Then
            	count = count + 1
            	path = ExportFolder & "contact" & count & ".vcf"
            	objContactEntry.SaveAs path, olVCard '将该条目输出到目录中
            End If
        End If
    Next
    Set objNS = Nothing
End Sub

经过上述代码后，将该类别所有的通信联系人条目输出到单个文件中，再用命令将所有文件合并起来，我采用的方法是 Cygwin 的Cat 命令，即

cat contact*.vcf > all.vcf

这样导入到Gmail后，再用Merge整合重复的人员即可