通达信 自定义配置

通达信 自定义配置

目录

配置文件

[T0002]目录

user.ini 全局个性化数据

配色方案：

Solarized配色方案

  • Scheme.dat 文件
[Color]
SchemeNum=9
CurrentScheme=7

SchemeName7=Solarized Dark
Scheme7=002B36002F333E0083949600DC322F002AA198008394960019A3470083949600181B2200EEE8D50007364200FFFF0000B58900006C71C400D3368200859900002AA19800DC322F0093A1A1001E3048002F333E00002B36001D1F270050505000EEE8D500FF000000DC322F0019A347008394960093A1A10093A1A1008394960083949600002B360083949600002B360019

SchemeName8=Solarized Light
Scheme8=FDF6E300657B8300657B8300DC322F002AA19800657B830019A34700657B8300657B830007364200EEE8D5008000FF00B58900006C71C400D3368200859900002AA19800DC322F00657B8300CBE4FA00657B8300FDF6E300FCFCFC000079D50007364200FF000000DC322F0019A34700657B8300657B8300657B8300657B8300657B8300FDF6E300657B8300FDF6E3007C
自定板块

[blocknew] 板块目录

  • 自定板块分类及颜色
    blocknew.cfg
    blocknew.clr
    UserSetCfg.json
    zxgmore.dat
  • 自定板块品种
    xxx.blk
    ZXG.blk 自选股
自选标记

mark.dat

配置选项

外观

  • 配色方案：
  • 字体风格：现代

设置1

  • 行情表使用实心选中框

设置3

  • 分析图中指标值显示涨跌箭头
  • 主图指标不影响坐标的高底值

链接

90bd97fb33ccf5b9ec130995bc90526c.png

公式代码

  • MAX
MA5:MA(CLOSE,5);
MA10:MA(CLOSE,10);
MA20:MA(CLOSE,20);
MA60:MA(CLOSE,60);
MA120:MA(CLOSE,120);
MA250:MA(CLOSE,250);

DRAWICON(CURRBARSCOUNT=5,H*1.01, 26);
DRAWICON(CURRBARSCOUNT=10,H*1.01,24);
DRAWICON(CURRBARSCOUNT=20,H*1.01,33);
DRAWICON(CURRBARSCOUNT=60,H*1.01,27);
DRAWICON(CURRBARSCOUNT=120,H*1.01,28);
DRAWICON(CURRBARSCOUNT=250,H*1.01,25);

BIASC:(C-MA5)/MA5*100,NODRAW;
BIASH:(H-MA5)/MA5*100,NODRAW;
BIASL:(L-MA5)/MA5*100,NODRAW;
HL:(H-L)/C*100,NODRAW;

行业:=STRCAT('行业板块：',HYBLOCK);
概念:=STRCAT('  概念板块：',GNBLOCK);
地域:=STRCAT('  地域板块：',DYBLOCK);
指数:=STRCAT('  ||  指数板块：',ZSBLOCK);
字幕1:=STRCAT(行业,地域);
字幕2:=STRCAT(概念,  指数);
字幕:=STRCAT(字幕1,字幕2);
DRAWTEXT_FIX(ISLASTBAR,0,0,0,字幕)
  • BOLLX
MA5:MA(CLOSE, 5),LINETHICK1; 
MA10:MA(CLOSE, 10),LINETHICK1; 
BOLL:MA(CLOSE,20),LINETHICK1; 
MA60:MA(CLOSE, 60),LINETHICK1; 
MA120:MA(CLOSE, 120),LINETHICK1; 
MA250:MA(CLOSE, 250),LINETHICK1; 

BIASC:(C-MA5)/MA5*100,NODRAW; 
BIASH:(H-MA5)/MA5*100,NODRAW; 
BIASL:(L-MA5)/MA5*100,NODRAW; 
HL:(H-L)/C*100,NODRAW; 

LB:BOLL-2*STD(CLOSE,20),LINETHICK1,DOTLINE; 
UB:BOLL+2*STD(CLOSE,20),LINETHICK1,DOTLINE;

DRAWICON(CURRBARSCOUNT=5,H*1.01, 26);
DRAWICON(CURRBARSCOUNT=10,H*1.01,24);
DRAWICON(CURRBARSCOUNT=20,H*1.01,33);
DRAWICON(CURRBARSCOUNT=60,H*1.01,27);
DRAWICON(CURRBARSCOUNT=120,H*1.01,28);
DRAWICON(CURRBARSCOUNT=250,H*1.01,25);
  • AMOX
AMOW:AMOUNT/10000.0,VOLSTICK;
AMO5:MA(AMOW,5);
{AMO10:MA(AMOW,10);}
AMO20:MA(AMOW,20);
AMO60:MA(AMOW,60);
AMO250:MA(AMOW,250);

换手率:DYNAINFO(37),NODRAW;
量比:DYNAINFO(17),NODRAW;
委比:DYNAINFO(15)*100,NODRAW;
委差:DYNAINFO(16)/100,NODRAW;
内外比:DYNAINFO(51)*100,NODRAW;
  • VOLX
VOLUME:VOL,VOLSTICK;
MAVOL5:MA(VOLUME,5);
MAVOL20:MA(VOLUME,20);
MAVOL60:MA(VOLUME,60);

换手率:DYNAINFO(37),NODRAW;
量比:DYNAINFO(17),NODRAW;
委比:DYNAINFO(15)*100,NODRAW;
委差:DYNAINFO(16)/100,NODRAW;
内外比:DYNAINFO(51)*100,NODRAW;
  • MACDX
DIFF:EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:EMA(DIFF,9);
MACD:2*(DIFF-DEA), COLORSTICK,LINETHICK2;
X:MACD-REF(MACD,1),NODRAW;
低位金叉:=CROSS(DIFF,DEA) AND DIFF<-0.1;
STICKLINE(低位金叉,0,0.08,6,0),COLOR0089B5;
DRAWTEXT(低位金叉,0.16,' 低位金叉'),COLOR0089B5;
JCCOUNT:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
二次金叉:=CROSS(DIFF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1;
STICKLINE(二次金叉,0,0.06,6,0),COLOR8236D3;
DRAWICON(二次金叉,DEA*0.9,1) ;
DRAWTEXT(二次金叉,0.2,' 二次金叉'),COLOR8236D3;
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIFF>REF(DIFF,A1+1) AND CROSS(DIFF,DEA);
STICKLINE(底背离,0,0.03,6,0),COLOR2F32DC;
底背:DRAWLINE(A1=0,DEA,底背离,DEA,0),COLOR2F32DC,LINETHICK4;
{DRAWTEXT(底背离,0.12,' 底背离'),COLORFF00FF;}
A2:=BARSLAST(REF(CROSS(DEA,DIFF),1));
顶背离:=REF(CLOSE,A2+1)<CLOSE AND REF(DIFF,A2+1)>DIFF AND CROSS(DEA,DIFF);
顶背:DRAWLINE(A2=0,DEA,顶背离,DEA,0),COLOR009985,LINETHICK4;
DRAWTEXT(低位金叉 AND 二次金叉 AND 底背离,0.25,'三全项'),COLOR0000FF,LINETHICK2;
  • KDJX
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;
X:ABS(K-D),NODRAW;
DRAWICON(K>80 AND REF(K,1)>80 AND REF(K,2)>80,100,8);
DRAWICON(K<20 AND REF(K,1)<20 AND REF(K,2)<20,0,7);
20;
50,DOTLINE;
80;
  • RSIX
LC:=REF(CLOSE,1);
RSI9:SMA(MAX(CLOSE-LC,0),9,1)/SMA(ABS(CLOSE-LC),9,1)*100;
20;
65,DOTLINE;
40,DOTLINE;
80;
  • CCIX
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
100;
-100;
  • BIASX
BIASC:(CLOSE-MA(CLOSE,5))/MA(CLOSE,5)*100;
BIASH:(H-MA(CLOSE,5))/MA(CLOSE,5)*100;
BIASL:(L-MA(CLOSE,5))/MA(CLOSE,5)*100;
0,DOTLINE;
10;
25;
-10;
-25;

选股公式

  • 印钞机模式
MA5:=MA(CLOSE,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA(C,5)>REF(MA(C,5),1) AND MA(C,10)>REF(MA(C,10),1) AND MA(C,20)>REF(MA(C,20),1) AND MA5>MA10 AND MA10>MA20 AND (C-MA5)/MA5<0.03;

标记

1-9

  • 1：通达信一级行业分类
  • 2：通达信细分行业/申万二级行业
  • 9：概念板块分类

ABDSVZ

  • Z：印钞机模式
  • A：印钞机模式 启动前三
  • B：印钞机模式 MACD 上0轴
  • D：印钞机模式超跌
  • T：文字
posted @ 2022-01-05 15:07  孤逐王  阅读(2122)  评论(0)  编辑  收藏  举报