big tree

导航

Introduction to Big Real Mode

转自Merck Hung merck@olux.org, 洪豪謙

应朋友的要求, 希望我花一点时间整理一下 x86 Big Real Mode 的文章.另外也发现, 身边似乎有一些朋友也准备要开始从事 BIOS 方面之工作了.感谢你们偶而会來逛一下我的 Blog.虽然网路上已经有蛮多资料了, 不过今天我打算从 Intel 64 and IA32 Architecture Software Developer’s Manual (后面简称SDM), 以及 x86 Processor 的角度, 來解說如何打开 Big Real Mode.我将会花时间解說 Intel SDM 内的资料, 最后才丢一段 Code 给你.例如說明什么是 Big Real Mode, 地址空间的差異, A20, Segment Descriptor 等细节.而我会另外找时间再把 Protected Mode + Paging + PSE (存取大于 4GB Memory) 写完.

感谢啰!

　　

Big Real Mode 定义

Big Real Mode 是一个有趣的 x86 Processor Mode, 正好处在 32bit protected mode 与 16bit real mode 中间.

Fig.1, Real Mode, Big Real Mode, 与 Protected Mode 比较图

　　以上图來說, Real Mode 的 Code 与 Data Segment 的最大范围均为 1MB (16bit).当 CPU 进入 Protected Mode 之后, Code 与 Data Segment 的最大范围将可以达到 4GB.而 Big Real Mode 很神奇的是, Code Segment 维持原來 1MB (16bit) 的限制, 但 Data Segment却可以存取到整个 4GB 的空间.

　　因为一般 real mode 只有办法存取到 1MB Memory, 然而以现在的计算机配备來說, 动辄 1GB, 2GB,或 4GB 的内存大小. 如果 BIOS 单纯仅运作在 real mode 内, 那样根本完全无法存取到你所安装的所有内存.而一般 OS, 如 Windows, Linux 等, 皆是以打开 protected mode 來存取到整个 4GB 的Memory Space.

　　但因为 BIOS Code 大部分都是以 real mode 撰写的, 所以当有那个需求要存取 1MB 以上的记忆体时, big real mode 就会是一个不错的选择.

　　虽然 protected mode 也可以达成存取 4GB 的目的, 但如果程序本身所执行的环境是 DOS 或BIOS Code 的话, 打开 protected mode 反而会造成麻烦. 例如你会无法呼叫原來写给 real mode呼叫的一些 routines, 或是必须频频不断的在兩个 mode 之间切换.

 

Address Space 差異

　　

Fig.2, Real Mode 与 Protected Mode 地址空间之差異

　　在 real mode 中, CPU 最后实际存取 Memory 的位置 (Physical Address 或 Linear Address), 是透过 Segment Address 向左 Shift 4 bits, 然后加上 Offset Address 來计算.故 real mode 的 address space range 是从 0_0000 ~ F_FFFF, 也就是只能组合出 1MB 的空间.

　　而在 protected mode (或 big real mode) 中, 原 real mode 中的 “segment register” 换了个名称与定义, 改称作 “segment selector”. 而这个 “segment selector” 将不是直接填写 Address, 而改为载入 Segment Descriptor 在 GDT Table 裡面的 Offset Address.

　　而 Segment Descriptor 内将会含有 Base Address 这个栏位, 用以說明 Segment 起始地址.故将 Segment Descriptor 内之 Base Address, 加上 Offset Address 后, 便是实际 CPU 所将存取的 Memory 位置 (Physical Address 或 Linear Address).

 

Enable 与 Disable 流程

Fig.3, Enable 与 Disable Big Real Mode 的流程图

打开 Big Real Mode 的程序:

1. 设定 Global Descriptor Table (GDT)

2. 载入 GDT Pointer 的 Physical Address 到 GDTR Register

3. 打开 A20

4. Enable Protected Mode Bit, CR0 Bit 0 = 1, 并作一个 Flush Jump

5. 将 4GB 的 Data Segment Selector 载入 DS, ES, FS, GS

6. Disable Protected Mode Bit, CR0 Bit 0 = 0

7. 作一个 Far Jump Flush

 

关闭 Big Real Mode 的程序:

1. 关闭 A20

2. 将 DS, ES, FS, GS 的内容设定 (或从 Stack pop 回來) 为 Real Mode Segment Offset 即可

 

A20 开关

Fig.4, 在 Real Mode 中, A20 Enabled 所多出之約 64k Address Space

　　在早期 8086 CPU 位址線只有 20 條, 所以造就了 Segment:Offset 這樣的存取方式. 但其實大家可以注意到, FFFF:000F = FFFFF (1MB), 其中 Offset Address 還沒填到最大值 FFFF. 但因為8086 只有 20 隻腳位, 所以超過 FFFFF (1MB) 的搭配, CPU 將會回繞回 0MB 起算.

　　而後來的 CPU 的位址線增加, 如 286 有 24 隻腳位, 386 以上有 32 隻腳位. 但為了維持 PC架構的相容性, 所以增加了 A20 這樣的開關, 在 A20 關閉時讓超過 1MB 的寻址做回绕到 1MB的动作. 但只要 A20 打开后, 超过 1MB 将不会有回绕动作.

　　而在 real mode 中, 因为使用 Segment:Offset 的存取方式, 所以打开了 A20 后, 大约只能增加64k 左右的空间 (10000 ~ 10FFEF).但也因为 A20 开关牵涉到地址线回绕的问题, 所以当我们打算进入 protected mode (使用全部 32只地址线) 之前, 打开 A20 开关也是一个重要的课题.

 

GDT 与 Segment Descriptor

　　有别于 16bit real mode 将Segment Address 直接加载 DS, ES, FS, GS (Data Segment Registers) 的方式.在 protected mode 内, DS, ES, FS, GS 转换了一个名称, Segment Selector.因为 DS, ES, FS, GS 还是维持原來 16bit 的大小, 并非像 AX, BX,……等 16bit 缓存器, 推出32bit 的版本, 如: EAX, EBX,……等.

　　但因为 32bit protected mode 存取 Data 的方法还是维持 DS:XX, ES:XX, FS:XX, GS:XX 的方式,所以 Intel 提供存取 4GB 的新方法, 而这个方式就是利用 Segment Descriptor 与 Segment Selector.

Fig.5, Segment Descriptor 定义 Segment 的与地址的对应关系

一般为了方便使用, Segment Base Address 通常会被设为 0, 而 Segment Limit 会设为 4GB. 这不是我所创造的惯例, 而是现在的操作系统都是这样使用. 甚至现在支持 64bit 的 CPU, 在进入64bit long mode 后, Segment 这样的 feature 已经干脆被舍弃了 (因为过去大家都直接开 4GB,等同于不使用 Segment 这个特性).

 

Fig.6, Intel SDM Vol.3 3-13, Segment Descriptor 各栏位說明

由上图所知, Segment Descriptor 是一个 8 bytes 的资料结构.

其中 Base Address (31:00, 32bit), 将会用來 “說明”, 这个 Segment 的起始地址.

而 Segment Limit (19:00, 20bit), 将会用來 “說明”, 从起始地址开始算起的 “长度”, 是属于这个Segment.

而 G 栏位用來决定 Segment Limit 的单位, 0 为 1 bytes, 1 为 4k. 因为 Segment Limit 只有20bit, 所以当 G=0 (1 bytes) 时, 最大只能涵盖到 1MB. 但当 G=1 (4 kbytes) 时, 最大就能涵盖到4GB.

Type 是一个 4bit 栏位, 总共有 16 种 Type 可供填写, 主要的分類是 Code 或 Data, 细项分類将于 protected mode 一文中說明.

P 栏位让 OS 用來表示这个 Segment 是否被 Swap Out 到硬盘上, 而没有实际在内存上.

S 栏位, 为 0 时表示 System Segment, 为 1 时表示 Code 或 Data Segment.

 1 ;##############################################################################
 2 ; Globel Descriptor Table (GDT)
 3 ;
 4 align 16
 5 GDT_TABLE:
 6 ; NULL segment
 7 DW 0, 0, 0, 0 ; 四個 WORD 等於 8 bytes
 8 ; Data segment, read/write
 9 FLAT_DATA_SEG EQU $ - GDT_TABLE
10 DW 0FFFFh
11 DW 0
12 DW 9200h
13 DW 00CFh
14 GDT_SIZE EQU $ - GDT_TABLE
15 ;
16 ; GDT Pointer
17 ;
18 GDT_POINTER:
19 DW GDT_SIZE - 1
20 DW 0 ;
21 DW 0 ; GDT base address

我们來看一个实际的范例, 设定 GDT 的主要重点是:

1. GDT 起头要对齐 16 bytes (align 16)

2. 第一个 Segment Descriptor 务必要为NULL Segment

3. 最后需要填写GDT Pointer, Pointer 的 Linear Address 将用于加载 CPU 的GDTR 缓存器.

4. 整个GDT 的 Size 及 GDT 的起始 Linear Address 需填入 GDT Pointer.

　　而以 Big Real Mode 來說, 我们只需设定一个Data Segment Descriptor, 而FLAT_DATA_SEG就是所谓的Segment Selector (此例中为 08h), 将会用于载入 DS, ES, GS, FS 缓存器.

 

 

 Fig.7,范例中各栏位 Bit标示

Segment Base = 0000_0000h

G = 1, 单位 = 4 kbytes

Segment Limit (00:19) = F_FFFFh

Segment Limit = 4GB (FFFF_FFFFh)

D/B = 1, 32bit Segment (为存取 4GB, 故为 32bit 区段)

DPL = 0, Kernel Segment, Ring 0 (属于 Kernel Ring 0, 最大权限)

Type = 2, Data Read/Write Segment (属于资料, 可讀可写区段)

AVL = 0, Reserved (保留)

L = 0, Reserved (保留)

P = 1, Present in Physical Memory (预设 1)

S = 1, Code or Data Segment (程序或资料区段)

 

Sample Code – Enter and Leave Big Real Mode

  1 LIBFLAT SEGMENT USE16 'CODE'
  2 ;##############################################################################
  3 ; __enter_flat_mode – Enter Big Real Mode, 进入 Big Real Mode
  4 ;
  5 ; Input:
  6 ; None
  7 ;
  8 ; Output:
  9 ; None
 10 ;
 11 ; Modified:
 12 ; All possible
 13 ;
 14 __enter_flat_mode PROC FAR PUBLIC
 15 ; Convert GDT base physical address to linear one
 16 ; 将 GDT 的 Base Address, 由 Segment:Offset 转为 Linear Address
 17 xor eax, eax ; 另 EAX = 0 (32bit)
 18 mov ax, cs ; 将 Code Segment Address 放入 AX (16bit)
 19 shl eax, 4 ; EAX (32bit) 向左位移 4 的 bits
 20 add eax, OFFSET GDT_TABLE ; 加法演算, 加上 GDT 在 Code Segment 内的 Offset
 21 mov dword ptr GDT_POINTER+2, eax ; 将 EAX (32bit) 的结果值, 写入 GDT Pointer (本來为 0)
 22 ; Save original GDT and Load new one
 23 ; 利用 LGDT 指令, 将 GDT Pointer 加载 CPU 的 GDTR 缓存器
 24 lgdt fword ptr GDT_POINTER
 25 ; Disable interrupt
 26 ; 关闭 CPU 中断
 27 cli
 28 ; Enable A20
 29 ; 打开 A20
 30 in al, 92h ; 从 Keyboard Controller (IO Port 92h) 讀入
 31 or al, 02h ; 将 Bit 1, A20 设为 1
 32 out 92h, al ; 写回 Keyboard Controller
 33 ; Enable protected mode
 34 ; 打开 CR0 Bit 0, 也就是 protected mode
 35 mov eax, cr0 ; 先将 CR0 讀入 EAX
 36 or eax, 01h ; 将 Bit 0, PM Flag 设定为 1
 37 mov cr0, eax ; 将 EAX 写入 CR0
 38 jmp @f ; Flush Jump, 让 CPU 更新狀态
 39 @@: ; Flush Jump 到这裡
 40 没有 Far Jump 的指令, 所以我们直接利用 DB, DW 等 Macro 來写 CPU 指令
 41 ; OpCode 部分是 EAh, 后面第一个 WORD 是 Offset Address, 第二个是 Segment Address
 42 DB 0eah ; Far Jump 指令的 OpCode
 43 DW OFFSET @f ; 请组译器帮我们填 Offset Address
 44 DW SEG @f ; 请组译器帮我们填 Segment Address
 45 @@: ; Far Jump 到这裡
 46 ret
 47 __enter_flat_mode ENDP
 48 ;##############################################################################
 49 ; __exit_flat_mode – Leave Big Real Mode, 離开 Big Real Mode
 50 ;
 51 ; Input:
 52 ; None
 53 ;
 54 ; Output:
 55 ; None
 56 ;
 57 ; Modified:
 58 ; All possible
 59 ;
 60 __exit_flat_mode PROC FAR PUBLIC
 61 ; Disable A20
 62 ; 关闭 A20
 63 in al, 92h ; 从 Keyboard Controller 讀入
 64 and al, not 02h ; 将 Bit 1, A20 设为 0
 65 out 92h, al ; 写回 Keyboard Controller
 66 ; Reenable interrupt
 67 ; 重新打开中断
 68 sti
 69 ret
 70 __exit_flat_mode ENDP
 71 ;##############################################################################
 72 ; Globel Descriptor Table (GDT)
 73 ;
 74 align 16
 75 GDT_TABLE:
 76 ; NULL segment
 77 DW 0, 0, 0, 0
 78 ; Data segment, read/write
 79 FLAT_DATA_SEG EQU $ - GDT_TABLE
 80 DW 0ffffh
 81 DW 0
 82 DW 9200h
 83 DW 00cfh
 84 GDT_SIZE EQU $ - GDT_TABLE
 85 ;
 86 ; GDT Pointer
 87 ;
 88 GDT_POINTER:
 89 DW GDT_SIZE - 1
 90 DW 0 ;
 91 DW 0 ; GDT base address
 92 LIBFLAT ENDS
 93 ;##############################################################################
 94 ; enter_flat_mode -- Enter Big Real Mode, 进入 Big Real Mode
 95 ;
 96 ; Input:
 97 ; None
 98 ;
 99 ; Output:
100 ; None
101 ;
102 ; Modified:
103 ; All possible
104 ;
105 enter_flat_mode MACRO
106 ; Save segment for FLAT exit
107 ; 因为我们会将 DS, ES 设定为 4GB, 所以一般应用可以在进入前, 将原 DS, ES 推入 Stack
108 push ds
109 push es
110 call __enter_flat_mode
111 ENDM
112 ;##############################################################################
113 ; exit_flat_mode -- Leave Big Real Mode, 離开 Big Real Mode
114 ;
115 ; Input:
116 ; None
117 ;
118 ; Output:
119 ; None
120 ;
121 ; Modified:
122 ; All possible
123 ;
124 exit_flat_mode MACRO
125 ; Restore original segments
126 ; 回存进入时所推入的 ES, DS, Segment Address 值, 來回復 real mode 64k.
127 pop es
128 pop ds
129 call __exit_flat_mode ; 关闭 A20, 打开中断
130 ENDM
131 ;------------------------------------------------------------------------------
132 ; Code segment
133 ;
134 _TEXT SEGMENT PARA USE16 'CODE'
135 libflat SEGMENT USE16 PUBLIC
136 EXTERN __enter_flat_mode:FAR
137 EXTERN __exit_flat_mode:FAR
138 @CurSeg ENDS
139 ;##############################################################################
140 ; MAIN procedure
141 ;
142 MAIN PROC FAR PRIVATE
143 ; Save for DOS return
144 push ds
145 push ax
146 ASSUME SS:STACK, DS:_DATA, CS:_TEXT, ES:_DATA
147 mov ax, _DATA
148 mov ds, ax
149 mov es, ax
150 ;--------------------------------------------------------------------------
151 ; Enter FLAT mode
152 ;--------------------------------------------------------------------------
153 enter_flat_mode ; 进入 Big Real Mode
154 ;--------------------------------------------------------------------------
155 ; FLAT mode code start
156 ;--------------------------------------------------------------------------
157 ; 存取 Linear Address 12345678h, 讀入 Double Word 到 EAX
158 mov esi, 12345678h ; 将 ESI 设为 12345678h
159 mov eax, ds:esi ; 将 Linear Address 12345678h 的内容, 讀入 EAX
160 ;--------------------------------------------------------------------------
161 ; Exit FLAT mode
162 ;--------------------------------------------------------------------------
163 exit_flat_mode ; 離开 Big Real Mode
164 ;--------------------------------------------------------------------------
165 ; REAL mode code
166 ;--------------------------------------------------------------------------
167 ; Return to DOS
168 ret
169 MAIN ENDP
170 _TEXT ENDS

 

 

 

posted on 2015-12-04 15:07  big tree  阅读(1338)  评论(0)  编辑  收藏  举报