BZOJ 3876：支线剧情（有下界最小费用最大流）

3876: [Ahoi2014]支线剧情

Description

【故事背景】
宅男JYY非常喜欢玩RPG游戏，比如仙剑，轩辕剑等等。不过JYY喜欢的并不是战斗场景，而是类似电视剧一般的充满恩怨情仇的剧情。这些游戏往往
都有很多的支线剧情，现在JYY想花费最少的时间看完所有的支线剧情。
【问题描述】
JYY现在所玩的RPG游戏中，一共有N个剧情点，由1到N编号，第i个剧情点可以根据JYY的不同的选择，而经过不同的支线剧情，前往Ki种不同的新的剧情点。当然如果为0，则说明i号剧情点是游戏的一个结局了。
JYY观看一个支线剧情需要一定的时间。JYY一开始处在1号剧情点，也就是游戏的开始。显然任何一个剧情点都是从1号剧情点可达的。此外，随着游戏的进行，剧情是不可逆的。所以游戏保证从任意剧情点出发，都不能再回到这个剧情点。由于JYY过度使用修改器，导致游戏的“存档”和“读档”功能损坏了，
所以JYY要想回到之前的剧情点，唯一的方法就是退出当前游戏，并开始新的游戏，也就是回到1号剧情点。JYY可以在任何时刻退出游戏并重新开始。不断开始新的游戏重复观看已经看过的剧情是很痛苦，JYY希望花费最少的时间，看完所有不同的支线剧情。
Input

输入一行包含一个正整数N。
接下来N行，第i行为i号剧情点的信息；
第一个整数为，接下来个整数对，Bij和Tij，表示从剧情点i可以前往剧
情点，并且观看这段支线剧情需要花费的时间。
Output

输出一行包含一个整数，表示JYY看完所有支线剧情所需要的最少时间。

Sample Input

6

2 2 1 3 2

2 4 3 5 4

2 5 5 6 6

0

0

0
Sample Output

24
HINT

JYY需要重新开始3次游戏，加上一开始的一次游戏，4次游戏的进程是

1->2->4，1->2->5，1->3->5和1->3->6。

对于100%的数据满足N<=300,0<=Ki<=50,1<=Tij<=300,Sigma(Ki)<=5000
Source

By 佚名上传

 

分析：

dag图上每个边有各自费用，每次从1出发在图上走，求最少代价是每个边经过至少一次。

有源有下界最小费用最大流，每个边流量下界为1

建图：

创立特殊源汇s,t

对于每条边(x,y,下界z，cost)，由s到y连一条z容量cost费用的边表示至少流一次，由x到y连一条inf容量cost费用的边表示可以经过多次

对于每个点x，由x向汇点连一条容量为其出度费用为0的边，由x向1连一条容量为inf费用为0的边表示可以重复从1开始，（也就是使将原来的源点替换掉转为无源汇来做）

跑费用流即可。

program watching;
type
  point=record
    x,c,next,v,fr:longint;
  end;
var
  q:array[0..5000]of longint;
  d,head,p:array[0..500]of longint;
  g:array[0..500]of boolean;
  e:array[-1..80000]of point;
  n,i,m,tot,s,v,inf,k,j,x,t:longint;
procedure add(x,y,v,cost:longint);
begin
  inc(tot);e[tot].x:=y; e[tot].c:=v; e[tot].next:=head[x]; e[tot].v:=cost;e[tot].fr:=x; head[x]:=tot;
  inc(tot);e[tot].x:=x; e[tot].c:=0; e[tot].next:=head[y]; e[tot].v:=-cost;e[tot].fr:=y; head[y]:=tot;
end;
function min(x,y:longint):longint;
begin
  if x<y then min:=x else min:=y;
end;
function spfa:boolean;
var i,h,t,x,y:longint;
begin
  for i:=0 to v do begin d[i]:=inf; g[i]:=false; end;
  d[s]:=0; h:=0; t:=1; g[s]:=true; q[1]:=s;
  while h<t do
   begin
     inc(h); x:=q[h]; i:=head[x];
     while i>-1 do
      begin
        y:=e[i].x;
        if (e[i].c>0)and(d[y]>d[x]+e[i].v) then
        begin
          d[y]:=d[x]+e[i].v; p[y]:=i;
          if g[y]=false then
           begin
             g[y]:=true; inc(t); q[t]:=y;
           end;
        end;
        i:=e[i].next;
      end;
     g[x]:=false;
   end;
  if d[v]<inf then exit(true) else exit(false);
end;
function work:longint;
var ans,f,x:longint;
begin
  ans:=0;
  while spfa do
   begin
     f:=inf;
     x:=v;
     while x<>s do begin f:=min(f,e[p[x]].c); x:=e[p[x]].fr; end;
     x:=v;
     while x<>s do begin dec(e[p[x]].c,f); inc(e[p[x] xor 1].c,f); x:=e[p[x]].fr; end;
     inc(ans,d[v]*f);
   end;
  exit(ans);
end;
begin
  assign(input,'watching.in');
reset(input);
assign(output,'watching.out');
rewrite(output);
  readln(n);  inf:=maxlongint div 3;  tot:=-1;
  for i:=0 to n+1 do head[i]:=-1;
  s:=n+1; v:=n+2;
  for i:=1 to n do
  begin
    read(k); add(i,v,k,0); if i<>1 then add(i,1,inf,0);
    for j:=1 to k do
    begin read(x,t); add(i,x,inf,t); add(s,x,1,t); end;
  end;
  writeln(work);
  close(input); close(output);
end.