wsn实验

　　【记录一下关键步骤】

　　【实验一LED】

下面两个.nc文件在分别Notepad++中新建，并保存到同一个文件夹中

　　【LED_C.nc】

configuration LED_C  
{ }  
  
implementation  
{  
    components LED_M as App;  
    components MainC;     
    App.Boot->MainC.Boot;  
      
    components LedsC;  
    App.Leds -> LedsC.Leds;  
      
    //CC2530 GPIO组件  
    components HplCC2530GeneralIOC as GPIO;  
    App.Key->GPIO.P2_Port[0];  
      
    //定时器组件  
    components new TimerMilliC() as Timer1;  
    App.Timer1->Timer1;    
      
    //ADC 组件      
    components new AdcC() as Ad;  
    App.AdControl->Ad;  
    App.AdRead->Ad;    
}

　　【LED_M.nc】

/*********************************************** 
*   文 件 名 : LED_M.nc 
*   功能描述 : 当按下上、下、左键中一个按键时 
*              分别反转红、黄、绿颜色的LED状态。 
*   日    期 : 2019/12/4 
***********************************************/  
#include "ADC.H"  
module LED_M  
{  
    uses interface Boot;  
    uses interface Leds;  
    uses interface AdcControl as AdControl;  
    uses interface Read<int16_t> as AdRead;  
    uses interface Timer<TMilli> as Timer1;  
    uses interface GeneralIO as Key;  
}  
implementation  
{  
      
    uint8_t keyValue;   
    enum {NoKey,KeyDown,KeyHold};   //按键状态  
    uint8_t keyState;             
      
    task void NopTask()     //空任务  
    {  
    }  
    event void Boot.booted()  
    {  
        // 使能ADC采样，采样端口 P0.6  
        call AdControl.enable(ADC_REF_AVDD,ADC_12_BIT,ADC_AIN6);  
        //设置ADC采样时间 1s钟采样一次  
        call Timer1.startPeriodic(100);  
    }  
    event void AdRead.readDone(error_t result, int16_t val)  
    {  
         unsigned char s[16];  
         //读取高8位的ADC采样寄存器的值  
         uint8_t adc_value=val>>5;   
         if((adc_value>20) && (adc_value<40))//最初(10,20)  
            call Leds.led1Toggle();//up键按下红灯状态翻转  
         else if((adc_value>80) && (adc_value<100))  
            call Leds.led2Toggle();//down键按下黄灯状态翻转  
         else if((adc_value>110) && (adc_value<140))  
            call Leds.led0Toggle();//left键按下绿灯状态翻转  
  
            DbgOut(9,"adc_value is:%d\n",adc_value);      
    }  
    event void Timer1.fired()  
    {  
        keyValue=call Key.get();      
        switch(keyState)  
        {  
            //没有键按下的状态  
            case NoKey:   
                if(keyValue==0)  
                    //无键按下  
                    keyState=NoKey;   
                else  
                    //有键按下  
                    keyState=KeyDown;  
            break;  
            //有键按下的状态  
            case KeyDown:  
                if(keyValue==1)  
                {  
                    //转按下键保持状态  
                    keyState=KeyHold;  
                }  
                //调用ADC采样读取命令  
                call AdRead.read();  
            break;  
            case KeyHold:                 
                if(keyValue==1)  
                {  
                    //按键保持  
                    keyState=KeyHold;  
                }  
                else  
                {  
                    //按键松开  
                    keyState=NoKey;  
                }     
            break;  
        }     
    }  
}