BZOJ1016 [JSOI2008]最小生成树计数

江苏就是江苏啊，题目质量高。

看到题的时候只YY出了第一个性质：MST中边权相同的的边的个数是一定的。（证略，可以用反证法）

后来上网找题解，发现还有第二个性质：MST如果用Kruskal来做，做完长度为x的所有边以后，此时图的连通性是确定的。（这也是很明显的）

于是嘛。。。先算出每个长度的边的cnt，然后每次暴力枚举哪些边在MST中。

判断方式就是看新加的边有没有使得原来不联通的块联通，然后就做完了。

但是要注意的是，暴力枚举的时候并查集不能路径压缩，因为还要还原。

 

/**************************************************************
    Problem: 1016
    User: rausen
    Language: Pascal
    Result: Accepted
    Time:8 ms
    Memory:344 kb
****************************************************************/
 
{$inline on}
 
const prime = 31011;
 
var
  n, m, k, t : longint;
  i, x, y, z : longint;
  count, ans : longint;
  a, b, c, p, cnt, fa : array[0..5000] of longint;
  flag : boolean;
 
procedure add_edge(x, y, z : longint); inline;
begin
  inc(t);
  a[t] := x;
  b[t] := y;
  c[t] := z;
end;
 
procedure swap(x, y : longint); inline;
var
  t : longint;
 
begin
  t := a[x]; a[x] := a[y]; a[y] := t;
  t := b[x]; b[x] := b[y]; b[y] := t;
  t := c[x]; c[x] := c[y]; c[y] := t;
end;
 
procedure qsort(l, r : longint);
var
  i, j, x : longint;
 
begin
  i := l;
  j := r;
  x := c[(i + j) shr 1];
  repeat
    while c[i] < x do inc(i);
    while c[j] > x do dec(j);
    if i <= j then begin
      swap(i, j);
      inc(i);
      dec(j);
    end;
  until i > j;
  if i < r then qsort(i, r);
  if l < j then qsort(l, j);
end;
 
function find_fa(x : longint) : longint;
var
  f : longint;
 
begin
  f := fa[x];
  if f = x then exit(f);
  f := find_fa(f);
  fa[x] := f;
  exit(f);
end;
 
procedure make_mst;
var
  i, j, f1, f2 : longint;
 
begin
  for i := 1 to n do
    fa[i] := i;
  j := 0;
  fillchar(cnt, sizeof(cnt), 0);
  for i := 1 to t do begin
    if c[i] <> c[i - 1] then inc(j);
    f1 := find_fa(a[i]);
    f2 := find_fa(b[i]);
    if f1 <> f2 then begin
      inc(cnt[j]);
      fa[f1] := f2;
    end;
  end;
end;
 
function find_f(x : longint) : longint; inline;
begin
  while fa[x] <> x do
    x := fa[x];
  exit(x);
end;
 
procedure sub(l, r, num : longint);
var
  f1, f2 : longint;
 
begin
  if num = 0 then begin
    inc(count);
    if count > prime then
      count := count - prime;
    exit;
  end;
  if l > r then exit;
  if r - l + 1 > num then sub(l + 1, r, num);
  f1 := find_f(a[l]);
  f2 := find_f(b[l]);
  if f1 <> f2 then begin
    fa[f1] := f2;
    sub(l + 1, r, num - 1);
    fa[f1] := f1;
  end;
end;
 
procedure make_ans;
var
  i, j, f1, f2 : longint;
 
begin
  for i := 1 to n do
    fa[i] := i;
  ans := 1;
  for i := 1 to k do begin
    count := 0;
    sub(p[i], p[i + 1] - 1, cnt[i]);
    ans := (ans * count) mod prime;
    for j := p[i] to p[i + 1] - 1 do begin
      f1 := find_fa(a[j]);
      f2 := find_fa(b[j]);
      if f1 <> f2 then fa[f1] := f2;
    end;
  end;
end;
 
begin
  readln(n, m);
  for i := 1 to m do begin
    read(x, y, z);
    add_edge(x, y, z);
  end;
  qsort(1, t);
  p[1] := 1;
  k := 1;
  for i := 2 to t do
    if c[i] <> c[i - 1] then begin
      inc(k);
      p[k] := i;
    end;
  p[k + 1] := t + 1;
  make_mst;
  make_ans;
  flag := true;
  for i := 1 to n do
    if fa[i] = i then
      if flag then flag := false
      else begin
        writeln(0);
        exit;
      end;
  writeln(ans);
end.