Adobe AIR and Flex - 实现堆栈容器

1.需求描述：

    在对云平台的监控中，我们经常需要在一张图上可视化的描述集群下的物理机所虚拟的虚拟机使用情况，以及超卖情况。那么传统的chart图就不满足我们的需求了，那么要实现这样一个定制化的chart图，反向LIST容器（堆栈容器)，可谓是我们的桥梁，如下图：

  

2、Demo实现

  我们如何实现这样的效果呢？首先，大多数情况下需要一个反向list容器，那么FLEX提供的默认list容器又是从上往下的，很显然不满足我们的需求，

我们需要自定义一个这样的容器。步骤：

(1)继承BaseLayout类  (2)重写updateDisplayList()

 

3、具体实现

 

/**
 * Created with IntelliJ IDEA.
 * @author: DongYang
 * Date: 13-7-24
 * Time: 上午10:22
 * Progress every day a little more.
 */
package component.charts.layout
{
    import mx.core.ILayoutElement;
    import mx.core.UIComponent;
    
    import spark.layouts.BasicLayout;
    
    public class StackLayout extends BasicLayout
    {
        public function StackLayout()
        {
            super();
        }
        private var _gap:int = 6;

        public function get gap():int
        {
            return _gap;
        }

        public function set gap(value:int):void
        {
            _gap = value;
           if(!this.target) return;
            target.invalidateDisplayList();
            target.invalidateSize();
        }

        override public function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
        {
            super.updateDisplayList(unscaledWidth, unscaledHeight);
            if(!this.target)  
                return;  
            
            var layoutElement:ILayoutElement;  
            var count:uint = target.numElements;  
         
            var h : Number = target.height;
            var depth:Number=0;
            
            for (var i:int = 0; i < count; i++)  
            {  
                layoutElement = target.getElementAt(i);  
                
                if (!layoutElement || !layoutElement.includeInLayout)  
                    continue;  
              
                var _eh:Number=UIComponent(layoutElement).height;
                var _y:Number=0;
                if(i==0){
                    depth=depth+_eh;
                }else{
                    depth=depth+_eh+gap;
                }
                _y=h-depth;
                layoutElement.setLayoutBoundsPosition( 0, _y );
            }
        }
    
    }
}

4、使用方法

让容器的layout实例等于 new StackLayout();

如：

/**
 * Created with IntelliJ IDEA.
 * @author: DongYang
 * Date: 13-7-25
 * Time: 上午11:41
 * Progress every day a little more.
 */
package component.charts.container {
import component.charts.layout.StackLayout;

import spark.components.Group;

public class StackGroup extends Group {
    public function StackGroup() {
        super();
        _lay=new StackLayout();
        this.layout=_lay;
    }
    private var _lay:StackLayout;
    private var _gap:Number=6;

    public function get gap():Number {
        return _gap;
    }

    public function set gap(value:Number):void {
        _gap = value;
        _lay.gap=value;
    }
}
}

其中gap是子元素之间的间隔距离

这样我们在StackGroup里放子元素的话，就可以看到子元素“入栈”了。

注：使用StackGroup容器的时候，必须指定它的高度。我们想想在日常生活中，我们要向一个桶里装水，肯定是提前知道它的容量的。