解密SQL Server存储过程等对象

这个版本综合了前辈 王成辉翻译的版本 和 另外一个不知道出处的版本，在他们的基础上增加了 对内联和多语句表值函数（IF和TF）的解密。

虽然修改部分没多少技术含量，还是分享出来。^_^

-- =============================================
--王成辉翻译整理，转贴请注明出自微软BI开拓者www.windbi.com
--增加对表值函数的解密功能by wofei
-- =============================================
CREATE PROC [dbo].[DP_DecryptObj]
(
    @ObjectName  VARCHAR(200),
    @flag          INT=1
)
AS

IF @flag = 1
BEGIN
PRINT '警告：该存储过程会删除并重建原始的存储过程。'
PRINT ' 在运行该存储过程之前确保你的数据库有一个备份。'
PRINT ' 该存储过程通常应该运行在产品环境的一个备份的非产品环境下。'
PRINT ' 为了运行这个存储过程，将参数@flag的值更改为0。'
PRINT '注意：请使用DAC连接方式执行此过程。'
RETURN 0
END


DECLARE @PROTEXT VARCHAR(MAX),@sql VARCHAR(MAX),@droptype VARCHAR(50)


DECLARE @intProcSpace bigint, 
        @t bigint, 
        @procNameLength INT

SELECT @procNameLength = datalength(@ObjectName) + 29

DECLARE @real_01 nvarchar(max),
        @fake_01 nvarchar(max),
        @fake_encrypt_01 nvarchar(max),
        @real_decrypt_01 nvarchar(max),@real_decrypt_01a nvarchar(max)
declare @objtype varchar(2),@ParentName nvarchar(max)
select @real_decrypt_01a = ''
--提取对象的类型如是存储过程还是函数，如果是触发器，还要得到其父对象的名称
select @objtype=type,@parentname=object_name(parent_object_id)
from sys.objects where [object_id]=object_id(@ObjectName)



-- 从sys.sysobjvalues里提出加密的imageval记录
SET @real_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid = object_id(@ObjectName) and valclass = 1 order by subobjid)
--创建一个临时表
create table #output ( 
[ident] [int] IDENTITY (1, 1) NOT NULL ,
[real_decrypt] NVARCHAR(MAX) 
)
--开始一个事务，稍后回滚
BEGIN TRAN


/*******以下是修改部分,二部的代码原来解密函数有问题,就直接把王成辉的版本,然后增加加了对IF和TF的解密*******/

--更改原始的存储过程，用短横线替换
if @objtype='P'
BEGIN
  SET @fake_01='ALTER PROCEDURE '+ @ObjectName +' WITH ENCRYPTION AS select 1
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
  SET @droptype='DROP PROCEDURE'
END
else if @objtype='V'
BEGIN
  SET @fake_01='ALTER VIEW '+ @ObjectName +' WITH ENCRYPTION AS select 1 as col
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
  SET @droptype='DROP VIEW'
END
else if @objtype='TR'
BEGIN  
  SET @fake_01='ALTER TRIGGER '+ @ObjectName +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
  SET @droptype='DROP TRIGGER'
END
else if @objtype='FN'
BEGIN  
  SET @fake_01='ALTER FUNCTION '+ @ObjectName +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/ END'
  SET @droptype='DROP FUNCTION'
END
else if @objtype='IF'
BEGIN
  SET @fake_01='ALTER FUNCTION '+ @ObjectName +'() RETURNS TABLE WITH ENCRYPTION AS RETURN (SELECT 0 AS col)
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
  SET @droptype='DROP FUNCTION'
END
else if @objtype='TF'
BEGIN
  SET @fake_01='ALTER FUNCTION '+ @ObjectName +'() RETURNS @Temp TABLE(ID INT) WITH ENCRYPTION AS BEGIN RETURN
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/ END'
  SET @droptype='DROP FUNCTION'
END
EXECUTE (@fake_01)
--从sys.sysobjvalues里提出加密的假的
SET @fake_encrypt_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid =
object_id(@ObjectName) and valclass = 1 order by subobjid )
if @objtype='P'
  SET @fake_01='CREATE PROCEDURE '+ @ObjectName +' WITH ENCRYPTION AS select 1
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='V'
  SET @fake_01='CREATE VIEW '+ @ObjectName +' WITH ENCRYPTION AS select 1 as col
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='TR'
  SET @fake_01='CREATE TRIGGER '+ @ObjectName +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='FN'
  SET @fake_01='CREATE FUNCTION '+ @ObjectName +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/ END'
else if @objtype='IF'
  SET @fake_01='CREATE FUNCTION '+ @ObjectName +'() RETURNS TABLE WITH ENCRYPTION AS RETURN (SELECT 0 AS col)
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='TF'
  SET @fake_01='CREATE FUNCTION '+ @ObjectName +'() RETURNS @Temp TABLE(ID INT) WITH ENCRYPTION AS BEGIN RETURN
  /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 - @procNameLength)+'*/ END'
  
/***********************修改完成*****************************************************************************************/



--开始计数
SET @intProcSpace=1
--使用字符填充临时变量
SET @real_decrypt_01 = replicate(cast('A'as nvarchar(max)), (datalength(@real_01) /2 ))
--循环设置每一个变量，创建真正的变量，每次一个字节
SET @intProcSpace=1
--如有必要，遍历每个@real_xx变量并解密
WHILE @intProcSpace<=(datalength(@real_01)/2)
BEGIN
--真的和假的和加密的假的进行异或处理
SET @real_decrypt_01 = stuff(@real_decrypt_01, @intProcSpace, 1,
NCHAR(UNICODE(substring(@real_01, @intProcSpace, 1)) ^
(UNICODE(substring(@fake_01, @intProcSpace, 1)) ^
UNICODE(substring(@fake_encrypt_01, @intProcSpace, 1)))))
SET @intProcSpace=@intProcSpace+1
END
--通过sp_helptext逻辑向表#output里插入变量
insert #output (real_decrypt) select @real_decrypt_01

-- -------------------------------------
--开始从sp_helptext提取
-- -------------------------------------
declare @dbname sysname
,@BlankSpaceAdded int
,@BasePos int
,@CurrentPos int
,@TextLength int
,@LineId int
,@AddOnLen int
,@LFCR int --回车换行的长度
,@DefinedLength int
,@SyscomText nvarchar(max)
,@Line nvarchar(255)
Select @DefinedLength = 255
SELECT @BlankSpaceAdded = 0 --跟踪行结束的空格。注意Len函数忽略了多余的空格
CREATE TABLE #CommentText
(LineId int,Text nvarchar(255) collate database_default)
--使用#output代替sys.sysobjvalues
DECLARE ms_crs_syscom CURSOR LOCAL
FOR SELECT real_decrypt from #output
ORDER BY ident
FOR READ ONLY
--获取文本
SELECT @LFCR = 2
SELECT @LineId = 1
OPEN ms_crs_syscom
FETCH NEXT FROM ms_crs_syscom into @SyscomText
WHILE @@fetch_status >= 0
BEGIN
SELECT @BasePos = 1
SELECT @CurrentPos = 1
SELECT @TextLength = LEN(@SyscomText)
WHILE @CurrentPos != 0
BEGIN
--通过回车查找行的结束
SELECT @CurrentPos = CHARINDEX(char(13)+char(10), @SyscomText, 
@BasePos)
--如果找到回车
IF @CurrentPos != 0
BEGIN
--如果@Lines的长度的新值比设置的大就插入@Lines目前的内容并继续
While (isnull(LEN(@Line),0) + @BlankSpaceAdded + @CurrentPos-@BasePos + @LFCR) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength-(isnull(LEN(@Line),0) + @BlankSpaceAdded)
INSERT #CommentText VALUES
( @LineId,isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText,@BasePos, @AddOnLen), N''))
SELECT @Line = NULL, @LineId = @LineId + 1,@BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded = 0
END
SELECT @Line = isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText, @BasePos, @CurrentPos-@BasePos + @LFCR), N'')
SELECT @BasePos = @CurrentPos+2
INSERT #CommentText VALUES( @LineId, @Line )
SELECT @LineId = @LineId + 1
SELECT @Line = NULL
END
ELSE
--如果回车没找到
BEGIN
IF @BasePos <= @TextLength
BEGIN
--如果@Lines长度的新值大于定义的长度
While (isnull(LEN(@Line),0) + @BlankSpaceAdded + @TextLength-@BasePos+1 ) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength - (isnull(LEN(@Line),0) + @BlankSpaceAdded)
INSERT #CommentText VALUES
( @LineId,isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText, @BasePos, @AddOnLen), N''))
SELECT @Line = NULL, @LineId = @LineId + 1, @BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded = 0
END
SELECT @Line = isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText, @BasePos, @TextLength-@BasePos+1 ), N'')
if LEN(@Line) < @DefinedLength and charindex(' ', @SyscomText, @TextLength+1 ) > 0
BEGIN
SELECT @Line = @Line + ' ', @BlankSpaceAdded = 1
END
END
END
END
FETCH NEXT FROM ms_crs_syscom into @SyscomText
END
IF @Line is NOT NULL
INSERT #CommentText VALUES( @LineId,@Line)
--select Text from #CommentText order by LineId
CLOSE ms_crs_syscom
DEALLOCATE ms_crs_syscom


SET @PROTEXT=''
SELECT @PROTEXT=@PROTEXT+Text+CHAR(10) FROM #CommentText WHERE TEXT NOT LIKE '%WITH ENCRYPTION%' order by LineId



DROP TABLE #CommentText
-- -------------------------------------
--结束从sp_helptext提取
-- -------------------------------------
ROLLBACK TRAN
DROP TABLE #output

/**********以下是重建解密后的对象*************/
BEGIN TRAN
BEGIN TRY
SET @sql=@droptype+' '+ @ObjectName
--PRINT @sql
EXEC(@sql)
--PRINT @PROTEXT
EXEC(@PROTEXT)
COMMIT TRAN
END TRY
BEGIN CATCH
PRINT ERROR_MESSAGE()
ROLLBACK TRAN
END CATCH
/**********重建对象完成***********************/