POJ3667 HOTEL

POJ3667 HOTEL

【题目大意】

     有一个旅馆，有N个房间排成一排，现在有两种操作，第一是有X个顾客要入住连续的X个房间，要求输出最小的左端点的位置，不能满足就输出0，第二是将以l开始，长度为X的连续房间清空。

【输入文件】

     第一行两个数N，M，表示房间数和操作数

     接下来M行，每行有两种情况：

     1 X 表示操作1

     2 l X 表示操作2

【输出文件】

     对于每一个1操作，输出答案。

【输入样例】

10 6

1 3

1 3

1 3

1 3

2 5 5

1 6

【输出样例】

1

4

7

0

5

【题目分析】

     方案一：线段树

     首先最经典的是线段树的做法，在每个节点上新加3个域Z，Y，S，Z表示区间左边连续的空房个数，Y表示区间有边连续的空房个数，S表示区间上最大的一段空房的长度。

     那么：

      A[i].z:=a[a[i].l].z（左区间不都为空时）

            A[a[i].l].len+a[a[i].r].z（左区间为空时）

      A[i].y类似。

      A[i].s:=max(a[a[i].l].s,a[a[i].r].s,a[a[i].l].y+a[a[i].r].z)

     插入和删除线段时要用到lazy操作

     查询时：

        1、如果1~n区间的S值都比X小，就无解，否则有解。

        2、对于每一个区间，如果它的左儿子的S值大于等于X，到左儿子里去找。

        3、如果左儿子的Y加上有儿子的Z大于等于X，直接返回左儿子的右端点减去左儿子的Y值。

        4、否则到右儿子里去找。

        5、如果满足2，则不再考虑3，4；同样，满足3就不再考虑4。

     

program poj3667;
type tree=record
      a,b,l,r,z,y,s,bj:longint;
     end;
var a:array[0..100000]of tree;
    i,j,m,n,k,x,tot,ans,p,l,r:longint;
procedure make(l,r:longint);
var mid,now:longint;
begin
    inc(tot);
    a[tot].a:=l;
    a[tot].b:=r;
    a[tot].z:=r-l;
    a[tot].y:=r-l;
    a[tot].s:=r-l;
    mid:=(l+r)shr 1;
    if l<mid then
    begin
        now:=tot;
        a[now].l:=tot+1;
        make(l,mid);
        a[now].r:=tot+1;
        make(mid,r);
    end;
end;
function max(a,b:longint):longint;
begin
    if a>b then exit(a)
    else exit(b);
end;
procedure calc(i:longint);
begin
    if a[a[i].l].z=a[a[i].l].b-a[a[i].l].a then a[i].z:=a[a[i].l].z+a[a[i].r].z
    else a[i].z:=a[a[i].l].z;
    if a[a[i].r].y=a[a[i].r].b-a[a[i].r].a then a[i].y:=a[a[i].r].y+a[a[i].l].y
    else a[i].y:=a[a[i].r].y;
    a[i].s:=max(max(a[a[i].l].s,a[a[i].r].s),a[a[i].l].y+a[a[i].r].z);
end;
procedure clean(i:longint);
begin
    a[a[i].l].bj:=a[i].bj;
    a[a[i].r].bj:=a[i].bj;
    if a[i].bj=1 then
    begin
        a[a[i].l].z:=0;
        a[a[i].r].z:=0;
        a[a[i].l].y:=0;
        a[a[i].r].y:=0;
        a[a[i].l].s:=0;
        a[a[i].r].s:=0;
    end
    else
    begin
        a[a[i].l].z:=a[a[i].l].b-a[a[i].l].a;
        a[a[i].r].z:=a[a[i].r].b-a[a[i].r].a;
        a[a[i].l].y:=a[a[i].l].b-a[a[i].l].a;
        a[a[i].r].y:=a[a[i].r].b-a[a[i].r].a;
        a[a[i].l].s:=a[a[i].l].b-a[a[i].l].a;
        a[a[i].r].s:=a[a[i].r].b-a[a[i].r].a;
    end;
    a[i].bj:=0;
end;
procedure insert(i,l,r:longint);
var mid:longint;
begin
    if (l<=a[i].a)and(a[i].b<=r) then
    begin
        a[i].z:=0;
        a[i].y:=0;
        a[i].s:=0;
        a[i].bj:=1;
        exit;
    end;
    mid:=(a[i].a+a[i].b)shr 1;
    if a[i].bj<>0 then clean(i);
    if l<mid then insert(a[i].l,l,r);
    if mid<r then insert(a[i].r,l,r);
    calc(i);
end;
procedure delete(i,l,r:longint);
var mid:longint;
begin
    if (l<=a[i].a)and(a[i].b<=r) then
    begin
        a[i].z:=a[i].b-a[i].a;
        a[i].y:=a[i].b-a[i].a;
        a[i].s:=a[i].b-a[i].a;
        a[i].bj:=-1;
        exit;
    end;
    mid:=(a[i].a+a[i].b)shr 1;
    if a[i].bj<>0 then clean(i);
    if l<mid then delete(a[i].l,l,r);
    if mid<r then delete(a[i].r,l,r);
    calc(i);
end;
function get(i,x:longint):longint;
var mid:longint;
begin
    if a[i].s<x then exit(0);
    if a[i].bj<>0 then clean(i);
    if a[a[i].l].s>=x then exit(get(a[i].l,x));
    if a[a[i].l].y+a[a[i].r].z>=x then exit(a[a[i].l].b-a[a[i].l].y+1);
    exit(get(a[i].r,x));
end;
begin
    readln(n,m);
    make(0,n);
    for i:=1 to m do
    begin
        read(k);
        if k=1 then
        begin
            readln(x);
            l:=get(1,x);
            writeln(l);
            r:=l+x-1;
            if l<>0 then insert(1,l-1,r);
        end
        else
        begin
            readln(l,r);
            r:=l+r-1;
            delete(1,l-1,r);
        end;
    end;
end.

 

      方案二：链表

      首先表示这个方法不是自己想的，是小银月亮童鞋想出来的。

      搞一个链表，链表的每个元素是一段连续空房的区间，查询时找到第一个长度足够的区间，然后更新这个区间的左右端点或直接将该区间删除，增加空房时就将给出的区间与原有区间合并。

      这个方法的理论复杂度是N^2的，对于随机数据常数较小，但是还是能被一些数据能卡住。

      事实证明，这个方法对付POJ的数据绰绰有余，上面的线段树方法454ms，链表的做法344ms

 

program poj3667_2;
type lian=record
      l,r,last,next:longint;
     end;
var a:array[0..100000]of lian;
    i,j,m,n,k,x,l,r,tot,tp:longint;
function max(a,b:longint):longint;
begin
    if a>b then exit(a)
    else exit(b);
end;
function min(a,b:longint):longint;
begin
    if a<b then exit(a)
    else exit(b);
end;
begin
    readln(n,m);
    a[0].l:=0;a[0].r:=-1;a[0].next:=1;a[0].last:=-1;
    a[1].l:=1;a[1].r:=n;a[1].next:=2;a[1].last:=0;
    a[2].l:=n+2;a[2].r:=n+1;a[2].last:=1;a[2].next:=-1;
    tot:=2;
    for tp:=1 to m do
    begin
        read(k);
        if k=1 then
        begin
            readln(x);
            i:=0;
            while (i<>-1)and(a[i].r-a[i].l+1<x) do i:=a[i].next;
            if i=-1 then
            begin
                writeln(0);
                continue;
            end;
            writeln(a[i].l);
            if a[i].r-a[i].l+1=x then
            begin
                a[a[i].last].next:=a[i].next;
                a[a[i].next].last:=a[i].last;
            end
            else a[i].l:=a[i].l+x;
        end
        else
        begin
            readln(l,r);
            r:=l+r-1;
            i:=0;
            while a[a[i].next].r+1<l do i:=a[i].next;
            j:=i;
            while a[j].l<=r+1 do j:=a[j].next;
            inc(tot);
            a[tot].l:=min(l,a[a[i].next].l);
            a[tot].r:=max(r,a[a[j].last].r);
            a[tot].next:=j;
            a[tot].last:=i;
            a[i].next:=tot;
            a[j].last:=tot;
        end;
    end;
end.