AX2012 查询用户在线操作记录

 

static void ExportSysClientAccessLog(Args _args)
{
    SysClientAccessLog          sysClientAccessLog;

    SysExcelApplication         xlsApplication;
    SysExcelWorkBooks           xlsWorkBookCollection;
    SysExcelWorkBook            xlsWorkBook;
    SysExcelWorkSheets          xlsWorkSheetCollection;
    SysExcelWorkSheet           xlsWorkSheet;
    SysExcelRange               xlsRange;

    int                         row = 1, idx;
    str                         fileName, formName;
    container                   con, conSel;
    ;

    fileName = @"C:\Users\currentUserFileName\Desktop\log\userAccessLog.csv";    

    xlsApplication           = SysExcelApplication::construct();
    xlsWorkBookCollection    = xlsApplication.workbooks();
    xlsWorkBook              = xlsWorkBookCollection.add();
    xlsWorkSheetCollection   = xlsWorkBook.worksheets();
    xlsWorkSheet             = xlsWorkSheetCollection.itemFromNum(1);

    xlsWorkSheet.cells().item(row, 1).value("User Id");
    xlsWorkSheet.cells().item(row, 2).value("Form Name");
    xlsWorkSheet.cells().item(row, 3).value("Operation");
    xlsWorkSheet.cells().item(row, 4).value("DateTime");

    row++;
    
    while select sysClientAccessLog
        where sysClientAccessLog.createdDateTime > 2023-02-14T03:00:00
           && sysClientAccessLog.createdDateTime < 2023-02-15T00:00:00
           && sysClientAccessLog.createdBy == 'admin' // UserName
    {
        con = sysClientAccessLog.EventsContainer;

        for(idx = 1; idx <= conLen(con); idx++)
        {
            conSel = conpeek(con, idx);
            formName = formName2Pname(conPeek(conSel, 1));
            //Information to Excel
            xlsWorkSheet.cells().item(row, 1).value(strFmt("%1", sysClientAccessLog.createdBy));
            xlsWorkSheet.cells().item(row, 2).value(strFmt("%1", formName ? formName : conPeek(conSel, 1)));
            xlsWorkSheet.cells().item(row, 3).value(strFmt("%1", conPeek(conSel, 2)));  
            xlsWorkSheet.cells().item(row, 4).value(strFmt("%1", DateTimeUtil::applyTimeZoneOffset(sysClientAccessLog.createdDateTime, DateTimeUtil::getUserPreferredTimeZone())));

            row++;
        }
    }


    if(WinApi::fileExists(fileName))
        WinApi::deleteFile(fileName);

    xlsWorkbook.saveAs(fileName);
    xlsApplication.visible(true);

    info(strFmt("File has been exported"));
}