实验3 转移指令跳转原理及其简单应用编程

一、实验目的

1. 理解和掌握转移指令的跳转原理

2. 掌握使用call和ret指令实现子程序的方法，理解和掌握其参数传递方式

3. 理解和掌握80×25彩色字符模式显示原理

4. 综合应用寻址方式和汇编指令完成简单应用编程

二、实验准备

复习教材9-10章：

转移指令的跳转原理

汇编指令jmp, loop, jcxz, call, ret, retf的用法

三、实验内容

1. 实验任务1

使用任何一款文本编辑器，录入8086汇编程序源码task1.asm。

task1.asm

assume cs:code, ds:data

data segment 
    x db 1, 9, 3 
    len1 equ $ - x ; 符号常量, $指下一个数据项的偏移地址，这个示例中，是3 
    y dw 1, 9, 3 
    len2 equ $ - y ; 符号常量, $指下一个数据项的偏移地址，这个示例中，是9 
data ends 

code segment 
start:
    mov ax, data 
    mov ds, ax 

    mov si, offset x ; 取符号x对应的偏移地址0 -> si 
    mov cx, len1 ; 从符号x开始的连续字节数据项个数 -> cx 
    mov ah, 2 
s1:mov dl, [si] 
    or dl, 30h 
    int 21h
 
    mov dl, ' ' 
    int 21h ; 输出空格 

    inc si 
    loop s1 

    mov ah, 2 
    mov dl, 0ah 
    int 21h ; 换行 

    mov si, offset y ; 取符号y对应的偏移地址3 -> si 
    mov cx, len2/2 ; 从符号y开始的连续字数据项个数 -> cx 
    mov ah, 2 
s2:mov dx, [si] 
    or dl, 30h 
    int 21h
 
    mov dl, ' ' 
    int 21h ; 输出空格 

    add si, 2 
    loop s2 

    mov ah, 4ch 
    int 21h 
code ends 
end start      

源代码运行结果：

 

 ①

 line27 loop命令的机器码为E2F2，F2的八位二进制形式为11110010，其补码为10001110，十进制形式为-14,即位移量为14

从CPU角度来看，此时cs：ip指向line27的内存单元，读取loop s1进入指令缓冲器

首先通过读取指令的长度修改ip的值，ip=ip+指令长度

然后执行loop s1，跳转到s1处，位移量等于s1处的偏移地址减去当前ip指向地址的偏移地址

②

 

line44 loop命令的机器码为E2F0，F0的八位二进制形式为11110000，补码为10010000，十进制形式为-16，即位移量为16

从CPU角度来看，此时cs：ip指向line44的内存单元，读取loop s2进入指令缓冲器

首先通过读取指令的长度修改ip的值，ip=ip+指令长度

然后执行loop s2，跳转到s2处，位移量等于s2处的偏移地址减去当前ip指向地址的偏移地址

 

2. 实验任务2

使用任何一款文本编辑器，录入8086汇编程序源码task2.asm。

task2.asm

assume cs:code, ds:data 

data segment 
    dw 200h, 0h, 230h, 0h 
data ends 

stack segment 
    db 16 dup(0) 
stack ends 

code segment 
start:
    mov ax, data 
    mov ds, ax 
    mov word ptr ds:[0], offset s1 
    mov word ptr ds:[2], offset s2 
    mov ds:[4], cs 

    mov ax, stack 
    mov ss, ax 
    mov sp, 16 

    call word ptr ds:[0] 
s1: pop ax 

    call dword ptr ds:[2] 
s2: pop bx 
    pop cx 
    mov ah, 4ch 
    int 21h 
code ends 
end start 

 分析： call word ptr ds:[0] 短转移, 将下一条指令偏移地址(ip)压入栈, 并转移至 ds:[0]地址即 s1 处, 此后的 pop ax 将该内容出栈给ax;
             call dword ptr ds:[2]为段间转移, 将下一条指令基址和偏移地址(cs 和 ip)压入栈, 并转移至 ds:[2] 地址即 s2 处, 此后的 pop bx 将ip出栈给bx, pop cx 将 cs 出栈给 cx.

 

 

所以AX=0021 BX=0026 CX=076C

根据debug之后验证AX，BX，CX正确

 

3. 实验任务3

实验要求：

针对8086CPU，已知逻辑段定义如下：

编写8086汇编源程序task3.asm，在屏幕上以十进制形式输出data段中这一组连续的数据，数据和数据

之间以空格间隔。

data segment 
    x db 99, 72, 85, 63, 89, 97, 55 
    len equ $- x 
data ends

要求：

编写子程序printNumber

功能：以十进制形式输出一个两位数

入口参数：寄存器ax（待输出的数据 --> ax）

出口参数：无

编写子程序printSpace

功能：打印一个空格

入口参数：无

出口参数：无

在主体代码中，综合应用寻址方式和循环，调用printNumber和printSpace, 实现题目要求。

源码如下：

assume cs:code, ds:data
 
data segment
    x    db  99, 72, 85, 63, 89, 97, 55
    len    equ $- x
data ends
 
code segment
    start:     
        mov ax, data
        mov ds, ax
        
        mov cx, len
        mov si, 0
    print:
        mov al, [si]
        mov ah, 0
        call printNumber
        call printSpace
        inc si
        loop print
 
        mov ah, 4ch
        int 21h

    printNumber:
        mov bl, 10
        div bl
        mov bx, ax
        
        mov ah, 2
 
        mov dl, bl    ; 打印商
        or dl, 30h
        int 21h
 
        mov dl, bh    ; 打印余数
        or dl, 30h
        int 21h
        ret
             
    printSpace:
        mov ah, 2
        mov dl, ' '
        int 21h
        ret
 
code ends
end start

测试结果如下：

 

 

4. 实验任务4

实验要求：

针对8086CPU，已知逻辑段定义如下：

data segment 
    str db 'try' 
    len equ $ - str 
data ends

编写8086汇编源程序task4.asm，在屏幕上以指定颜色、指定行，在屏幕上输出字符串。

要求：

编写子程序printStr

功能：在指定行、以指定颜色，在屏幕上显示字符串

入口参数

字符串首字符地址 --> ds:si（其中，字符串所在段的段地址—> ds, 字符串起始地址的偏

移地址—> si）

字符串长度 --> cx

字符串颜色 --> bl

指定行 --> bh （取值：0 ~24）

出口参数：无

在主体代码中，两次调用printStr，使得在屏幕最上方以黑底绿字显示字符串，在屏幕最下方以黑

底红色显示字符串

源码：

assume cs:code
data segment
    str db    'try'
    len equ    $ - str
data ends

stack segment
    dw 2 dup(?)
stack ends

code segment
start:
    mov ax, data
    mov ds, ax
    mov ax, stack
    mov ss, ax
    mov sp, 2

    mov cx, len         ;字符串长度
    mov ax, 0
    mov si, ax

     mov bl, 0Ah    ;绿色字符
    mov bh, 0    ;行号
     call printStr

    mov bl, 0Ch    ;红色
    mov bh, 24
    call printStr
    
    mov ah, 4ch
    int 21h

printStr:
    mov al, bh
    mov dl, 0A0h    ;一行160字节
    mul dl
    
    mov di, ax    ;行起始地址
    mov ax, 0b800h    ;显存起始地址
    mov es, ax

    push si
    push cx
    startPrint:
        mov al, ds:[si]
        mov es:[di], al    ;放入字符
        mov es:[di+1], bl    ;放入颜色
        inc si
        inc di
        inc di
    loop startPrint

    pop cx
    pop si
    ret

code ends
end start

输出结果如下：

5. 实验任务5

实验要求：

针对8086CPU，针对8086CPU，已知逻辑段定义如下：

data segment 
    stu_no db '201983290032' 
    len = $ - stu_no 
data ends

在80×25彩色字符模式下，在屏幕最后一行正中间显示学号。要求输出窗口蓝底，学号和两侧折线，以

白色前景色显示。

源码：

assume cs:code, ds:data

data segment
    stu_no db '201983290032' 
    len = $ - stu_no 
data ends

code segment
start:
    mov ax, data
    mov ds, ax
    mov di, 0

    call printStuNum
    
    mov ah, 4ch
    int 21h

printStuNum:
    mov ax, 0b800h
    mov es, ax
    mov si, 1

    mov al, 24
    mov dl, 80
    mul dl
    
    mov cx, ax
    printBlue:
        mov al, 17h    ;00010111
        mov es:[si], al    ;填充颜色
        add si, 2
    loop printBlue

    sub si, 1
    mov ax, 80
    sub ax, len
    mov dl, 2
    div dl
    mov dx, ax    ;保存-的长度

    mov cx, dx
    call printheng

    mov cx, len
    printStu:    ;输出学号
        mov al, ds:[di]
        mov ah, 17h
        mov word ptr es:[si], ax
        inc di
        add si, 2
    loop printStu

    mov cx, dx
    call printheng

    ret
    
printheng:
    mov al, '-'
    mov ah, 17h
    mov word ptr es:[si], ax
    add si, 2
    loop printheng
    ret
     
code ends
end start

 

 

输出结果：

 

 

四、实验总结

1.可以将要用到多次并且在使用过程中会产生变化的值，先压入栈，使用完之后出栈，方便之后的使用

2.通过这次实验更加理解了call和ret的使用方式，可以简单理解为类似汇编语言版的函数调用，但是更加底层以及更加基础

3.将数字写入显示内存要转换成对应的ascii码，不能直接写入