IDEA中使用Generate POJOs.groovy 生成实体类

一、定制groovy脚本

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat
/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.demo.model;"
typeMapping = [
        (~/(?i)int/)                      : "Long",
        (~/(?i)float|double|decimal|real/): "Double",
        (~/(?i)datetime|timestamp/)       : "Date",
        (~/(?i)date/)                     : "Date",
        (~/(?i)time/)                     : "java.sql.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = className(table.getName()).capitalize()
  def fields = calcFields(table)
  packageName = getPackageName(dir)
  //new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields) }
  PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
  printWriter.withPrintWriter {out -> generate(out, className, fields,table)}
}

def generate(out, className, fields,table) {
  out.println "package $packageName"
  out.println ""

  // 判断是否需要引入Date
  boolean dateFlag = false
  fields.each() {
    if(it.type.contains("Date")){
      dateFlag = true
    }
  }
  if(dateFlag){
    out.println "import java.util.Date;"
  }

  // 判断表名的注释，为空时设置为表名
  def tableComment = table.getComment()
  if(null == tableComment){
    tableComment = table.getName()
  }

  out.println "import lombok.Data;"
  out.println "import javax.persistence.Table;"
  out.println "import javax.persistence.Column;"
  out.println "import io.swagger.annotations.ApiModel;"
  out.println "import io.swagger.annotations.ApiModelProperty;"

  out.println ""

  out.println "/**\n" +
          " * @Description " + tableComment + " \n" +
          " * @Author yangli\n" +
          " * @Date "+ new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
          "**/"
  out.println "@Data"
  out.println "@ApiModel(\"" + tableComment + "\")"
  out.println "@Table(name = \"" + table.getName() + "\")"
  out.println "public class $className {"
  out.println ""
  fields.each() {
    // 输出注释
//    if (isNotEmpty(it.commoent)) {
//      out.println " /**"
//      out.println "  * ${it.commoent.toString()}"
//      out.println "  */"
//    }
    // 改为swagger注解
    if (isNotEmpty(it.commoent)) {
      out.println "    @ApiModelProperty(value = \"" + it.commoent.toString() + "\")"
    }

    out.println "    @Column(name = \"" + it.realColumnName.toString() + "\")"

    if (it.annos != "") out.println "  ${it.annos}"
    out.println "    private ${it.type} ${it.name};"
  }
  out.println ""
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                       name : javaName(col.getName(), false),
                       type : typeStr,
                       commoent: col.getComment(),
                       realColumnName : col.getName(), //20190825 新增未处理列名
                       annos: ""]]
  }
}

def className(str) {
  // 过滤表名最后的_T
  boolean endFlag = str.endsWith('_T')
  if(endFlag){
    str = str.substring(0, str.length()-2)
  }
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
          .collect { Case.LOWER.apply(it).capitalize() }
          .join("")
          .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
          .collect { Case.LOWER.apply(it).capitalize() }
          .join("")
          .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}
// 获取包所在文件夹路径
def getPackageName(dir) {
  return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

 

二、操作

三、打完收功~