[动态规划]p1051选课

牢记树型dp的代码！重点中间三句

 

 

【问题描述】

 学校实行学分制。每门的必修课都有固定的学分，同时还必须获得相应的选修课程学分。学校开设了N（N<300）门的选修课程，每个学生可选课程的数量M是给定的。学生选修了这M门课并考核通过就能获得相应的学分。

　　在选修课程中，有些课程可以直接选修，有些课程需要一定的基础知识，必须在选了其它的一些课程的基础上才能选修。例如《Frontpage》必须在选修了《Windows操作基础》之后才能选修。我们称《Windows操作基础》是《Frontpage》的先修课。每门课的直接先修课最多只有一门。两门课也可能存在相同的先修课。每门课都有一个课号，依次为1，2，3，…。 例如:

表中1是2的先修课，2是3、4的先修课。如果要选3，那么1和2都一定已被选修过。 　　你的任务是为自己确定一个选课方案，使得你能得到的学分最多，并且必须满足先修课优先的原则。假定课程之间不存在时间上的冲突。
  
  
输入格式 Input Format 
   输入文件的第一行包括两个整数N、M（中间用一个空格隔开）其中1≤N≤300,1≤M≤N。
以下N行每行代表一门课。课号依次为1，2，…，N。每行有两个数（用一个空格隔开），第一个数为这门课先修课的课号（若不存在先修课则该项为0），第二个数为这门课的学分。学分是不超过10的正整数。 

输出格式 Output Format 
   输出文件只有一个数,实际所选课程的学分总数。

【解题报告】

树形DP。先多叉转二叉。F[I,J]表示以I为接点取j门课程能得到的最大分数。

program xuanke;

type
  arr=record
    left,right:longint;
  end;

var
  x,t,y,n,m,i:longint;
  tree:array[0..1001]of arr;
  f:array[0..1001,0..1001]of longint;
  a:array[0..1001]of longint;

function max(a,b:longint):longint;
begin
  if a>b then exit(a);
  exit(b);
end;

function find(x,y:longint):longint;
var
  ans,i:longint;
begin
  if x=-1 then exit(0);
  if f[x,y]<>-1 then exit(f[x,y]);
  if y=0 then exit(0);

  ans:=find(tree[x].right,y);
  for i:=0 to y-1 do
  begin
    ans:=max(ans,find(tree[x].left,i)+find(tree[x].right,y-1-i)+a[x]);
  end;
  f[x,y]:=ans;
  exit(ans);
end;

procedure main;
begin
  readln(n,m);
  fillchar(tree,sizeof(tree),$ff);

  a[0]:=0;
  for i:=1 to n do
  begin
    readln(x,y);
    a[i]:=y;
    if tree[x].left=-1 then tree[x].left:=i
    else
    begin
      t:=tree[x].left;
      while tree[t].right<>-1 do t:=tree[t].right;
      tree[t].right:=i;
    end;
  end;

  fillchar(f,sizeof(f),$ff);
  writeln(find(0,m+1));
end;

begin
  main;
end.