sql 表被锁查询

--检测死锁
 
--如果发生死锁了，我们怎么去检测具体发生死锁的是哪条SQL语句或存储过程？
 
--这时我们可以使用以下存储过程来检测，就可以查出引起死锁的进程和SQL语句。SQL Server自带的系统存储过程sp_who和sp_lock也可以用来查找阻塞和死锁, 但没有这里介绍的方法好用。
 
use master
go
create procedure sp_who_lock
as
begin
declare @spid int,@bl int,
 @intTransactionCountOnEntry  int,
        @intRowcount    int,
        @intCountProperties   int,
        @intCounter    int
 
 create table #tmp_lock_who (
 id int identity(1,1),
 spid smallint,
 bl smallint)
  
 IF @@ERROR<>0 RETURN @@ERROR
  
 insert into #tmp_lock_who(spid,bl) select  0 ,blocked
   from (select * from sysprocesses where  blocked>0 ) a 
   where not exists(select * from (select * from sysprocesses where  blocked>0 ) b 
   where a.blocked=spid)
   union select spid,blocked from sysprocesses where  blocked>0
 
 IF @@ERROR<>0 RETURN @@ERROR 
   
-- 找到临时表的记录数
 select  @intCountProperties = Count(*),@intCounter = 1
 from #tmp_lock_who
  
 IF @@ERROR<>0 RETURN @@ERROR 
  
 if @intCountProperties=0
  select '现在没有阻塞和死锁信息' as message
 
-- 循环开始
while @intCounter <= @intCountProperties
begin
-- 取第一条记录
  select  @spid = spid,@bl = bl
  from #tmp_lock_who where Id = @intCounter 
 begin
  if @spid =0 
            select '引起数据库死锁的是: '+ CAST(@bl AS VARCHAR(10)) + '进程号,其执行的SQL语法如下'
 else
            select '进程号SPID：'+ CAST(@spid AS VARCHAR(10))+ '被' + '进程号SPID：'+ CAST(@bl AS VARCHAR(10)) +'阻塞,其当前进程执行的SQL语法如下'
 DBCC INPUTBUFFER (@bl )
 end 
 
-- 循环指针下移
 set @intCounter = @intCounter + 1
end
 
drop table #tmp_lock_who
 
return 0
end

 

--杀死锁和进程
 
--如何去手动的杀死进程和锁？最简单的办法，重新启动服务。但是这里要介绍一个存储过程，通过显式的调用，可以杀死进程和锁。
 
use master
go
 
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_killspid]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_killspid]
GO
 
create proc p_killspid
@dbname varchar(200)    --要关闭进程的数据库名
as  
    declare @sql  nvarchar(500)  
    declare @spid nvarchar(20)
 
    declare #tb cursor for
        select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
    open #tb
    fetch next from #tb into @spid
    while @@fetch_status=0
    begin  
        exec('kill '+@spid)
        fetch next from #tb into @spid
    end  
    close #tb
    deallocate #tb
go
 
--用法  
exec p_killspid  'newdbpy'

 

SELECT TOP 10
[session_id],
[request_id],
[start_time] AS '开始时间',
[status] AS '状态',
[command] AS '命令',
dest.[text] AS 'sql语句',
DB_NAME([database_id]) AS '数据库名',
[blocking_session_id] AS '正在阻塞其他会话的会话ID',
[wait_type] AS '等待资源类型',
[wait_time] AS '等待时间',
[wait_resource] AS '等待的资源',
[reads] AS '物理读次数',
[writes] AS '写次数',
[logical_reads] AS '逻辑读次数',
[row_count] AS '返回结果行数'
FROM sys.[dm_exec_requests] AS der
CROSS APPLY
sys.[dm_exec_sql_text](der.[sql_handle]) AS dest
WHERE [session_id]>50 AND DB_NAME(der.[database_id])='dbname'
ORDER BY [cpu_time] DESC

 

ALTER PROC [dbo].[sp_who_lock2]
as
SELECT 
  r.[session_id]                  as [会话ID], 
  r.[request_id]                  as [请求ID], 
  r.[scheduler_id]                as [计划ID],   
  r.[status]                      as [状态],  
  r.[blocking_session_id]         as [阻塞会话ID],   
  --r.[statement_start_offset],   
  --r.[statement_end_offset],  
  CASE   
    WHEN r.[statement_start_offset] > 0 THEN  
      CASE r.[statement_end_offset]  
        WHEN -1 THEN  
          SUBSTRING(q.TEXT, (r.[statement_start_offset]/2) + 1, 2147483647) 
        ELSE   
          SUBSTRING(q.TEXT, (r.[statement_start_offset]/2) + 1, 
              (r.[statement_end_offset] - r.[statement_start_offset])/2)   
      END  
    ELSE  
      CASE r.[statement_end_offset]  
        WHEN -1 THEN   
          RTRIM(LTRIM(q.[text]))  
        ELSE  
          LEFT(q.TEXT, (r.[statement_end_offset]/2) +1)  
      END  
  END                             as [当前查询],  
  q.[text]                        as [完整查询],
  r.[cpu_time]                    as [CPU时间(ms)],   
  r.[start_time]                  as [开始时间],   
  r.[total_elapsed_time]          as [执行总时间],   
  r.[reads]                       as [读取数],   
  r.[writes]                      as [写入数],   
  r.[logical_reads]               as [逻辑读取数],                  
  d.[name]                        as [数据库名]    
FROM sys.[dm_exec_requests] r 
CROSS APPLY sys.[dm_exec_sql_text](r.[sql_handle]) q  
LEFT JOIN sys.databases d ON (r.database_id=d.database_id)   
WHERE r.session_id > 50 AND r.session_id <> @@SPID   
ORDER BY r.[session_id], r.[request_id]