玫瑰花-初级程序-极语言教程

//窗体代码:

整数 窗体;
程序资源 24,"清单.xml";
程序段 加载窗体
整数 左=(桌面.宽-500)>>1,上=(桌面.高-600)>>1;
窗体=创建窗口($100,程序.名称,"玫瑰花",$10C80000,左,上,500,600,0,0,0,0);
窗体启动;读取消息
结束

 

//程序代码:

小程序 窗体消息(整数 窗口,整数 消息,整数 参数,整数 数据)
    判断(消息)
    为 窗口关闭{停止(0)}
    为 窗口重绘 重绘图像
    否则{处理窗口(窗口,消息,参数,数据)}
结束

浮点 水平,垂直,厚度,红色,绿色;正数 数组()
整数 设备,图层,图像,次数,最大随机=32767,比例=250,大小=500

小程序 窗体启动
    重置 数组(300000)
    设备=取设备(窗体)
    图层=创建设备(设备)
    图像=创建图像(设备,500,600)
    选择对象(图层,图像)
    重绘图像
    读取消息
结束

小程序 重绘图像
    整数 数=0,值=0,左,右,上,下,颜色
    如果(次数<2000)
    {
    循环
    {
        如果(计算点)
        {
            下=厚度;
            左=水平 * 大小 / 下 + 比例;
            上=垂直 * 大小 / 下 + 比例;
            右=上*大小+左;
            如果(数组(右)=0 || ?>下)
            {
                数组(右)=下;
                颜色=红色*比例;
                颜色=颜色 & 255; 
                下=绿色*比例;
                颜色+ 下 <<8;
                下=红色*红色*80;
                颜色+ 下 <<16;
                设置颜色(图层,左,上,颜色)
            }
        }
    值++}(值>=10000)
    次数++}
    位图传输(设备,0,0,500,600, 图层,0,0,原图复制);
结束

小程序 计算点
    整数 数=随机数,值=随机数,一=1,二=2;浮点 上,下,左,右,前,中,后;
    上=数/最大随机;下=值/最大随机;数=值 % 68;
    如果(数>60)
    {// 花柄
    值=4;右=值;左=下*值;左=幂(左,右);值=5;右= 值/(左+0.2)+13;值=7;数=50;
    水平=(上*值)正弦 * 右 - (下)正弦 * 数;垂直=下*大小+数;
    厚度=(上*值)余弦 * 右 + 625 + 下 * 400;
    红色=上-下/二;绿色=上;返回(1);
    }
    前=上*二 - 一;后=下*二 - 一;
    如果(前*前 + 后*后 <1.0)
    {
        如果(数>39)
        {// 叶
            数=数 & 1;值=如果是(数)6,4;右=值
            厚度=下*比例;左=0.5/(上+0.01) + (下*125)余弦*3 -上*300;
            水平=(右)余弦*左 - (右)正弦*厚度 + 数 * 610 - 390;
            垂直=(右)正弦*左 + (右)余弦*厚度 - 数 * 350 + 550;
            绿色=左/1000 + 0.7 + 左*厚度* 0.000003;值=比例*6;
            右=值;如果(后>0)厚度=-厚度;中=一 - 后*后;值=25;
            前=幂(中,右);左=(左*(上 + 一)-厚度/值)余弦;
            右=30;左=幂(左,右);
    红色=0.4 -上*0.1 +前*0.15 -上*下*0.4 +(上+下)余弦/5 + 左*中*0.1
            厚度=1180 +(前+后)余弦 *99 - 数*300;返回(1);
        }值=7;
        如果(数>30)
        {// 花萼
            左= 数 * 1.16 - 0.15;
            右= 上 * 45 - 20;
            中=下*下*比例;
            厚度=(左)正弦*右 - 中*(左)余弦+620;
            水平=(左)余弦*右 + 中*(左)正弦;
            垂直= (后 * 0.5)余弦 * 99 - 下 * 下 * 下 * 60 - 厚度 / 二 + 比例+ 28 ;
            左=一 - (前*前);右=值;左=幂(左,右);
            红色=(下*下*0.3+左 * 0.15 + 0.3)*下;
            绿色=下*0.7;返回(1);
        }
    // 花
        中=一 - 下;右=值;左=幂(中,右);
        右=99 - (前)余* 120 - (下)余* (比例 - 数 * 4.9) + (左)余弦* 50 + 数 * 二;
        左= 前 * (二 - 下) * (80 - 数 * 二);
        厚度=左 * (数)正弦+ 右 * (数)余弦+ 700;
        水平=左 * (数)余弦- 右 * (数)正弦;
        右=值;左=幂(下,右);
        垂直=后 * 99 - (左)余弦* 50 - 数 / 3 - 厚度 / 1.35 + 450;
        红色=(一 - 下 / 1.2) * 0.9 + 上 * 0.1;
        右=20;左=幂(中,右);
        绿色=左 / 4 + 0.05;返回(1)
    }返回(0)
结束