获取IE地址栏内容

文件：https://files.cnblogs.com/wanghj-dz/%E8%8E%B7%E5%8F%96ie%E5%9C%B0%E5%9D%80%E6%A0%8F%E5%86%85%E5%AE%B9.rar

.版本 2
.支持库 spec

.程序集 窗口程序集1

.子程序 _按钮寻找窗口_被单击
.局部变量 窗口句柄, 整数型
.局部变量 窗口类名, 文本型
.局部变量 窗口标题, 文本型

.如果真 (编辑框窗口标题.内容 ＝ “” 且 编辑框窗口类名.内容 ＝ “”)
    信息框 (“窗口类名和窗口标题至少必输其一。”, #信息图标, )
    返回 ()
.如果真结束
.如果真 (编辑框窗口类名.内容 ≠ “”)
    窗口类名 ＝ 编辑框窗口类名.内容
.如果真结束
.如果真 (编辑框窗口标题.内容 ≠ “”)
    窗口标题 ＝ 编辑框窗口标题.内容
.如果真结束
窗口句柄 ＝ FindWindow (窗口类名, 窗口标题)
.如果真 (窗口句柄 ＝ 0)
    编辑框窗口句柄.内容 ＝ “”
    信息框 (“未找到指定的窗口。”, #信息图标, )
    返回 ()
.如果真结束
窗口标题 ＝ 取空白文本 (256)
GetWindowText (窗口句柄, 窗口标题, 255)
编辑框窗口标题.内容 ＝ 窗口标题
编辑框窗口句柄.内容 ＝ 到文本 (窗口句柄)

.子程序 _按钮显示隐藏窗口_被单击
.局部变量 窗口句柄, 整数型

.如果真 (编辑框窗口句柄.内容 ＝ “”)
    信息框 (“请先寻找窗口。”, #信息图标, )
    返回 ()
.如果真结束
窗口句柄 ＝ 到数值 (编辑框窗口句柄.内容)
.如果真 (IsWindow (窗口句柄) ＝ 0)
    信息框 (“窗口不存在，是不是已被关闭？”, #信息图标, )
    返回 ()
.如果真结束
.如果 (IsWindowVisible (窗口句柄) ＝ 0)
    ShowWindow (窗口句柄, #SW_SHOW)
.否则
    ShowWindow (窗口句柄, #SW_HIDE)
.如果结束

.子程序 __启动窗口_将被销毁
.局部变量 窗口句柄, 整数型

' 确保在退出程序的时候，把隐藏的窗口显示出来。
窗口句柄 ＝ 到数值 (编辑框窗口句柄.内容)
ShowWindow (窗口句柄, #SW_SHOW)

.子程序 _按钮获取IE地址栏中的文本_被单击
.局部变量 窗口句柄, 整数型
.局部变量 NULL, 文本型
.局部变量 窗口文本, 文本型

窗口句柄 ＝ FindWindow (“IEFrame”, NULL)  ' IE的窗口类名为“IEFrame”
.如果真 (窗口句柄 ＝ 0)
    信息框 (“没有打开Internet Explorer，请先打开一个IE窗口。”, #信息图标, )
    返回 ()
.如果真结束
窗口句柄 ＝ FindWindowEx (窗口句柄, 0, “WorkerW”, NULL)  //0表示子窗口句柄，0也表示查找所有的子窗口。窗口句柄，表示获得IE中类名为WorkerW的窗口句柄。
窗口句柄 ＝ FindWindowEx (窗口句柄, 0, “ReBarWindow32”, NULL)  //表示在WorkerW窗口中查找类名为ReBarWindow32的窗口。
窗口句柄 ＝ FindWindowEx (窗口句柄, 0, “Address Band Root”, NULL)//表示在ReBarWindow32窗口中查找类名为Address Band Root的窗口
窗口句柄 ＝ FindWindowEx (窗口句柄, 0, “Edit”, NULL)//表示在Address Band Root中查找类名为Edit的窗口。
.如果真 (窗口句柄 ＝ 0)
    信息框 (“查找控件句柄失败！”, #错误图标, )
    返回 ()
.如果真结束
窗口文本 ＝ 取空白文本 (256)  ' 先分配存储空间
SendMessage (窗口句柄, #WM_GETTEXT, 255, 取变量数据地址 (窗口文本))
信息框 (“IE地址栏中的内容为：” ＋ 窗口文本, #信息图标, )

----------------------------------------------------------------------------------------------------------------------------

按键精灵

RunApp "C:\Program Files\Internet Explorer\iexplore.exe"
Delay 6000
Plugin.Window.Foreground
Hwnd = Plugin.Window.Foreground()
Delay 10
Hwnd = Plugin.Window.FindEx(Hwnd, 0, "WorkerW", 0)

Hwnd = Plugin.Window.FindEx(Hwnd, 0, "ReBarWindow32", 0)

Hwnd = Plugin.Window.FindEx(Hwnd, 0, "Address Band Root", 0)

HwndEx = Plugin.Window.FindEx(Hwnd, 0, "Edit", 0)

Call Plugin.Window.SendString(HwndEx, "mail.163.com")