【codevs1028】花店橱窗布置（费用流）

　　这几天刚学了费用流，找到了这道题来练一练手。

　　题目：

题目描述 Description

假设以最美观的方式布置花店的橱窗，有F束花，V个花瓶，我们用美学值（一个整数）表示每束花放入每个花瓶所产生的美学效果。为了取得最佳的美学效果，必须使花的摆放取得最大的美学值。

输入描述 Input Description

第一行为两个整数F,V(F<=V<=100)

接下来F行每行V个整数，第i行第j个数表示第i束花放入第j个花瓶的美学值。

输出描述 Output Description

一个整数，即最大美学值。

样例输入 Sample Input

2 2

10 0

5 2

样例输出 Sample Output

12

---

　　这道题很明显是二分图的最大权匹配，可以用最大费用最大流来做。做法：首先先建图，在源点到每束花之间连一条流量为1，花费0为的点（每束花只能用一次），在每个花屏到汇点之间连一条流量为1，花费为0的边（每个花瓶只能用一次），然后再在每束花和每个花瓶之间连一条流量为1，权值为这种匹配的美学值的边；然后就用spfa找增广路，建反向边时，反向边的流量是这条增广路的流量，花费是原边的花费的相反数。

　　一开始写的时候受了最大流的影响，也像最大流那样建了分层图，于是WA了两次也找不出错。后来把分层图删掉才能AC。其实分层图的作用就是避免出现环造成死循环，而用spfa来找增广路，就已经避免了这个问题，反而会把原图中的一些边删掉，所以费用流中千万不要用分层图。

　　代码：

var a,c:array[0..210,0..210]of longint;//a是原图，c是花费的图
  fa,d:array[0..210]of longint;//fa[i]是在到i的最短路径上i的前一个点（前驱结点），d[i]是到i的最短路径的距离
  b:array[0..210]of boolean;//记录是否在队列中
  q:array[0..40010]of longint;//队列
  n,m,i,j,k,p,t,h,sum:longint;
procedure spfa(s:longint);//spfa模板
var i,h,t:longint;
begin
  for i:=0 to n do begin
    d[i]:=-1<<25; b[i]:=true;//初始化
  end;
  h:=1; t:=1; q[1]:=s; d[s]:=0; b[s]:=false; fa[s]:=-1;//初始化2
  repeat
    for i:=0 to n do
      if(a[q[h],i]>0)and(d[q[h]]+c[q[h],i]>d[i])then begin//判断是否有边，是否更优
        d[i]:=d[q[h]]+c[q[h],i]; fa[i]:=q[h];//更新距离
        if b[i] then begin
          inc(t); q[t]:=i; b[i]:=false;//入队
        end;
      end;
    b[q[h]]:=true; inc(h);//出队
  until h>t;
end;
function flow(s,t:longint):longint;
var p,min:longint;
begin
  spfa(s);
  if d[t]=-1<<25 then exit(0);//判断是否有增广路
  p:=t; min:=1<<25;
  while fa[p]>=0 do begin
    if min>a[fa[p],p] then min:=a[fa[p],p];//从汇点访问到源点，计算流量
    p:=fa[p];
  end;
  p:=t;                               
  while fa[p]>=0 do begin
    c[p,fa[p]]:=-c[fa[p],p];//建反向边1
    a[fa[p],p]:=a[fa[p],p]-min; a[p,fa[p]]:=a[p,fa[p]]+min;//建反向边2
    p:=fa[p];
  end;
  sum:=sum+d[t];//加上这次增广的花费，更新答案
  exit(min);
end;
begin
  read(n,m);
  for i:=1 to n do begin
    a[0,i]:=1; c[0,i]:=0;//建图1
  end;
  for i:=1 to m do begin
    a[i+n,n+m+1]:=1; c[i+n,n+m+1]:=0;//建图2
  end;
  for i:=1 to n do
    for j:=1 to m do begin
      read(k); a[i,n+j]:=1; c[i,n+j]:=k;//建图3
    end;
  n:=n+m+1; sum:=0; k:=1;
  while k>0 do k:=flow(0,n);//一行费用流
  writeln(sum);//输出最大美学值
end.