Shader入门精要笔记 - CH6_最简单的逐像素Blinn-Phong光照

效果

 

要点

1) 我们看到的物体颜色是没被物体吸收，反射出来的颜色。这个就是漫反射。

2) 漫反射相关定理和公式：

a) 兰伯特定律：漫反射反射光线的强度与表面法线和光线方向夹角的cos值成正比。

b) Color_light * Color_diffuse * 漫反射光线辐照度。光线辐照度就是光线强度的量化表示，光线辐照度= max(0, N • L)，N为表面法线向量，L为光线方向向量

 

3) 高光反射相关公式：

a) phong方式的计算公式：Color_light * Color_specular * 高光反射光线辐照度。高光反射光线辐照度= (max(0, V • R))^gloss，V为视角方向，R为反射方向

b) blinn-phong方式的计算公式：Color_light * Color_specular * 高光反射光线辐照度。高光反射光线辐照度= (max(0, N • h))^gloss，N为表面法线向量，h=normal(L + V)

 

4) 光照计算放在了vert着色器中，所以是逐像素计算的。也可以用逐顶点的方式，具体可参考《Shader入门精要》CH6

Shader "My/Light/SpecularPerPixel"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1, 1, 1, 1) //漫反射颜色
        _Specular("Specular", Color) = (1, 1, 1, 1) //高光反射颜色
        _Gloss("Gloss", Range(8.0, 256)) = 20 //高光区域大小
    }
    SubShader
    {
        Tags { "LightMode" = "ForwardBase" } //设置了LightMode=ForwardBase时, 内置变量_WorldSpaceLightPos0才被赋值

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL; //顶点法线
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos: TEXCOORD1;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex); //模型空间转换为裁剪空间
                o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject); //模型空间转换为世界空间(平移对向量没影响, 所以3x3矩阵就行)
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                //fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos)); //指向光源向量(世界空间)

                fixed lambert = max(0, dot(worldNormal, worldLightDir));
                fixed3 diffuseColor = _LightColor0.rgb * _Diffuse.rgb * lambert; //漫反射计算公式

                //fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos)); //视线方向(顶点到相机)

                //fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
                //fixed3 specularColor = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss); //phong模型高光反射计算公式

                fixed3 halfDir = normalize(worldLightDir + viewDir); // blinn-phong模型引入的半角向量
                fixed3 specularColor = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss); // blinn-phong模型高光反射计算公式(更亮, 高光区域更大)

                fixed3 ambientColor = UNITY_LIGHTMODEL_AMBIENT.xyz; //环境光
                return fixed4(ambientColor + diffuseColor + specularColor, 1);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

 

参考

shader入门精要