【批处理】启动 VMware 服务的简单批处理脚本

早些时候编写的一个启动VMware服务的简单批处理脚本。

主要是记录一下自动提升运行权限的命令，不用再右键"以管理员身份运行"。

 

@echo off
mode con cols=90 lines=20
title Windows 服务管理工具 -- Version 2016-09-01 09:00:00

::------------------------------ 自动提升运行权限 ------------------------------::
:BatchGetAdmin
>nul 2>&1 "%Windir%\System32\cacls.exe" "%Windir%\System32\config\system"

if '%ERRORLEVEL%' NEQ '0' (
echo 正在获取管理员权限...
goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%TEMP%\getAdmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%TEMP%\getAdmin.vbs"
"%TEMP%\getAdmin.vbs"
exit

:gotAdmin
if exist "%TEMP%\getadmin.vbs" ( del "%TEMP%\getadmin.vbs" )
pushd "%cd%"
cd /d "%~dp0"
::------------------------------------------------------------------------------::

::------------------------------ 启动 VMware 服务 ------------------------------::
:Start
cls & echo.
net start "VMAuthdService"
net start "VMUSBArbService"
net start "VMwareHostd"
net start "VMnetDHCP"
net start "VMware NAT Service"
::------------------------------------------------------------------------------::

set "tip= VMware 服务启动完成"
::------------------------------------------------------------------------------::

::--------------------------------- 倒计时退出 ---------------------------------::
:End
for /l %%t in (3,-1,0) do (
cls & echo. && echo %tip%
echo. & echo %%t 秒后退出...
choice.exe /t 1 /d y /n >nul
)

Exit