PLSQL基础
Oracle之PLSQL基础
- SQL和PLSQL特点和区别
- PLSQL格式([declare]..begin..[exception..]end;/)
- PLSQL类型(变量类型,其它类型)
- PLSQL声明(declare..)
- PLSQL主体(begin..end;)
- PLSQL判断(if..then..[elsif..then..]else..end if;)
- PLSQL循环(loop:in,while,exit)
- PLSQL游标(cursor)
- PLSQL例外(内置例外,自定义例外)
1.1、什么是SQL,SQL有什么特点?
SQL:
- SQL是所有关系型数据库的操作规则
- 是一种结构化查询语言
- 输入命令就能获得结果
SQL特点:
- 交互性强,非过程化
- 数据操纵能力强,只需要发送命令,不需要关注过程如何实现
- 强调结果
1.2、什么是PLSQL,为什么要使用它?
PLSQL:
PLSQL是Oracle在SQL99规则之上添加的一些过程化控制语句, 包括:变量定义,判断,循环,游标,例外等。 PLSQL强调过程。
为什么要使用?
SQL是命令式语言,只能一句一句执行,无法处理一系列过程化的业务。PLSQL与其互相弥补。
PLSQL与SQL执行有什么不同:
(1)SQL是单条执行的
(2)PLSQL是整体执行的,不能单条执行,整个PLSQL结束用/,其中每条语句结束用;号
2、书写格式
--输出hello world!
declare
pstr varchar2(20) := 'hello world!';
begin
dbmsoutput.putline(pstr);
end;
/
3、类型
- 常规类型:和Oracle的字段类型一致。
- 根据表字段类型创建变量类型:表名.字段名%type;
- 整个表类型当作变量类型:表名%rowtype;
例如:pemp emp%rowtype;
调用:pemp.ename, pemp.sal... - 异常类型:exception
- 赋值:使用“:=”
- 游标空值:%notfound;
- 控制台输出:dbmsoutput.putline(变量名[ || 需要拼接的])
4、变量,例外,游标等的声明
declare
--基本类型
pvar number(2);
pvar2 number(3) := 100;
pdate date := sysdate;
--表字段类型 pname emp.ename%type;
--表类型 pemp emp%rowtype; --游标
cursor pcur is select * from emp; --例外/异常类型
pexception exception;何时使用%type,何时使用%rowtype? 当定义变量时,该变量的类型与表中某字段的类型相同时,可以使用%type 当定义变量时,该变量与整个表结构完全相同时,可以使用%rowtype,此时通过变量名.字段名,可以取值变量中对应的值 项目中,常用%type
5、主体部分
使用基本类型变量,常量和注释,求10+100的和
declare
--定义变量
mysum number(3) := 0;
tip varchar2(10) := '结果是';
begin
/*业务算法*/
mysum := 10 + 100;
/*输出到控制器*/
dbms_output.put_line(tip || mysum);
end;
/
输出7369号员工姓名和工资,格式如下:7369号员工的姓名是SMITH,薪水是800,语法:使用表名.字段%type
declare
--定义二个变量,分别装姓名和工资
pename emp.ename%type;
psal emp.sal%type;
begin
--SQL语句
--select ename,sal from emp where empno = 7369;
--PLSQL语句,将ename的值放入pename变量中,sal的值放入psal变量中
select ename,sal into pename,psal from emp where empno = 7369;
--输出
dbms_output.put_line('7369号员工的姓名是'||pename||',薪水是'||psal);
end;
/
6、判断
使用if-else-end if显示今天星期几,是"工作日"还是"休息日"
declare
pday varchar2(10);
begin
select to_char(sysdate,'day') into pday from dual;
dbms_output.put_line('今天是'||pday);
if pday in ('星期六','星期日') then
dbms_output.put_line('休息日');
else
dbms_output.put_line('工作日');
end if;
end;
/
从键盘接收值,使用if-elsif-else-end if显示"age<16","age<30","age<60","age<80"
declare
age number(3) := &age;
begin
if age < 16 then
dbms_output.put_line('你未成人');
elsif age < 30 then
dbms_output.put_line('你青年人');
elsif age < 60 then
dbms_output.put_line('你奋斗人');
elsif age < 80 then
dbms_output.put_line('你享受人');
else
dbms_output.put_line('未完再继');
end if;
end;
/
7、循环
使用loop循环显示1-10
declare
i number(2) := 1;
begin
loop
--输出i的值
dbms_output.put_line(i);
--变量自加
i := i + 1;
--当i>10时,退出循环
exit when i>10;
end loop;
end;
/
使用while循环显示1-10
declare
i number(2) := 1;
begin
while i<11
loop
dbms_output.put_line(i);
i := i + 1;
end loop;
end;
/
使用while循环,向emp表中插入999条记录
declare
i number(4) := 1;
begin
while i < 1000
loop
insert into emp(empno,ename) values(i,'哈哈');
i := i + 1;
end loop;
end;
/
使用while循环,从emp表中删除999条记录
declare
i number(4) := 1;
begin
while i<1000
loop
delete from emp where empno = i;
i := i + 1;
end loop;
end;
/
使用for循环显示20-30
declare
i number(2) := 20;
begin
for i in 20 .. 30
loop
dbms_output.put_line(i);
end loop;
end;
/
8、游标
什么是光标/游标/cursor
类似于JDBC中的ResultSet对象的功能,从上向下依次获取每一记录的内容
使用无参光标cursor,查询所有员工的姓名和工资【如果需要遍历多条记录时,使用光标cursor,无记录找到使用cemp%notfound】
declare
--定义游标
cursor cemp is select ename,sal from emp;
--定义变量
vename emp.ename%type;
vsal emp.sal%type;
begin
--打开游标,这时游标位于第一条记录之前
open cemp;
--循环
loop
--向下移动游标一次
fetch cemp into vename,vsal;
--退出循环,当游标下移一次后,找不到记录时,则退出循环
exit when cemp%notfound;
--输出结果
dbms_output.put_line(vename||'--------'||vsal);
end loop;
--关闭游标
close cemp;
end;
/
使用带参光标cursor,查询10号部门的员工姓名和工资
declare
cursor cemp(pdeptno emp.deptno%type) is select ename,sal from emp where deptno=pdeptno;
pename emp.ename%type;
psal emp.sal%type;
begin
open cemp(&deptno);
loop
fetch cemp into pename,psal;
exit when cemp%notfound;
dbms_output.put_line(pename||'的薪水是'||psal);
end loop;
close cemp;
end;
/
使用无参光标cursor,真正给员工涨工资,ANALYST涨1000,MANAGER涨800,其它涨400,要求显示编号,姓名,职位,薪水
declare
cursor cemp is select empno,ename,job,sal from emp;
pempno emp.empno%type;
pename emp.ename%type;
pjob emp.job%type;
psal emp.sal%type;
begin
open cemp;
loop
fetch cemp into pempno,pename,pjob,psal;
--循环退出条件一定要写
exit when cemp%notfound;
if pjob='ANALYST' then
update emp set sal = sal + 1000 where empno = pempno;
elsif pjob='MANAGER' then
update emp set sal = sal + 800 where empno = pempno;
else
update emp set sal = sal + 400 where empno = pempno;
end if;
end loop;
commit;
close cemp;
end;
/
10、例外/异常处理
使用oracle系统内置例外,演示除0例外【zero_divide】
declare
myresult number;
begin
myresult := 1/0;
dbms_output.put_line(myresult);
exception
when zero_divide then
dbms_output.put_line('除数不能为0');
delete from emp;
end;
/
使用oracle系统内置例外,查询100号部门的员工姓名,演示没有找到数据【no_data_found】
declare
pename varchar2(20);
begin
select ename into pename from emp where deptno = 100;
dbms_output.put_line(pename);
exception
when NO_DATA_FOUND then
dbms_output.put_line('查无该部门员工');
insert into emp(empno,ename) values(1111,'ERROR');
end;
/
使用用户自定义例外,使用光标cursor,查询10/20/30/100号部门的员工姓名,演示没有找到数据【nohave_emp_found】
在declare节中定义例外
out_of exception ;
在begin节中可行语句中抛出例外
raise out_of ;
在exception节处理例外
when out_of then …