【多关键字排序】完美的对称

【问题描述】
    在HZOI峰会期间，必须使用许多保镖保卫各校代表。代表们除了由他自己的随身保镖保
护外，组委会还指派了一些其他的特工和阻击手保护他们。为了使他们的工作卓有成效，使被
保卫的人的安全尽可能得到保障，保镖被分配到被保护人的各个方向。
    保镖的最佳站立位置应该是这样的：被保护人应站在所有保镖的对称中心。但是，只要
被保护人一移动，保镖就很难根据要人的新位置调整位置。大多数的特工都很难对此作出实时
调整。
    因此，内政部长saltless决定将该过程逆转一下，保镖先站好自己的位置，然后要人
在他们的对称中心找到合适的位置。如果要人随便走动，我们就对他的安全不必负责。
    你的工作是使这个过程自动操作。给出一组N个点（保镖的位置），你要找出它们的对称
中心S，在这儿被保护人将相对安全。下面以此类推。
    首先我们给定一点A以及对称中心S，点A'是点A以S为对称中心形成的像点，即点S是线
段AA'的对称中心。
    点阵组（X）以S为中心的像点是由每个点的像点组成的点阵组。X是用来产生对称中心S
的，即点阵X以S为中心的像点的集合即为点阵X本身。
 
【输入格式】
    输入文件第一行是一个整数N，1<=N<=20000，接下来的N行每行包含用空格隔开的两个
整数Xi和Yi，-100000<=Xi,Yi<=100000，表示这组点阵中第I个点的笛卡尔坐标值。
    因为任何两个保镖都不会站在同一个位置上，所以在给定的作业中，任何两点都不相同。
但注意保镖可以站在被保护人相同的位置。
【输出格式】
    输出文件仅有一行。如果给定的点阵能产生一个对称中心，则输出“V.I.P should 
stay at (x,y)”，其中X和Y代表中心的笛卡尔坐标值，格式为四舍五入保留至小数点后一
位。如果该组点阵无对称中心，输出"This is a dangerous situation!"，注意输出
时除了两个单词之间用一个空格隔开外，不要输出多余空格。
【输入样例】
8
1 10
3 6
6 8
6 2
3 -4
1 0
-2 -2
-2 4
【输出样例】
V.I.P. should stay at (2.0,3.0).

      又是一道看起来像计算几何的题，其实简单的不得了。我们要充分运用对称点坐标的性质：如果按照横坐标从大到小排序，则第i个点和第n-i+1个点一定相互对称，按照纵坐标排序也一样。所以我们只要以横坐标和纵坐标两个关键字进行一遍排序，再以此检查每一对的对称点对的对称中心是否一样即可。因为坐标都是整数，我们甚至不用浮点运算，直接保留2倍关系进行比较即可。

. 

      参考代码：

program symmetry;
  var
    i,j:longint;
    x,y:array[0..20005]of longint;
    n,m:longint;
    xs,ys:longint;
  procedure qsort(l,r:longint);  //多关键字的快排
    var
      i,j:longint;
      x1,x2,yy:longint;
      m:longint;
    begin
      i:=l;
      j:=r;
      x1:=x[(i+j)>>1];
      x2:=y[(i+j)>>1];
      repeat
        while((x[i]>x1)or((x[i]=x1)and(y[i]>x2)))do inc(i);
        while((x[j]<x1)or((x[j]=x1)and(y[j]<x2)))do dec(j);
        if i<=j then
          begin
            yy:=x[i];
            x[i]:=x[j];
            x[j]:=yy;
            yy:=y[i];
            y[i]:=y[j];
            y[j]:=yy;
            inc(i);
            dec(j);
          end;
      until i>j;
      if (i<r) then qsort(i,r);
      if (j>l) then qsort(l,j);
    end;
  begin
    readln(n);
    for i:=1 to n do
      readln(x[i],y[i]);
    qsort(1,n);
    xs:=x[1]+x[n];
    ys:=y[1]+y[n];
    for i:=2 to n>>1 do
      if(x[i]+x[n-i+1]<>xs)or(y[i]+y[n-i+1]<>ys) then  //检查对称中心是否重合
        begin
          writeln('This is a dangerous situation!');
          close(input);
          close(output);
          halt;
        end;
    writeln('V.I.P. should stay at (',xs/2:0:1,',',ys/2:0:1,').');
  end.

.

本文地址：http://www.cnblogs.com/saltless/archive/2011/06/01/2067190.html

（saltless原创，转载请注明出处）