as3 使用sound类(翻译)-暂停和继续播放声音
如何暂停声音,如何从暂停的地方继续播放声音。
解决方法
通过记录当前声音的SoundChannel的position属性值,继续播放时用刚刚的值恢复一下。
具体讨论
在问题二中提到了sound对象的close()方法,它可以用来停止一个声音文件的播放,但是,同时它也停止了声音文件的加载,当重新播放的时候,我们必须重新调用load()方法。
幸运的是,SoundChannel类提供了一个stop()方法,它可以使声音文件停止播放而不停止加载,当再次播放音乐的时候,只要调用play()方法就可以了。
我们应该记住:不管什么时候只要是使用play()方法都是从文件开头进行播放的,这相当于播放器中的“STOP■”按钮。创建一个“PAUSE‖”按钮稍微有点麻烦。解决的策略是:当按下按钮的时候调用一个事件处理函数:这个函数从SoundChannel中读取当前的position数据并把它保存起来,它提供了声音文件已经播放了多少毫秒。把这个量保存为类级别的,以便后面调用。此时,“PAUSE‖”按钮变成“PLAY”按钮,当再次被按下的时候,调用sound对象的play()方法,通过刚才保存的位置信息,就能恢复到刚才停下来的那地方继续播放,下面给出例程:
package {
import flash.display.Sprite;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.net.URLRequest;
import flash.events.Event;
import flash.display.Sprite;
import flash.events.MouseEvent;
public class PlayPause extends Sprite {
private var _sound:Sound;
private var _channel:SoundChannel;
private var _playPauseButton:Sprite;
private var _playing:Boolean = false;
private var _position:int;
public function PlayPause( ) {
// 创建一个声音对象,并播放之
_sound = new Sound(new URLRequest("song.mp3"));
_channel = _sound.play( );
_playing = true;
//一个作为Play/Pause按钮的sprite
_playPauseButton = new Sprite( );
addChild(_playPauseButton);
_playPauseButton.x = 10;
_playPauseButton.y = 20;
_playPauseButton.graphics.beginFill(0xcccccc);
_playPauseButton.graphics.drawRect(0, 0, 20, 20);
_playPauseButton.addEventListener(MouseEvent.MOUSE_UP, onPlayPause); }
public function onPlayPause(event:MouseEvent):void {
// 如果正在播放,停止,记下当前位置信息
if(_playing) {
_position = _channel.position;
_channel.stop( );
}
else {
// 如果未播放,从记录处开始播放
//
_channel = _sound.play(_position);
}
_playing = !_playing;
}
}
}
以上代码创建了一个sprite图像作为按钮,为其鼠标抬起事件添加了事件处理函数,如果当前声音正在播放,则停止当前播放,并记录当前位置,如果当前已经停止,则从刚才记录的位置开始播放。