JSOI2008 最小生成树计数

JSOI2008 最小生成树计数

【题目描述】

现在给出了一个简单无向加权图。你不满足于求出这个图的最小生成树，而希望知道这个图中有多少个不同的最小生成树。（如果两颗最小生成树中至少有一条边不同，则这两个最小生成树就是不同的）。由于不同的最小生成树可能很多，所以你只需要输出方案数对31011的模就可以了。

【输入文件】

第一行包含两个数，n和m，其中1<=n<=100; 1<=m<=1000; 表示该无向图的节点数和边数。每个节点用1~n的整数编号。接下来的m行，每行包含两个整数：a, b, c，表示节点a, b之间的边的权值为c，其中1<=c<=1,000,000,000。数据保证不会出现自回边和重边。注意：具有相同权值的边不会超过10条。

【输出文件】

输出不同的最小生成树有多少个。你只需要输出数量对31011的模就可以了。

【输入样例】

4 6
1 2 1
1 3 1
1 4 1
2 3 2
2 4 1
3 4 1
【输出样例】

8 

【题目分析】

一开始超时了，加了半天优化发现快排写错了……

继续……水题……首先按kruskal的思路做一遍最小生成树，统计一下各个相同权值的边分别加进去了几条，然后对每组相同权值的边进行dfs，计算对于每组边有多少种加入先前计算出的边的数量的方案，乘在一起即可。注意，dfs时并查集朴素合并，不要进行路径压缩，否则无法进行状态还原，处理完每组边后，修改连通性时再进行状态压缩。再次注意，有不连通的情况，此时输出0。

【代码实现】

program tyvj1826;
var s,t,l:array[0..1001]of longint;
    f:array[0..1000]of longint;
    g,ss:array[0..1000]of longint;
    i,j,m,n,ans,k,p,ll,rr,x,y,sum:longint;
procedure kp(ll,rr:longint);
var i,j,x,y:longint;
begin
    i:=ll;j:=rr;
    x:=l[(i+j)shr 1];
    repeat
        while l[i]<x do inc(i);
        while l[j]>x do dec(j);
        if i<=j then
        begin
            y:=l[i];
            l[i]:=l[j];
            l[j]:=y;
            y:=s[i];
            s[i]:=s[j];
            s[j]:=y;
            y:=t[i];
            t[i]:=t[j];
            t[j]:=y; 
            inc(i);
            dec(j);
        end;
    until i>j;
    if ll<j then kp(ll,j);
    if i<rr then kp(i,rr);
end;
function find(x:longint):longint;
begin
    if x<>f[x] then f[x]:=find(f[x]);
    exit(f[x]);
end;
procedure dfs(i,j:longint);
var x,y:longint;
begin
    if j=p then
    begin
        inc(g[rr]);
        exit;
    end;
    if i=rr+1 then exit;
    if rr-i+1+j<p then exit;
    dfs(i+1,j);
    x:=s[i];y:=t[i];
    while x<>f[x] do x:=f[x];
    while y<>f[y] do y:=f[y];
    if x<>y then
    begin
        f[x]:=y;
        dfs(i+1,j+1);
        f[x]:=x;
    end;
end;
begin
    readln(n,m);
    for i:=1 to m do readln(s[i],t[i],l[i]);
    kp(1,m);
    for i:=1 to n do f[i]:=i;
    p:=0;sum:=0;
    for i:=1 to m do
    begin
         x:=find(s[i]);y:=find(t[i]);
         if x<>y then
         begin
             f[x]:=y;
             inc(sum);
             inc(p);
         end;
         if l[i]<>l[i+1] then
         begin
             ss[i]:=p;
             p:=0;
         end;
    end;
    if sum<n-1 then
    begin
        writeln(0);
        halt;
    end;
    for i:=1 to n do f[i]:=i;
    ll:=1;rr:=1;
    for i:=1 to m do
    begin
        if l[i]=l[i+1] then
        begin
            inc(rr);
            continue;
        end;
        p:=ss[rr];
        dfs(ll,0);
        for j:=ll to rr do
        begin
            x:=find(s[j]);y:=find(t[j]);
            if x<>y then f[x]:=y;
        end;
        ll:=i+1;rr:=i+1;
    end;
    ans:=1;
    for i:=1 to m do
      if l[i]<>l[i+1] then ans:=ans*g[i] mod 31011;
    writeln(ans);
end.