洛谷 P1052 过河

题目描述

在河上有一座独木桥，一只青蛙想沿着独木桥从河的一侧跳到另一侧。在桥上有一些石子，青蛙很讨厌踩在这些石子上。由于桥的长度和青蛙一次跳过的距离都是正整数，我们可以把独木桥上青蛙可能到达的点看成数轴上的一串整点：0，1，……，L（其中L是桥的长度）。坐标为0的点表示桥的起点，坐标为L的点表示桥的终点。青蛙从桥的起点开始，不停的向终点方向跳跃。一次跳跃的距离是S到T之间的任意正整数（包括S,T）。当青蛙跳到或跳过坐标为L的点时，就算青蛙已经跳出了独木桥。

题目给出独木桥的长度L，青蛙跳跃的距离范围S,T，桥上石子的位置。你的任务是确定青蛙要想过河，最少需要踩到的石子数。

输入输出格式

输入格式：

输入文件river.in的第一行有一个正整数L（1 <= L <= 10^9），表示独木桥的长度。第二行有三个正整数S，T，M，分别表示青蛙一次跳跃的最小距离，最大距离，及桥上石子的个数，其中1 <= S <= T <= 10，1 <= M <= 100。第三行有M个不同的正整数分别表示这M个石子在数轴上的位置（数据保证桥的起点和终点处没有石子）。所有相邻的整数之间用一个空格隔开。

输出格式：

输出文件river.out只包括一个整数，表示青蛙过河最少需要踩到的石子数。

输入输出样例

输入样例#1：

10
2 3 5
2 3 5 6 7

输出样例#1：

2

说明

对于30%的数据，L <= 10000；
对于全部的数据，L <= 109。
2005提高组第二题

解题思路

第一眼看到这个题材，我想到的自然是那种不断枚举的简单动归，方程如下

f[i]:=min(f[i-w]+a[i]) //w表示的是步数，a[i]表示格子上有没有石子，有的话为1，没有为0

当我写完去敲变量的时候我发现l<=10^9，这是分分钟爆内存和时间的节奏！！！

这时候就要引入状态压缩（由于这是我第一次接触这个算法，也不是很明白）

可以把中间那些没有石子又超级超级长的路用最大步数替换，严格的证明我写不出来，不过可以这样想

如果有一段超级长的路，跳xt之后才能到下一个点，路上没有任何一个点改变石子数，我们完全可以把这段路去掉。。。

代码如下

program flag;  
var a,st:array[0..101] of longint;  
    f,w:array[0..100000] of longint;  
    l,s,t,m,i,j,k,ans,min:Longint;  
procedure sort(l,r: longint);  
      var  
         i,j,x,y: longint;  
      begin  
         i:=l;  
         j:=r;  
         x:=a[(l+r) div 2];  
         repeat  
           while a[i]<x do  
            inc(i);  
           while x<a[j] do  
            dec(j);  
           if not(i>j) then  
             begin  
                y:=a[i];  
                a[i]:=a[j];  
                a[j]:=y;  
                inc(i);  
                j:=j-1;  
             end;  
         until i>j;  
         if l<j then  
           sort(l,j);  
         if i<r then  
           sort(i,r);  
      end;  
  
begin  
    read(l);  
    read(s,t,m);  
    filldword(f,sizeof(f) div 4, maxint);  
    for i:=1 to m do  
    begin  
        read(a[i]);  
    end;  
    if s=t then  //特判一下
    begin  
        for i:=1 to m do  
        if a[i] mod t =0 then inc(ans);  
        writeln(ans);  
        halt;  
    end;  
    sort(1,m);  //这里没有说有序给出，排一下总归是好的
    a[0]:=0;  //注意初始化
    a[m+1]:=l;  
    l:=0;  
    for i:=1 to m+1 do  
    if a[i]-a[i-1]>t then  //如果比t大，就减少为t
    begin  
        st[i]:=st[i-1]+t;  
        inc(l,t);  
        w[st[i]]:=1;  
    end  
    else  
    begin  //否则就加上原来的路径
        st[i]:=st[i-1]+a[i]-a[i-1];  
        w[st[i]]:=1;  
        inc(l,a[i]-a[i-1]);  
    end;  
    w[0]:=0;  //起点终点的值为0，因为并不存在这样的石子
    w[st[m+1]]:=0;  
    f[0]:=0;  
    for i:=1 to l+t do  //超过l即可，所以保险循环到l+1
    begin  
        for k:=t downto s do    
         if (i-k>=0)and(f[i]>f[i-k]+w[i]) then f[i]:=f[i-k]+w[i];  
    end;  
    ans:=maxint;  
    for i:=l to l+t do if ans>f[i] then ans:=f[i];  
    writeln(ans);  
end.