POJ 1274

POJ 1274

题目大意：求二分图最大匹配

解：初试匈牙利算法，具体的一些问题，总结见程序的同文件夹下。今晚用网络流切下并验证算法正确性。

2012.02.21 ： dinic做法已完成，记得逆边的cost为0！

{

如何证明其增广正确性
会不会因增广而堵塞？
最优性已经被证明，每次至少能拓展一条边
二分图的性质可以证明不会出现011的情况，拓展的相邻两条边一定是一条存在另一条不存在
每次皆从a类节点开始， 用match转跳

}

const
        maxn=211 << 1;
        maxm=(maxn * maxn )  << 1;
type
        data=record
          dest, next: longint;
        end;
var
        edge: array[1..maxm]of data;
        vect, match: array[1..maxn]of longint;
        visit: array[1..maxn]of boolean;
        n, m, tot, ans: longint;
procedure add(x, y: longint);
begin
  inc(tot);
  with edge[tot] do begin
    dest := y;
    next := vect[x];
    vect[x] := tot;
  end;
  inc(tot);
  with edge[tot] do begin
    dest := x;
    next := vect[y];
    vect[y] := tot;
  end;
end;

procedure init;
var
        i, j, l, x, y: longint;
begin
  tot := 0; ans := 0;
  fillchar(vect, sizeof(vect), 0);
  fillchar(match, sizeof(match), 0);
  readln(n, m);
  for i := 1 to n do begin
    read(l);
    for j := 1 to l do begin
      read(x);
      add(i, x+n);
    end;
  end;
end;

function dfs(x: longint): boolean;
var
        i: longint;
begin
  i := vect[x];
  while i<>0 do
    with edge[i] do begin
      if not visit[dest] then begin
        visit[dest] := true;
        if (match[dest]=0) or (dfs(match[dest])) then begin
          match[dest] := x;
          exit(true);
        end;
      end;
      i := next;
    end;
  exit(false);
end;

procedure main;
var
        i: longint;
begin
  for i := 1 to n do begin
    fillchar(visit, sizeof(visit), 0);
    if dfs(i) then inc(ans);
  end;
end;

procedure print;
begin
  writeln(ans);
end;

begin
  assign(input,'aaa.in'); reset(input);
  while not (seekeof) do begin
    init;
    main;
    print;
  end;
  close(input);
end.

 

const
        maxn=211 << 1;
        maxm = (maxn*maxn)<< 1;
        bilibili = maxlongint >> 1;
type
        data=record
          dest, next, cost, op: longint;
        end;
var
        edge: array[1..maxm]of data;
        vect, dist: array[1..maxn]of longint;
        n, m, sink, source, ans, tot: longint;
procedure add(x, y, z: longint);
begin
  inc(tot);
  with edge[tot] do begin
    dest := y;
    cost := z;
    next := vect[x];
    vect[x] := tot;
    op := tot + 1;
  end;
  inc(tot);
  with edge[tot] do begin
    dest := x;
    cost := 0;
    next := vect[y];
    vect[y] := tot;
    op := tot - 1;
  end;
end;

procedure init;
var
        i, j, x, l: longint;
begin
  fillchar(vect, sizeof(vect) , 0);
  tot := 0;
  ans := 0;
  readln(n, m);
  sink := n + m + 1; source := n + m + 2;
  for i := 1 to n do add(sink, i, 1);
  for i := 1 to m do add(i+n, source, 1);
  for i := 1 to n do begin
    read(l);
    for j := 1 to l do begin
      read(x);
      add(i, x + n, bilibili);
    end;
  end;
end;

function bfs: boolean;
var
        q: array[1..maxn]of longint;
        head, tail, i, u: longint;
begin
  filldword(dist, sizeof(dist)>> 2, bilibili);
  head := 0; tail := 1;
  q[tail] := sink; dist[sink] := 1;
  repeat
    head := head mod maxn + 1;
    u := q[head]; i := vect[u];
    while i<>0 do
      with edge[i] do begin
        if (cost > 0) and (dist[dest] > dist[u] + 1) then begin
          dist[dest] := dist[u] + 1;
          tail := tail mod maxn + 1;
          q[tail] := dest;
        end;
        i := next;
      end;
    if dist[source] <> bilibili then break;
  until head=tail;
  exit(dist[source] <> bilibili);
end;

function min(a, b: longint): longint;
begin if a<b then exit(a) else exit(b); end;

function dinic(x, flow: longint): longint;
var
        i, tmp: longint;
begin
  if x = source then exit(flow);
  dinic := 0;
  i := vect[x];
  while i<>0 do
    with edge[i] do begin
      if (cost > 0)and(dist[dest]=dist[x]+1) then begin
        tmp := dinic(dest, min(flow, cost));
        dinic := dinic + tmp;
        flow := flow - tmp;
        cost := cost - tmp;
        edge[op].cost := edge[op].cost + tmp;
        if flow = 0 then break;
      end;
      i := next;
    end;
  if dinic = 0 then dist[x] := -1;
end;

procedure main;
begin
  while bfs do
    begin
      ans := ans + dinic(sink, bilibili);
    end;
end;

procedure print;
begin
  writeln(ans);
end;

begin
  assign(input,'aaa.in'); reset(input);
  while not seekeof do begin
    init;
    main;
    print;
  end;
  close(input);
end.