EBS: FORM窗体开发使用VIEW模式开发,plsql DEVELOPER 自动生成PLSQL脚本

FORM窗体开发使用VIEW模式开发,plsql DEVELOPER 自动生成PLSQL脚本,

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
CREATE OR REPLACE PACKAGE APPS.HAND_PLSQL_AUTOCREATE AUTHID CURRENT_USER AS
/* $Header: HDPLSATC.pls 115.1 2004/09/02 15:33:09 pkm ship   $ */
 
  PROCEDURE regist_table( p_table_name IN VARCHAR2,
                          p_owner      IN VARCHAR2,
                          p_appl_short_name IN VARCHAR2 DEFAULT NULL);
 
  PROCEDURE form_view_iud( p_block_name  IN VARCHAR2,
                           p_table_name  IN VARCHAR2,
                           p_owner       IN VARCHAR2,
                           p_primary_key IN VARCHAR2);
 
  PROCEDURE table_handle_pkg( p_table_name  IN VARCHAR2,
                              p_owner       IN VARCHAR2,
                              p_primary_key IN VARCHAR2);
 
  PROCEDURE form_table_handle( p_block_name   IN VARCHAR2,
                               p_package_name IN VARCHAR2,
                               p_table_name   IN VARCHAR2,
                               p_primary_key  IN VARCHAR2);
 
END HAND_PLSQL_AUTOCREATE;
/
 
CREATE OR REPLACE PACKAGE BODY APPS.HAND_PLSQL_AUTOCREATE AS
/* $Header: HDPLSATC.pls 115.1 2004/09/02 15:33:09 pkm ship   $ */
/**-----------------------------------------------------------------------------------------
 **   HISTORY:
 **     Date         Author               Description
 **     -----------  -------------------  --------------------------------------------------
 **     2004-09-02   jim.lin              creation
 **------------------------------------------------------------------------------------------- */
 
  g_output_first   BOOLEAN := FALSE;
  g_cp_flag        NUMBER;           -- conc program
  g_newline        VARCHAR2(1) := CHR(10);
 
  TYPE COLUMN_REC_TYPE IS RECORD
       ( COLUMN_NAME     VARCHAR2(30),
         NULLABLE        VARCHAR2(1),
         DATA_TYPE      VARCHAR2(106) );
 
  TYPE COLUMN_TBL_TYPE IS TABLE OF COLUMN_REC_TYPE INDEX BY BINARY_INTEGER;
 
  PROCEDURE output_msg( p_msg_data     IN VARCHAR2)
  IS
  BEGIN
    IF g_output_first = FALSE THEN
       g_cp_flag := fnd_profile.value('CONC_REQUEST_ID');
       IF g_cp_flag > 0 THEN
          NULL;
       ELSE
          dbms_output.enable(buffer_size => 20000000);
       END IF;
    END IF;
 
        if ( g_cp_flag > 0 ) then
            FND_FILE.put_line(FND_FILE.LOG, p_msg_data);
        else
            dbms_output.put_line(p_msg_data);
        end if;
  EXCEPTION
     WHEN OTHERS THEN
        NULL;
  END output_msg;
 
  PROCEDURE regist_table( p_table_name IN VARCHAR2,
                          p_owner      IN VARCHAR2,
                          p_appl_short_name IN VARCHAR2 DEFAULT NULL)
  IS
    CURSOR c_table
    IS SELECT t.owner, nvl(t.next_extent,2) next_extent, t.pct_free, t.pct_used
         FROM all_tables t
        WHERE t.table_name = p_table_name
          AND t.owner      = p_owner;
 
    CURSOR c_columns
    IS SELECT tc.column_id, tc.column_name, tc.data_type,
              decode(tc.data_type, 'NUMBER', 38, 'DATE', 9, tc.char_length) col_width,
              tc.nullable
         FROM all_tab_columns tc
        WHERE tc.table_name = p_table_name
          AND tc.owner      = p_owner
          AND tc.data_type IN ('VARCHAR2','VARCHAR','NCHAR','NVARCHAR2','NUMBER','DATE')
        ORDER BY tc.column_id;
 
    l_appl_short_name     VARCHAR2(30);
    l_table_rec           c_table%ROWTYPE;
 
    l_msg_data            VARCHAR2(2000);
  BEGIN
    IF p_appl_short_name IS NULL THEN
       l_appl_short_name := p_owner;
    ELSE
       l_appl_short_name := p_appl_short_name;
    END IF;
 
    OPEN c_table;
    FETCH c_table INTO l_table_rec;
    IF c_table%NOTFOUND THEN
       CLOSE c_table;
       l_msg_data := 'Table ' || p_table_name || ' not found';
       RAISE fnd_api.g_exc_error;
    END IF;
    CLOSE c_table;
 
    -- regist table
    l_msg_data := 'EXECUTE AD_DD.REGISTER_TABLE(''' || l_appl_short_name || ''','''
                  || p_table_name || ''',''T'',' || l_table_rec.next_extent || ','
                  || l_table_rec.pct_free || ',' || l_table_rec.pct_used || ');';
    output_msg(l_msg_data);
 
    -- regist column
    FOR r IN c_columns LOOP
       l_msg_data := 'EXECUTE AD_DD.REGISTER_COLUMN(''' || l_appl_short_name || ''','''
                     || p_table_name || ''',''' || r.column_name || ''',' || r.column_id || ','''
                     || r.data_type || ''',' || r.col_width || ',''' || r.nullable || ''',''N'');';
       output_msg(l_msg_data);
    END LOOP;
 
  EXCEPTION
     WHEN fnd_api.g_exc_error THEN
         output_msg(l_msg_data);
     WHEN OTHERS THEN
         output_msg(SQLERRM);
  END regist_table;
 
  PROCEDURE form_view_iud( p_block_name  IN VARCHAR2,
                           p_table_name  IN VARCHAR2,
                           p_owner       IN VARCHAR2,
                           p_primary_key IN VARCHAR2)
  IS
    CURSOR c_table
    IS SELECT 'Y'
         FROM all_tables t
        WHERE t.table_name = p_table_name
          AND t.owner      = p_owner;
 
    CURSOR c_columns
    IS SELECT tc.column_name, tc.nullable
         FROM all_tab_columns tc
        WHERE tc.table_name = p_table_name
          AND tc.owner      = p_owner
        ORDER BY tc.column_id;
 
    l_dummy          VARCHAR2(1);
    l_msg_data       VARCHAR2(2000);
    l_package_name   VARCHAR2(100);
    l_block_name_ext VARCHAR2(50) := ':' || p_block_name || '.';
    l_rec_ext        VARCHAR2(30) := 'rec.';
 
    l_column_tbl     COLUMN_TBL_TYPE;
    l_column_count   NUMBER := 0;
 
  BEGIN
    -- check table exists
    OPEN c_table;
    FETCH c_table INTO l_dummy;
    IF c_table%NOTFOUND THEN
       CLOSE c_table;
       l_msg_data := 'Table ' || p_table_name || ' not found';
       RAISE fnd_api.g_exc_error;
    END IF;
    CLOSE c_table;
    -- get columns
    FOR r IN c_columns LOOP
       l_column_count := l_column_count + 1;
       l_column_tbl(l_column_count).column_name := r.column_name;
       l_column_tbl(l_column_count).nullable := r.nullable;
    END LOOP;
 
    IF l_column_count < 1 THEN
       l_msg_data := 'Not column in table';
       RAISE fnd_api.g_exc_error;
    END IF;
 
    l_package_name := upper(p_block_name) || '_PRIVATE';
    -- generate package special
    l_msg_data := 'PACKAGE ' || l_package_name || ' IS' || g_newline || g_newline ||
                  '  PROCEDURE insert_row;' || g_newline ||
                  '  PROCEDURE lock_row;' || g_newline ||
                  '  PROCEDURE update_row;' || g_newline ||
                  '  PROCEDURE delete_row;' || g_newline || g_newline ||
                  'END ' || l_package_name || ';' || g_newline;
 
    output_msg(l_msg_data);
 
    -- generate package body
    -- begin
    l_msg_data := 'PACKAGE BODY ' || l_package_name || ' IS' || g_newline;
    output_msg(l_msg_data);
 
    -- insert row
    l_msg_data := '/*=====================================' || g_newline ||
                  '** PROCEDURE:    insert_row()' || g_newline ||
                  '**=====================================*/' || g_newline ||
                  'PROCEDURE insert_row IS' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  CURSOR row_id' || g_newline ||
                  '  IS SELECT rowid' || g_newline ||
                  '       FROM ' || p_table_name || g_newline ||
                  '      WHERE ' || p_primary_key || ' = ' || l_block_name_ext || p_primary_key || ';' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  fnd_standard.set_who;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  IF ' || l_block_name_ext || p_primary_key || ' IS NULL THEN' || g_newline ||
                  '    SELECT ' || upper(p_table_name) || '_S.NEXTVAL' || g_newline ||
                  '      INTO ' || l_block_name_ext || p_primary_key || g_newline ||
                  '      FROM SYS.DUAL;' || g_newline ||
                  '  END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  INSERT INTO ' || p_table_name || ' (';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       IF i = l_column_count THEN
          l_msg_data := '     ' || l_column_tbl(i).column_name || ')';
       ELSE
          l_msg_data := '     ' || l_column_tbl(i).column_name || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
    l_msg_data := '  VALUES (';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       IF i = l_column_count THEN
          l_msg_data := '     ' || l_block_name_ext || l_column_tbl(i).column_name || ');' || g_newline;
       ELSE
          l_msg_data := '     ' || l_block_name_ext || l_column_tbl(i).column_name || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
 
    l_msg_data := '  OPEN row_id;' || g_newline ||
                  '  FETCH row_id INTO ' || l_block_name_ext || 'row_id;' || g_newline ||
                  '  IF (row_id%NOTFOUND) THEN' || g_newline ||
                  '     CLOSE row_id;' || g_newline ||
                  '     RAISE NO_DATA_FOUND;' || g_newline ||
                  '  END IF;' || g_newline ||
                  '  CLOSE row_id;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'END insert_row;' || g_newline;
    output_msg(l_msg_data);
 
 
    -- lock row
    l_msg_data := '/*=====================================' || g_newline ||
                  '** PROCEDURE:    lock_row()' || g_newline ||
                  '**=====================================*/' || g_newline ||
                  'PROCEDURE lock_row IS' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  CURSOR c_row' || g_newline ||
                  '  IS SELECT *' || g_newline ||
                  '       FROM ' || p_table_name || g_newline ||
                  '      WHERE rowid = ' || l_block_name_ext || 'row_id' || g_newline ||
                  '      FOR UPDATE OF ' || p_primary_key || ' NOWAIT;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  rec     c_row%rowtype;' || g_newline ||
                  '  i NUMBER := 0;' || g_newline ||
                  'BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  LOOP' || g_newline ||
                  '    BEGIN';
    output_msg(l_msg_data);
 
    l_msg_data := '      i := i + 1;' || g_newline ||
                  '      OPEN c_row;' || g_newline ||
                  '      FETCH c_row INTO rec;';
    output_msg(l_msg_data);
 
    l_msg_data := '      IF (c_row%NOTFOUND) THEN' || g_newline ||
                  '        CLOSE c_row;' || g_newline ||
                  '        fnd_message.set_name(''FND'',''FORM_RECORD_DELETED'');' || g_newline ||
                  '        fnd_message.error;' || g_newline ||
                  '        RAISE FORM_TRIGGER_FAILURE;';
    output_msg(l_msg_data);
 
    l_msg_data := '      END IF;' || g_newline ||
                  '      CLOSE c_row;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '      IF (';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       IF i = 1 THEN
          l_msg_data := '              ';
       ELSE
          l_msg_data := '          AND ';
       END IF;
       IF l_column_tbl(i).column_name = p_primary_key THEN
          l_msg_data := l_msg_data || '(' || l_rec_ext || l_column_tbl(i).column_name ||
                        ' = ' || l_block_name_ext || l_column_tbl(i).column_name || ')';
       ELSE
          l_msg_data := l_msg_data || '((' || l_rec_ext || l_column_tbl(i).column_name ||
                        ' = ' || l_block_name_ext || l_column_tbl(i).column_name || ') OR' || g_newline ||
                        '               ((' || l_rec_ext || l_column_tbl(i).column_name || ' is null)' ||
                        ' AND (' || l_block_name_ext || l_column_tbl(i).column_name || ' is null)))';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
 
    l_msg_data := '      ) THEN' || g_newline ||
                  '        RETURN;' || g_newline ||
                  '      ELSE' || g_newline ||
                  '        fnd_message.set_name(''FND'', ''FORM_RECORD_CHANGED'');' || g_newline ||
                  '        fnd_message.error;' || g_newline ||
                  '        RAISE FORM_TRIGGER_FAILURE;' || g_newline ||
                  '      END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    EXCEPTION' || g_newline ||
                  '      WHEN app_exception.record_lock_exception THEN' || g_newline ||
                  '        app_exception.record_lock_error(i);' || g_newline ||
                  '    END;' || g_newline ||
                  '  END LOOP;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'END lock_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- update row
    l_msg_data := '/*=====================================' || g_newline ||
                  '** PROCEDURE:    update_row()' || g_newline ||
                  '**=====================================*/' || g_newline ||
                  'PROCEDURE update_row IS';
    output_msg(l_msg_data);
 
    l_msg_data := 'BEGIN' || g_newline;
    output_msg(l_msg_data);
    l_msg_data := '  fnd_standard.set_who;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  UPDATE ' || p_table_name || ' SET';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       l_msg_data := '      ' || rpad(l_column_tbl(i).column_name,30) || ' = ' ||
                     l_block_name_ext || l_column_tbl(i).column_name;
       IF i < l_column_count THEN
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
    l_msg_data := '  WHERE ROWID = ' || l_block_name_ext || 'row_id;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  IF (SQL%NOTFOUND) THEN' || g_newline ||
                  '     RAISE NO_DATA_FOUND;' || g_newline ||
                  '  END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'END update_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- delete row
    l_msg_data := '/*=====================================' || g_newline ||
                  '** PROCEDURE:    delete_row()' || g_newline ||
                  '**=====================================*/' || g_newline ||
                  'PROCEDURE delete_row IS';
    output_msg(l_msg_data);
 
    l_msg_data := 'BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  DELETE FROM ' || p_table_name || g_newline ||
                  '  WHERE ' || p_primary_key || ' = ' ||
                  l_block_name_ext || p_primary_key || ';' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  IF (SQL%NOTFOUND) THEN' || g_newline ||
                  '     RAISE NO_DATA_FOUND;' || g_newline ||
                  '  END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'END delete_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- end
    l_msg_data := 'END ' || l_package_name || ';';
    output_msg(l_msg_data);
 
  EXCEPTION
     WHEN fnd_api.g_exc_error THEN
         output_msg(l_msg_data);
     WHEN OTHERS THEN
         output_msg(SQLERRM);
  END form_view_iud;
 
  PROCEDURE table_handle_pkg( p_table_name  IN VARCHAR2,
                              p_owner       IN VARCHAR2,
                              p_primary_key IN VARCHAR2)
  IS
    CURSOR c_table
    IS SELECT 'Y'
         FROM all_tables t
        WHERE t.table_name = p_table_name
          AND t.owner      = p_owner;
 
    CURSOR c_columns
    IS SELECT tc.column_name, tc.nullable, tc.data_type
         FROM all_tab_columns tc
        WHERE tc.table_name = p_table_name
          AND tc.owner      = p_owner
        ORDER BY tc.column_id;
 
    l_dummy          VARCHAR2(1);
    l_msg_data       VARCHAR2(2000);
    l_package_name   VARCHAR2(100);
    l_object_version_column  BOOLEAN := FALSE;
    l_primary_key_exists BOOLEAN := FALSE;
    l_rec_ext            VARCHAR2(30);
 
    l_column_tbl     COLUMN_TBL_TYPE;
    l_column_count   NUMBER := 0;
  BEGIN
    -- check table exists
    OPEN c_table;
    FETCH c_table INTO l_dummy;
    IF c_table%NOTFOUND THEN
       CLOSE c_table;
       l_msg_data := 'Table ' || p_table_name || ' not found';
       RAISE fnd_api.g_exc_error;
    END IF;
    CLOSE c_table;
    -- get columns
    FOR r IN c_columns LOOP
       l_column_count := l_column_count + 1;
       l_column_tbl(l_column_count).column_name := r.column_name;
       l_column_tbl(l_column_count).nullable := r.nullable;
       l_column_tbl(l_column_count).data_type := r.data_type;
       IF r.column_name = 'OBJECT_VERSION_NUMBER' THEN
          l_object_version_column := TRUE;
       END IF;
    END LOOP;
 
    IF l_column_count < 1 THEN
       l_msg_data := 'Not column in table';
       RAISE fnd_api.g_exc_error;
    END IF;
 
    l_package_name := upper(p_table_name) || '_PKG';
    -- generate package special
    l_msg_data := 'CREATE OR REPLACE PACKAGE ' || l_package_name || ' AS' || g_newline || g_newline;
    output_msg(l_msg_data);
    -- insert row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  insert_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
    l_msg_data := '  PROCEDURE insert_row('  || g_newline ||
                  '               x_row_id IN OUT VARCHAR2,';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_tbl.COUNT LOOP
       IF l_column_tbl(i).column_name = p_primary_key THEN
          l_msg_data := '               x_' || lower(l_column_tbl(i).column_name) || ' IN OUT ' || l_column_tbl(i).data_type;
       ELSE
          l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
       END IF;
       IF l_column_tbl(i).nullable = 'Y' THEN
         l_msg_data := l_msg_data || ' DEFAULT NULL';
       END IF;
       IF i = l_column_tbl.COUNT THEN
          l_msg_data := l_msg_data || ');' || g_newline;
       ELSE
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
 
    -- lock row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  lock_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
    IF l_object_version_column THEN
       l_msg_data := '  PROCEDURE lock_row(';
       output_msg(l_msg_data);
       l_msg_data := '               p_' || lower(p_primary_key) || ' IN NUMBER,' || g_newline ||
                     '               p_object_version_number IN NUMBER);' || g_newline;
       output_msg(l_msg_data);
    ELSE
       l_msg_data := '  PROCEDURE lock_row(';
       output_msg(l_msg_data);
       FOR i IN 1..l_column_tbl.COUNT LOOP
--          IF l_column_tbl(i).column_name IN ('CREATION_DATE','CREATED_BY','LAST_UPDATE_DATE','LAST_UPDATED_BY','LAST_UPDATE_LOGIN') THEN
--            NULL;
--          ELSE
            l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
            IF i = l_column_tbl.COUNT THEN
               l_msg_data := l_msg_data || ');' || g_newline;
            ELSE
               l_msg_data := l_msg_data || ',';
            END IF;
            output_msg(l_msg_data);
--          END IF;
      END LOOP;
    END IF;
 
    -- update row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  update_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
    l_msg_data := '  PROCEDURE update_row(';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_tbl.COUNT LOOP
      IF l_column_tbl(i).column_name IN ('CREATION_DATE','CREATED_BY') THEN
        NULL;
      ELSE
       l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
       IF l_column_tbl(i).nullable = 'Y' THEN
         l_msg_data := l_msg_data || ' DEFAULT NULL';
       END IF;
       IF i = l_column_tbl.COUNT THEN
          l_msg_data := l_msg_data || ');' || g_newline;
       ELSE
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
      END IF;
    END LOOP;
 
    -- delete row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  delete_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
    l_msg_data := '  PROCEDURE delete_row(' || g_newline ||
                  '               p_' || lower(p_primary_key) || ' IN NUMBER);' || g_newline || g_newline ||
                  'END ' || l_package_name || ';' || g_newline ||
                  '/' || g_newline;
    output_msg(l_msg_data);
 
    -- generate package body
    -- begin
    l_msg_data := 'CREATE OR REPLACE PACKAGE BODY ' || l_package_name || ' AS' || g_newline;
    output_msg(l_msg_data);
 
    -- insert row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  insert_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
 
    l_msg_data := '  PROCEDURE insert_row('  || g_newline ||
                  '               x_row_id IN OUT VARCHAR2,';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_tbl.COUNT LOOP
       IF l_column_tbl(i).column_name = p_primary_key THEN
          l_primary_key_exists := TRUE;
          l_msg_data := '               x_' || lower(l_column_tbl(i).column_name) || ' IN OUT ' || l_column_tbl(i).data_type;
       ELSE
          l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
       END IF;
       IF l_column_tbl(i).nullable = 'Y' THEN
         l_msg_data := l_msg_data || ' DEFAULT NULL';
       END IF;
       IF i = l_column_tbl.COUNT THEN
          l_msg_data := l_msg_data || ')' || g_newline;
       ELSE
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
 
    IF l_primary_key_exists THEN
      l_msg_data := '  IS'  || g_newline ||
                    '     CURSOR c' || g_newline ||
                    '     IS SELECT rowid' || g_newline ||
                    '          FROM ' || p_table_name || g_newline ||
                    '         WHERE ' || p_primary_key || ' = x_' || lower(p_primary_key) || ';' || g_newline;
    ELSE
      l_msg_data := '  IS'  || g_newline ||
                    '     CURSOR c' || g_newline ||
                    '     IS SELECT rowid' || g_newline ||
                    '          FROM ' || p_table_name || g_newline ||
                    '         WHERE ' || p_primary_key || ' = p_' || lower(p_primary_key) || ';' || g_newline;
    END IF;
    output_msg(l_msg_data);
 
    l_msg_data := '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    IF l_primary_key_exists THEN
      l_msg_data := '    IF x_' || lower(p_primary_key) || ' IS NULL THEN' || g_newline ||
                    '      SELECT ' || p_table_name || '_S.NEXTVAL' || g_newline ||
                    '        INTO x_' || lower(p_primary_key) || g_newline ||
                    '        FROM DUAL;' || g_newline ||
                    '    END IF;' || g_newline;
      output_msg(l_msg_data);
    END IF;
 
    l_msg_data := '    INSERT INTO ' || lower(p_table_name) || ' (';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       IF i = l_column_count THEN
          l_msg_data := '       ' || lower(l_column_tbl(i).column_name) || ')';
       ELSE
          l_msg_data := '       ' || lower(l_column_tbl(i).column_name) || ',';
       END IF;
       output_msg(l_msg_data);
    END LOOP;
    l_msg_data := '    VALUES (';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
       IF i = l_column_count THEN
          IF l_column_tbl(i).column_name = p_primary_key THEN
            l_msg_data := '       x_' || lower(l_column_tbl(i).column_name) || ');' || g_newline;
          ELSE
            l_msg_data := '       p_' || lower(l_column_tbl(i).column_name) || ');' || g_newline;
          END IF;
       ELSE
          IF l_column_tbl(i).column_name = p_primary_key THEN
            l_msg_data := '       x_' || lower(l_column_tbl(i).column_name) || ',';
          ELSE
            l_msg_data := '       p_' || lower(l_column_tbl(i).column_name) || ',';
          END IF;
       END IF;
       output_msg(l_msg_data);
    END LOOP;
 
    l_msg_data := '    OPEN c;' || g_newline ||
                  '    FETCH c INTO x_row_id;' || g_newline ||
                  '    IF (c%NOTFOUND) THEN' || g_newline ||
                  '       CLOSE c;' || g_newline ||
                  '       RAISE NO_DATA_FOUND;' || g_newline ||
                  '    END IF;' || g_newline ||
                  '    CLOSE c;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  END insert_row;' || g_newline;
    output_msg(l_msg_data);
 
 
    -- lock row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  lock_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
 
    IF l_object_version_column THEN
       l_msg_data := '  PROCEDURE lock_row(';
       output_msg(l_msg_data);
       l_msg_data := '               p_' || lower(p_primary_key) || ' IN NUMBER,' || g_newline ||
                     '               p_object_version_number IN NUMBER)' || g_newline;
       output_msg(l_msg_data);
    ELSE
       l_msg_data := '  PROCEDURE lock_row(';
       output_msg(l_msg_data);
       FOR i IN 1..l_column_tbl.COUNT LOOP
--        IF l_column_tbl(i).column_name IN ('CREATION_DATE','CREATED_BY','LAST_UDPATE_DATE','LAST_UPDATED_BY','LAST_UPDATE_LOGIN') THEN
--          NULL;
--        ELSE
          l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
          IF i = l_column_tbl.COUNT THEN
             l_msg_data := l_msg_data || ')' || g_newline;
          ELSE
             l_msg_data := l_msg_data || ',';
          END IF;
          output_msg(l_msg_data);
--         END IF;
       END LOOP;
    END IF;
    l_msg_data := '  IS' || g_newline ||
                  '    CURSOR c' || g_newline ||
                  '    IS SELECT ';
    output_msg(l_msg_data);
 
    IF l_object_version_column THEN
       l_msg_data := '              object_version_number';
       output_msg(l_msg_data);
    ELSE
       FOR i IN 1..l_column_tbl.COUNT LOOP
          IF i = l_column_tbl.COUNT THEN
            l_msg_data := '              ' || lower(l_column_tbl(i).column_name);
          ELSE
            l_msg_data := '              ' || lower(l_column_tbl(i).column_name) || ',';
          END IF;
          output_msg(l_msg_data);
       END LOOP;
    END IF;
 
    l_msg_data := '         FROM ' || lower(p_table_name) || g_newline ||
                   '        WHERE ' || lower(p_primary_key) || ' = p_' || lower(p_primary_key) || g_newline ||
                   '        FOR UPDATE OF ' || lower(p_primary_key) || ' NOWAIT;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    rec     c%rowtype;' || g_newline ||
                  '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '      OPEN c;' || g_newline ||
                  '      FETCH c INTO rec;';
    output_msg(l_msg_data);
 
    l_msg_data := '      IF (c%NOTFOUND) THEN' || g_newline ||
                  '        CLOSE c;' || g_newline ||
                  '        fnd_message.set_name(''FND'',''FORM_RECORD_DELETED'');' || g_newline ||
                  '        app_exception.raise_exception;';
    output_msg(l_msg_data);
 
    l_msg_data := '      END IF;' || g_newline ||
                  '      CLOSE c;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '      IF (';
    output_msg(l_msg_data);
    l_rec_ext := 'rec.';
 
    IF l_object_version_column THEN
      l_msg_data := '              (rec.object_version_number = p_object_version_number)';
      output_msg(l_msg_data);
    ELSE
      FOR i IN 1..l_column_count LOOP
         IF i = 1 THEN
            l_msg_data := '              ';
         ELSE
            l_msg_data := '          AND ';
         END IF;
         IF l_column_tbl(i).column_name = p_primary_key THEN
            l_msg_data := l_msg_data || '(' || l_rec_ext || lower(l_column_tbl(i).column_name) ||
                          ' = p_' || lower(l_column_tbl(i).column_name) || ')';
         ELSE
            l_msg_data := l_msg_data || '((' || l_rec_ext || lower(l_column_tbl(i).column_name) ||
                          ' = p_' || lower(l_column_tbl(i).column_name) || ') OR' || g_newline ||
                          '               ((' || l_rec_ext || lower(l_column_tbl(i).column_name) || ' IS NULL)' ||
                          ' AND (p_' || lower(l_column_tbl(i).column_name) || ' IS NULL)))';
         END IF;
         output_msg(l_msg_data);
      END LOOP;
    END IF;
    l_msg_data := '      ) THEN' || g_newline ||
                  '        NULL;' || g_newline ||
                  '      ELSE' || g_newline ||
                  '        fnd_message.set_name(''FND'', ''FORM_RECORD_CHANGED'');' || g_newline ||
                  '        app_exception.raise_exception;' || g_newline ||
                  '      END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := 'END lock_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- update row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  update_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
 
    l_msg_data := '  PROCEDURE update_row(';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_tbl.COUNT LOOP
      IF l_column_tbl(i).column_name IN ('CREATION_DATE','CREATED_BY') THEN
        NULL;
      ELSE
       l_msg_data := '               p_' || lower(l_column_tbl(i).column_name) || ' IN ' || l_column_tbl(i).data_type;
       IF l_column_tbl(i).nullable = 'Y' THEN
         l_msg_data := l_msg_data || ' DEFAULT NULL';
       END IF;
       IF i = l_column_tbl.COUNT THEN
          l_msg_data := l_msg_data || ')' || g_newline;
       ELSE
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
      END IF;
    END LOOP;
 
    l_msg_data := '  IS' || g_newline ||
                  '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    UPDATE ' || p_table_name || ' SET';
    output_msg(l_msg_data);
    FOR i IN 1..l_column_count LOOP
      IF l_column_tbl(i).column_name IN ('CREATION_DATE','CREATED_BY') THEN
        NULL;
      ELSE
       l_msg_data := '        ' || rpad(lower(l_column_tbl(i).column_name),30) || ' = p_' ||
                     lower(l_column_tbl(i).column_name);
       IF i < l_column_count THEN
          l_msg_data := l_msg_data || ',';
       END IF;
       output_msg(l_msg_data);
      END IF;
    END LOOP;
    l_msg_data := '    WHERE ' || lower(p_primary_key) || ' = p_' || lower(p_primary_key) || ';' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    IF (SQL%NOTFOUND) THEN' || g_newline ||
                  '       RAISE NO_DATA_FOUND;' || g_newline ||
                  '    END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  END update_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- delete row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  delete_row()' || g_newline ||
                  '  **=====================================*/';
    output_msg(l_msg_data);
 
    l_msg_data := '  PROCEDURE delete_row(' || g_newline ||
                  '               p_' || lower(p_primary_key) || ' IN NUMBER)' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  IS' || g_newline ||
                  '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    DELETE FROM ' || lower(p_table_name) || g_newline ||
                  '    WHERE ' || lower(p_primary_key) || ' = p_' ||
                  lower(p_primary_key) || ';' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    IF (SQL%NOTFOUND) THEN' || g_newline ||
                  '       RAISE NO_DATA_FOUND;' || g_newline ||
                  '    END IF;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  END delete_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- end
    l_msg_data := 'END ' || l_package_name || ';' || g_newline ||
                  '/' || g_newline;
    output_msg(l_msg_data);
 
  EXCEPTION
     WHEN fnd_api.g_exc_error THEN
         output_msg(l_msg_data);
     WHEN OTHERS THEN
         output_msg(SQLERRM);
  END table_handle_pkg;
 
  PROCEDURE form_table_handle( p_block_name   IN VARCHAR2,
                               p_package_name IN VARCHAR2,
                               p_table_name   IN VARCHAR2,
                               p_primary_key  IN VARCHAR2)
  IS
    CURSOR c_columns(p_procedure IN VARCHAR2)
    IS SELECT A.ARGUMENT                            column_name,
           DECODE(A.TYPE#, 252, 'BOOLEAN',
                           12, 'DATE',
                           2, 'NUMBER',
                           1, 'VARCHAR2',
                              'VARCHAR2')           date_type,
           DECODE(A.IN_OUT,1,'OUT',2,'IN OUT','IN') inout
    FROM   SYS.ARGUMENT$ A,
           USER_OBJECTS B
    WHERE  A.OBJ# = B.OBJECT_ID
    AND    B.OBJECT_NAME = p_package_name
    AND    A.PROCEDURE$ = p_procedure
    AND    A.OVERLOAD# = 0
    ORDER BY a.sequence#;
 
    CURSOR c_object_version_number(p_procedure IN VARCHAR2)
    IS SELECT 'Y'
        FROM   SYS.ARGUMENT$ A,
               USER_OBJECTS B
        WHERE  A.OBJ# = B.OBJECT_ID
        AND    B.OBJECT_NAME = p_package_name
        AND    A.PROCEDURE$ = p_procedure
        AND    A.OVERLOAD# = 0
        AND    A.ARGUMENT  = 'P_OBJECT_VERSION_NUMBER';
 
    l_msg_data       VARCHAR2(2000);
    l_package_name   VARCHAR2(100);
    l_block_name_ext VARCHAR2(50) := ':' || lower(p_block_name) || '.';
 
    i                NUMBER;
  BEGIN
 
    l_package_name := upper(p_block_name) || '_PRIVATE';
    -- generate package special
    l_msg_data := 'PACKAGE ' || l_package_name || ' IS' || g_newline || g_newline ||
                  '  PROCEDURE insert_row;' || g_newline ||
                  '  PROCEDURE lock_row;' || g_newline ||
                  '  PROCEDURE update_row;' || g_newline ||
                  '  PROCEDURE delete_row;' || g_newline || g_newline ||
                  'END ' || l_package_name || ';' || g_newline;
 
    output_msg(l_msg_data);
 
    -- generate package body
    -- begin
    l_msg_data := 'PACKAGE BODY ' || l_package_name || ' IS' || g_newline;
    output_msg(l_msg_data);
 
    -- insert row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  insert_row()' || g_newline ||
                  '  **=====================================*/' || g_newline ||
                  '  PROCEDURE insert_row IS' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    fnd_standard.set_who;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    IF ' || l_block_name_ext || lower(p_primary_key) || ' IS NULL THEN' || g_newline ||
                  '      SELECT ' || upper(p_table_name) || '_S.NEXTVAL' || g_newline ||
                  '        INTO ' || l_block_name_ext || lower(p_primary_key) || g_newline ||
                  '        FROM DUAL;' || g_newline ||
                  '    END IF;' || g_newline;
    output_msg(l_msg_data);
 
    FOR r IN c_object_version_number('INSERT_ROW') LOOP
      l_msg_data := '    ' || l_block_name_ext || 'object_version_number := 1;';
      output_msg(l_msg_data);
      EXIT;
    END LOOP;
 
    l_msg_data := '    ' || lower(p_package_name) || '.insert_row (';
    output_msg(l_msg_data);
 
    i := 1;
    FOR r IN c_columns('INSERT_ROW') LOOP
       IF i = 1 THEN
          l_msg_data := '        ' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       ELSE
          l_msg_data := '       ,' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       END IF;
       output_msg(l_msg_data);
       i := i + 1;
    END LOOP;
    l_msg_data := '       );' || g_newline ||
                  '  END insert_row;' || g_newline;
    output_msg(l_msg_data);
 
 
    -- lock row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  lock_row()' || g_newline ||
                  '  **=====================================*/' || g_newline ||
                  '  PROCEDURE lock_row IS' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    i NUMBER := 0;' || g_newline ||
                  '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    LOOP' || g_newline ||
                  '      BEGIN';
    output_msg(l_msg_data);
 
    l_msg_data := '        i := i + 1;';
    output_msg(l_msg_data);
 
    l_msg_data := '        ' || lower(p_package_name) || '.lock_row(';
    output_msg(l_msg_data);
    i := 1;
    FOR r IN c_columns('LOCK_ROW') LOOP
       IF i = 1 THEN
          l_msg_data := '        ' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       ELSE
          l_msg_data := '       ,' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       END IF;
       output_msg(l_msg_data);
       i := i + 1;
    END LOOP;
    l_msg_data := '       );';
    output_msg(l_msg_data);
 
    l_msg_data := '        RETURN;' || g_newline ||
                  '      EXCEPTION' || g_newline ||
                  '        WHEN app_exception.record_lock_exception THEN' || g_newline ||
                  '          app_exception.record_lock_error(i);' || g_newline ||
                  '      END;' || g_newline ||
                  '    END LOOP;' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '  END lock_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- update row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  update_row()' || g_newline ||
                  '  **=====================================*/' || g_newline ||
                  '  PROCEDURE update_row IS';
    output_msg(l_msg_data);
 
    l_msg_data := '  BEGIN' || g_newline;
    output_msg(l_msg_data);
    l_msg_data := '    fnd_standard.set_who;' || g_newline;
    output_msg(l_msg_data);
 
    FOR r IN c_object_version_number('UPDATE_ROW') LOOP
      l_msg_data := '    ' || l_block_name_ext || 'object_version_number := '|| l_block_name_ext || 'object_version_number' ||' + 1;';
      output_msg(l_msg_data);
      EXIT;
    END LOOP;
 
    l_msg_data := '    ' || lower(p_package_name) || '.update_row(';
    output_msg(l_msg_data);
    i := 1;
    FOR r IN c_columns('UPDATE_ROW') LOOP
       IF i = 1 THEN
          l_msg_data := '        ' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       ELSE
          l_msg_data := '       ,' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       END IF;
       output_msg(l_msg_data);
       i := i + 1;
    END LOOP;
    l_msg_data := '       );';
    output_msg(l_msg_data);
 
    l_msg_data := '  END update_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- delete row
    l_msg_data := '  /*=====================================' || g_newline ||
                  '  ** PROCEDURE:  delete_row()' || g_newline ||
                  '  **=====================================*/' || g_newline ||
                  '  PROCEDURE delete_row IS';
    output_msg(l_msg_data);
 
    l_msg_data := '  BEGIN' || g_newline;
    output_msg(l_msg_data);
 
    l_msg_data := '    ' || lower(p_package_name) || '.delete_row(';
    output_msg(l_msg_data);
    i := 1;
    FOR r IN c_columns('DELETE_ROW') LOOP
       IF i = 1 THEN
          l_msg_data := '       ' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       ELSE
          l_msg_data := '       ' || lower(r.column_name) || ' => ' || l_block_name_ext || substr(lower(r.column_name),3);
       END IF;
       output_msg(l_msg_data);
       i := i + 1;
    END LOOP;
    l_msg_data := '       );';
    output_msg(l_msg_data);
 
    l_msg_data := '  END delete_row;' || g_newline;
    output_msg(l_msg_data);
 
    -- end
    l_msg_data := 'END ' || l_package_name || ';';
    output_msg(l_msg_data);
 
  EXCEPTION
     WHEN fnd_api.g_exc_error THEN
         output_msg(l_msg_data);
     WHEN OTHERS THEN
         output_msg(SQLERRM);
  END form_table_handle;
 
END HAND_PLSQL_AUTOCREATE;
/
 
/*
EBS Form : 利用代码自动生成器,设置Form为基于view
 
1.打开包Hand_plsql_autocreate
2.text:form_view_iud
3.输入4个参数:分别为:数据块的名称
                       数据库对应数据库视图对应的基表
                       数据库表的所有者
                       数据库表的主键
4.执行,查看运行结果:
  到form中建包:包名:数据块名称+_PRIVATE
5.添加块触发器:
  on-insert : 数据块名称+_PRIVATE.insert_row
  on-update : 数据块名称+_PRIVATE.update_row
  on-lock   : 数据块名称+_PRIVATE.lock_row
  on-delete : 数据块名称+_PRIVATE.delete_row --若数据块不允许删除数据,则可以省略此触发器
来源: https://www.cnblogs.com/CiWEi-/archive/2011/12/25/2300855.html  
*/

 注意必须:

1)创建序号程序对象: 命名格式:  表名+ “_S";

2)表字段必须有主键ID, 

3)建议有WHO(5个字段)。

posted @   samrv  阅读(47)  评论(0编辑  收藏  举报
相关博文:
阅读排行:
· 全程不用写代码,我用AI程序员写了一个飞机大战
· MongoDB 8.0这个新功能碉堡了,比商业数据库还牛
· 记一次.NET内存居高不下排查解决与启示
· DeepSeek 开源周回顾「GitHub 热点速览」
· 白话解读 Dapr 1.15:你的「微服务管家」又秀新绝活了
点击右上角即可分享
微信分享提示