尼克的任务

尼克每天上班之前都连接上英特网，接收他的上司发来的邮件，这些邮件包含了尼克主管的部门当天要完成的全部任务，每个任务由一个开始时刻与一个持续时间构成。

尼克的一个工作日为N分钟，从第一分钟开始到第N分钟结束。当尼克到达单位后他就开始干活。如果在同一时刻有多个任务需要完成，尼克可以任选其中的一个来做，而其余的则由他的同事完成，反之如果只有一个任务，则该任务必需由尼克去写成，假如某些任务开始时刻尼克正在工作，则这些任务也由尼克的同事完成。如果某任务于第P分钟开始，持续时间为T分钟，则该任务将在第P+T-1分钟结束。

写一个程序计算尼克应该如何选取任务，才能获得最大的空暇时间。

 

输入

输入数据第一行包含两个用空格隔开的整数N和K，1≤N≤10000，1≤K≤10000，N表示尼克的工作时间，单位为分，K表示任务总数。

接下来共有K行，每一行有两个用空格隔开的整数P和T，表示该任务从第P分钟开始，持续时间为T分钟，其中1≤P≤N，1≤P+T-1≤N。

 

输出

输出文件仅一行包含一个整数表示尼克可能获得的最大空暇时间。

 

样例

LIGNJA.IN

15 6

1 2

1 6

4 11

8 5

8 1

11 5

 

LIGNJA.OUT

4

 

 

方法一 spfa

 

（画图画了好久TVT）

如图建立一个图直接spfa（把0点和n+1点加入）☆好像动态规划的一个好方法啊 调了有点久终于A了

program LIGNJA;
type
  data=record
         now,quan,next:longint;
       end;
var
  biao:array[0..90001] of data;   //开始爆了所以似乎好像开的有点大啊= =
  a:array[0..10001] of longint;
  f,q:array[0..10001] of longint;
  v:array[0..10001] of boolean;
  n,m,ans:longint;

procedure init;
var i,s,t:longint;
begin
  assign(input,'LIGNJA.in');reset(input);
  assign(output,'LIGNJA.out');rewrite(output);
  fillchar(v,sizeof(v),0);
  fillchar(f,sizeof(f),255);
  fillchar(biao,sizeof(biao),0);
  fillchar(a,sizeof(a),255);
  readln(n,m);
  for i:=1 to m do begin
    readln(s,t);
    biao[i].now:=s+t;biao[i].next:=a[s];biao[i].quan:=0;                           //权值的设定真是很耐人寻味啊╮(╯▽╰)╭
    a[s]:=i;
  end;
  for i:=1 to n do if (a[i]=-1) then begin
    inc(m);
    biao[m].now:=i+1;biao[m].next:=a[i];biao[m].quan:=1;                      //同上
    a[i]:=m;
  end;
  inc(m);
  biao[m].now:=1;biao[m].next:=a[0];biao[m].quan:=0;
  a[0]:=m;
end;

procedure spfa;
var head,tail,i:longint;
begin
  head:=0;tail:=1;
  q[tail]:=0;v[0]:=true;f[0]:=0;
  while (head<>tail) do begin
    inc(head);if (head=10001) then head:=1;
    v[q[head]]:=false;
    i:=a[q[head]];
    while (i<>-1) do begin
      if (f[biao[i].now]<f[q[head]]+biao[i].quan) then begin
        f[biao[i].now]:=f[q[head]]+biao[i].quan;
        if not(v[biao[i].now]) then begin
          inc(tail);if (tail=10001) then tail:=1;
          q[tail]:=biao[i].now;
          v[biao[i].now]:=true;
        end;
      end;
      i:=biao[i].next;
    end;
  end;
  writeln(f[n+1]);
end;

procedure terminate;
begin
  close(input);close(output);
end;

begin
  init;
  spfa;
  terminate;
end.

 

方法二 从后往前推

我之所以要记这一道题 主要的原因是逆推！我开始完全没有想过 ……又是一个好方法 我学到了

当我一切都搞完的时候我开始写这个 没有想到这么简单= = 一次通过啊啊啊啊啊！

所以顺推不好推可以考虑逆推！

program LIGNJA;
type
  node=^point;
  point=record
          now:longint;
          next:node;
        end;
var
  f:array[0..10001] of longint;
  time:array[0..10001] of node;
  n,m,ans:longint;

procedure init;
var i,s,t:longint;
    p:node;
begin
  assign(input,'LIGNJA.in');reset(input);
  assign(output,'LIGNJA.out');rewrite(output);
  fillchar(time,sizeof(time),0);
  fillchar(f,sizeof(f),255);
  readln(n,m);
  for i:=1 to n do time[i]:=nil;
  for i:=1 to m do begin
    readln(s,t);
    new(p);
    p^.now:=s+t;p^.next:=time[s];time[s]:=p;
  end;
end;

function max(a1,a2:longint):longint;
begin
  if (a1>a2) then exit(a1) else exit(a2);
end;

procedure main;
var i:longint;
    p:node;
begin
  f[n+1]:=0;
  for i:=n downto 1 do begin
    if (time[i]=nil) then f[i]:=f[i+1]+1
    else begin
      p:=time[i];
      while (p<>nil) do begin
        f[i]:=max(f[i],f[p^.now]);
        p:=p^.next;
      end;
    end;
  end;
  writeln(f[1]);
end;

procedure terminate;
begin
  close(input);close(output);
end;

begin
  init;
  main;
  terminate;
end.

 

方法三 顺推……

本来我写不来 用了一个n^2的算法但是神奇的AC了 数据到底是有多弱啊！

……其实第一次交的时候只有10分 没有做可行性判断

……n^2太菜了 我看到tyvj有讲没细看 不过我一个同学用nlogn不知道怎么搞出来的