VBA实战技巧精粹002:如何调用过程

在使用VBA编写过程时,一个好的习惯是尽量将实现单独功能的代码放置在独立的过程中,并在主过程中调用这些独立的过程.这样不仅便于程序的高度,而且程序的结构清晰,便于理解和维护,也能够重复使用通用的过程代码.

通过一个示例演示在程序中调用过程的方法.如图所示工作表,其中"加班费基数"固定,每个加班为80元,"加班数"由人工输入,"加班系数"根据加班个数而不同."加班费"为"加班费基数"和"加班数"分别与"加班系数"的乘积.

要求:自动根据"加班数"确定"加班系数"并得到"加班费"的数值,然后将最大加班费数值所在单元格的底纹设置为绿色.

①解决利用过程及函数获取加班系数问题:

Option Explicit
Dim lLastRow As Integer
Sub 加班费计算()
    Worksheets("sheet1").Activate
    lLastRow = Range("A65536").End(xlUp).Row
    Range("D3:E" & lLastRow).ClearContents
    '调用获取加班系数的过程
    Call GetExtraNum
'    '调用计算加班费的过程
'    Call CalculaeExtra
'    Set rng = Range("E3:E" & lLastRow)
'    '调用设置加班费列格式的过程
'    Call SetFormat(rng)
End Sub

'获取加班系数填入工作表
Sub GetExtraNum()
    Dim i As Integer, ExtraNum As Single
    For i = 3 To lLastRow
        ExtraNum = Range("c" & i).Value
        Range("D" & i).Value = GetExtra(ExtraNum)
    Next i
End Sub
   
'获取加班系数
Function GetExtra(num As Single) As Single
    Select Case num
        Case 1, 2
            GetExtra = 1
        Case 3 To 5
            GetExtra = 1.05
        Case Is > 5
            GetExtra = 1.1
        Case Else
            GetExtra = 0
    End Select
End Function
    
运行以上程序,可以在工作表中填入加班系数.

反思:在数据传递过程中,要特别注意数据类型的一致性,对于小批量的数据运算,最好统一设置成Single类型,少用Integer类型.

②计算加班费并填入相应单元格

'计算加班费并填入指定位置
Sub CalculaeExtra()
    Range("E3:E" & lLastRow).FormulaR1C1 = "=RC2*RC3*RC4"
End Sub

 

这里遇到新情况:关于FormulaR1C1方法的使用.

FormulaR1C1是公式输入方法,上例中为绝对引用

例：C1单元格为"=$A$2+$E$3"  
Range("C1").FormulaR1C1 = "=R2C1+R3C5" 表示将单元格A2与E3相加并赋给C1单元格.

那上例中如何解释呢?看字面就是将第2列/第3列/第4列的值相乘,并赋给同一行的中第E列.

中括号是相对于选定单元格的相对偏移量，"-"为向左或向上偏移，正数为右或下偏移。
无中括号为相对于选定单元格的绝对偏移量，没有负数
"R"和"C"待变“行”和“列”
如：选定单元格为C8
R[-1]C[-1]为B7单元格，行列都-1，R[1]C[2]为E9单元格，行+1，列+2
R1C1代表A1单元格，R5C6代表F5单元格
清楚了吗？

例：C1单元格为"=A1+B1"
Range("C1").FormulaR1C1 = "=RC[-2]+RC[-1]"

例：C1单元格为"=A2+E3"
Range("C1").FormulaR1C1 = "=R[1]C[-2]+R[2]C[2]"

完整程序如下:

Option Explicit
Dim lLastRow As Integer
Sub 加班费计算()
    Worksheets("sheet1").Activate
    lLastRow = Range("A65536").End(xlUp).Row
    Range("D3:E" & lLastRow).ClearContents
    '调用获取加班系数的过程
    Call GetExtraNum
    '调用计算加班费的过程
    Call CalculaeExtra
'    Set rng = Range("E3:E" & lLastRow)
'    '调用设置加班费列格式的过程
End Sub

'获取加班系数填入工作表
Sub GetExtraNum()
    Dim i As Integer, ExtraNum As Single
    For i = 3 To lLastRow
        ExtraNum = Range("c" & i).Value
        Range("D" & i).Value = GetExtra(ExtraNum)
    Next i
End Sub
'获取加班系数
Function GetExtra(num As Single) As Single
    Select Case num
        Case 1, 2
            GetExtra = 1
        Case 3 To 5
            GetExtra = 1.05
        Case Is > 5
            GetExtra = 1.1
        Case Else
            GetExtra = 0
    End Select
End Function
'计算加班费并填入指定位置
Sub CalculaeExtra()
    Range("E3:E" & lLastRow).FormulaR1C1 = "=RC2*RC3*RC4"
End Sub

效果截图:

   

 这就是菊子曰啦！